I_MDChgProcessMatchScore

DDL: I_MDCHGPROCESSMATCHSCORE Type: view_entity COMPOSITE Package: MDC_MODEL

MDC Match Score for matching pairs

I_MDChgProcessMatchScore is a Composite CDS View that provides data about "MDC Match Score for matching pairs" in SAP S/4HANA. It reads from 6 data sources and exposes 15 fields with key fields MasterDataChangeProcess, MDChgProcessMatchGroupID, MDChgProcessSrceSystem, MDChgProcessSrceObject, MDChgProcessMatchSrceSystem. Part of development package MDC_MODEL.

6 data source(s) 15 fields

Data Sources (6)

SourceAliasJoin Type
I_MDChgProcessMatchGroup BestRecord inner
I_MDChgProcessMatchGroup BestRecord inner
I_MasterDataChangeProcess Process inner
I_MasterDataChangeProcess Process inner
I_MDChgProcessMatchGroup Record inner
I_MDChgProcessMatchGroup Record inner

Annotations (7)

NameValueLevelField
AccessControl.authorizationCheck #NOT_REQUIRED view
EndUserText.label MDC Match Score for matching pairs view
Metadata.ignorePropagatedAnnotations true view
ObjectModel.usageType.serviceQuality #C view
ObjectModel.usageType.sizeCategory #M view
ObjectModel.usageType.dataClass #TRANSACTIONAL view
VDM.viewType #COMPOSITE view

Fields (15)

KeyFieldSource TableSource FieldDescription
KEY MasterDataChangeProcess MatchResult MasterDataChangeProcess
KEY MDChgProcessMatchGroupID I_MDChgProcessMatchGroup MDChgProcessMatchGroupID
KEY MDChgProcessSrceSystem MatchResult MDChgProcessSrceSystem
KEY MDChgProcessSrceObject MatchResult MDChgProcessSrceObject
KEY MDChgProcessMatchSrceSystem MatchResult MDChgProcessMatchSrceSystem
KEY MDChgProcessMatchSrceObject MatchResult MDChgProcessMatchSrceObject
MDChgProcessMatchRule MatchResult MDChgProcessMatchRule
MasterDataChangeProcess
KEY MDChgProcessMatchGroupID I_MDChgProcessMatchGroup MDChgProcessMatchGroupID
KEY MDChgProcessSrceSystem MatchResult MDChgProcessMatchSrceSystem
KEY MDChgProcessSrceObject MatchResult MDChgProcessMatchSrceObject
KEY MDChgProcessMatchSrceSystem MatchResult MDChgProcessSrceSystem
KEY MDChgProcessMatchSrceObject MatchResult MDChgProcessSrceObject
MDChgProcessMatchRule MatchResult MDChgProcessMatchRule
MDChgProcessMatchScoreValue MatchResult MDChgProcessMatchScoreValue 
@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'MDC Match Score for matching pairs'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType:{
  serviceQuality: #C,
  sizeCategory: #M,
  dataClass: #TRANSACTIONAL
}
@VDM.viewType: #COMPOSITE
define view entity I_MDChgProcessMatchScore
  as select distinct from I_MDChgProcessMatchResult as MatchResult
    inner join            I_MDChgProcessMatchGroup  as Record     on  MatchResult.MasterDataChangeProcess = Record.MasterDataChangeProcess
                                                                  and MatchResult.MDChgProcessSrceObject  = Record.MDChgProcessSrceObject
                                                                  and MatchResult.MDChgProcessSrceObject  = Record.MDChgProcessSrceObject
    inner join            I_MDChgProcessMatchGroup  as BestRecord on  MatchResult.MasterDataChangeProcess      = BestRecord.MasterDataChangeProcess
                                                                  and MatchResult.MDChgProcessMatchSrceObject  = BestRecord.MDChgProcessSrceObject
                                                                  and MatchResult.MDChgProcessMatchSrceSystem  = BestRecord.MDChgProcessSrceSystem
                                                                  and BestRecord.MDChgProcMatchGrpIsBestRecord = 'X'
                                                                  and Record.MDChgProcessMatchGroupID          = BestRecord.MDChgProcessMatchGroupID
    inner join            I_MasterDataChangeProcess as Process    on MatchResult.MasterDataChangeProcess = Process.MasterDataChangeProcess
{
  key MatchResult.MasterDataChangeProcess,
  key Record.MDChgProcessMatchGroupID,
  key MatchResult.MDChgProcessSrceSystem,
  key MatchResult.MDChgProcessSrceObject,
  key MatchResult.MDChgProcessMatchSrceSystem,
  key MatchResult.MDChgProcessMatchSrceObject,
      MatchResult.MDChgProcessMatchRule,
      MatchResult.MDChgProcessMatchScoreValue
}
where
      MatchResult.MDChgProcessMatchScoreValue is not initial
  and Process.MDChgProcessGoal                <> 'A'

union select distinct from I_MDChgProcessMatchResult as MatchResult
  inner join               I_MDChgProcessMatchGroup  as Record     on  MatchResult.MasterDataChangeProcess = Record.MasterDataChangeProcess
                                                                   and MatchResult.MDChgProcessSrceObject  = Record.MDChgProcessSrceObject
                                                                   and MatchResult.MDChgProcessSrceObject  = Record.MDChgProcessSrceObject
  inner join               I_MDChgProcessMatchGroup  as BestRecord on  MatchResult.MasterDataChangeProcess      = BestRecord.MasterDataChangeProcess
                                                                   and MatchResult.MDChgProcessSrceObject       = BestRecord.MDChgProcessSrceObject
                                                                   and MatchResult.MDChgProcessSrceSystem       = BestRecord.MDChgProcessSrceSystem
                                                                   and BestRecord.MDChgProcMatchGrpIsBestRecord = 'X'
                                                                   and Record.MDChgProcessMatchGroupID          = BestRecord.MDChgProcessMatchGroupID
  inner join               I_MasterDataChangeProcess as Process    on MatchResult.MasterDataChangeProcess = Process.MasterDataChangeProcess
{
  key MatchResult.MasterDataChangeProcess,
  key Record.MDChgProcessMatchGroupID,
  key MatchResult.MDChgProcessMatchSrceSystem as MDChgProcessSrceSystem,
  key MatchResult.MDChgProcessMatchSrceObject as MDChgProcessSrceObject,
  key MatchResult.MDChgProcessSrceSystem      as MDChgProcessMatchSrceSystem,
  key MatchResult.MDChgProcessSrceObject      as MDChgProcessMatchSrceObject,
      MatchResult.MDChgProcessMatchRule,
      MatchResult.MDChgProcessMatchScoreValue
}
where
      MatchResult.MDChgProcessMatchScoreValue is not initial
  and Process.MDChgProcessGoal                = 'A'

Learn More