I_LogisticsOrderBasic

@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.personalData.blocking: #NOT_REQUIRED
@Analytics.dataCategory: #DIMENSION
@Analytics.technicalName: 'ILOGSORDBASIC'
@Analytics.internalName: #LOCAL
@Consumption.ranked: true
@Metadata.allowExtensions: true
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.modelingPattern: #NONE
@ObjectModel.supportedCapabilities: [#CDS_MODELING_ASSOCIATION_TARGET, #CDS_MODELING_DATA_SOURCE, #SQL_DATA_SOURCE, #SEARCHABLE_ENTITY]
@ObjectModel.representativeKey: 'OrderID'
@ObjectModel.semanticKey: ['OrderID']
@ObjectModel.usageType: {serviceQuality: #A, sizeCategory: #L, dataClass: #TRANSACTIONAL}
@Search.searchable: true
@VDM.lifecycle.contract.type: #PUBLIC_LOCAL_API
@VDM.viewType: #BASIC
@EndUserText.label: 'Logistics Order Basic'
// Basic view for order header table AFKO only (mainly logistics/work orders)

// Due to the high number of consumers, this CDS view is protected against incompatible changes


define view entity I_LogisticsOrderBasic
  as select from afko as afko

  association [1..1] to I_OrderInternalID             as _OrderInternalID             on  $projection.OrderInternalID = _OrderInternalID.OrderInternalID
  association [1..1] to I_Order                       as _Order                       on  $projection.OrderID = _Order.OrderID
  association [0..1] to I_LogisticsOrderPriority      as _OrderPriority               on  $projection.PriorityCode = _OrderPriority.PriorityCode
  association [0..1] to I_UnitOfMeasure               as _BaseUnit                    on  $projection.BaseUnit = _BaseUnit.UnitOfMeasure
  association [0..1] to I_UnitOfMeasure               as _MaterialBaseUnit            on  $projection.MaterialBaseUnit = _MaterialBaseUnit.UnitOfMeasure
  association [0..1] to I_ReservationDocumentHeader   as _Reservation                 on  $projection.Reservation = _Reservation.Reservation
  association [0..1] to I_ReservationDocumentHeader   as _SettlementReservation       on  $projection.SettlementReservation = _SettlementReservation.Reservation
  association [0..1] to I_ProjectNetwork              as _SuperiorProjectNetwork      on  $projection.SuperiorProjectNetwork = _SuperiorProjectNetwork.ProjectNetwork
  association [0..1] to I_ProjectBasicData            as _Project                     on  $projection.ProjectInternalID = _Project.ProjectInternalID
  association [0..1] to I_CapacityRequirement         as _CapacityRequirement         on  $projection.CapacityRequirement = _CapacityRequirement.CapacityRequirement
  association [0..1] to I_ConfirmationGroup           as _ConfirmationGroup           on  $projection.MfgOrderConfirmation = _ConfirmationGroup.ConfirmationGroup
  association [0..1] to I_ChangeMaster                as _ChangeNumber                on  $projection.ChangeNumber = _ChangeNumber.ChangeNumber
  association [0..1] to I_BillOfOperationsType        as _BillOfOperationsType        on  $projection.BillOfOperationsType  = _BillOfOperationsType.BillOfOperationsType
  association [0..1] to I_BillOfOperationsGroup       as _BillOfOperationsGroup       on  $projection.BillOfOperationsType  = _BillOfOperationsGroup.BillOfOperationsType
                                                                                      and $projection.BillOfOperationsGroup = _BillOfOperationsGroup.BillOfOperationsGroup
  association [0..1] to I_BillOfOperations            as _BillOfOperations            on  $projection.BillOfOperationsType    = _BillOfOperations.BillOfOperationsType
                                                                                      and $projection.BillOfOperationsGroup   = _BillOfOperations.BillOfOperationsGroup
                                                                                      and $projection.BillOfOperationsVariant = _BillOfOperations.BillOfOperationsVariant
  association [0..1] to I_BillOfOperationsChangeState as _BillOfOperationsChangeState on  $projection.BillOfOperationsType      = _BillOfOperationsChangeState.BillOfOperationsType
                                                                                      and $projection.BillOfOperationsGroup     = _BillOfOperationsChangeState.BillOfOperationsGroup
                                                                                      and $projection.BillOfOperationsVariant   = _BillOfOperationsChangeState.BillOfOperationsVariant
                                                                                      and $projection.BOOInternalVersionCounter = _BillOfOperationsChangeState.BOOInternalVersionCounter
  association [0..1] to I_BillOfOperationsUsage       as _BillOfOperationsUsage       on  $projection.BillOfOperationsUsage = _BillOfOperationsUsage.BillOfOperationsUsage
  association [0..1] to I_InspectionLot               as _InspectionLot               on  $projection.InspectionLot = _InspectionLot.InspectionLot
  association [0..1] to I_SchedulingType              as _BasicSchedulingType         on  $projection.BasicSchedulingType = _BasicSchedulingType.SchedulingType
  association [0..1] to I_SchedulingType              as _ForecastSchedulingType      on  $projection.ForecastSchedulingType = _ForecastSchedulingType.SchedulingType
  association [0..1] to I_RequestOrderType            as _RequestOrderType            on  $projection.RequestOrderType = _RequestOrderType.RequestOrderType

{
      @Search: {defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.8}  
  key afko.aufnr                                                     as OrderID,

      // Internal Key

      @ObjectModel.foreignKey.association: '_OrderInternalID'
      cast(afko.aufpl as pph_aufpl preserving type)                  as OrderInternalID,

      // Attributes

      @ObjectModel.foreignKey.association: '_OrderPriority'
      afko.aprio                                                     as PriorityCode,
      @Semantics.booleanIndicator 
      afko.prodnet                                                   as MfgOrderIsPartOfCollvOrder,
      @Semantics.booleanIndicator 
      cast(afko.naucost as vdm_naucost preserving type)              as OrderIsNotCostedAutomatically,
      @Semantics.booleanIndicator 
      cast(afko.nauterm as vdm_nauterm preserving type)              as OrdIsNotSchedldAutomatically,
      @VDM.lifecycle.status: #DEPRECATED
      @VDM.lifecycle.successor: 'OrderHierarchyLevelValue'
      afko.stufe                                                     as MfgOrderHierarchyLevel,
      afko.stufe                                                     as OrderHierarchyLevelValue,
      afko.wegxx                                                     as OrderHierarchyPathValue,
      afko.flexible_processing                                       as ProdnProcgIsFlexible,

      // Assignments

      afko.maufnr                                                    as MfgOrderSuperiorMfgOrder,
      afko.lead_aufnr                                                as LeadingOrder,
--    @ObjectModel.foreignKey.association: '_MRPController'
      cast(afko.dispo as pph_dispo preserving type)                  as MRPController,
--    @ObjectModel.foreignKey.association: '_ProductionSupervisor'
      cast(afko.fevor as pph_fevor preserving type)                  as ProductionSupervisor,
--    @ObjectModel.foreignKey.association: '_ProductionSchedulingProfile'
      afko.sfcpf                                                     as ProductionSchedulingProfile,
--    @ObjectModel.foreignKey.association: '_ResponsiblePlannerGroup'
      afko.plgrp                                                     as ResponsiblePlannerGroup,
      @ObjectModel.foreignKey.association: '_Project'
      cast(afko.pronr as ps_s4_proj_pspnr preserving type)           as ProjectInternalID,   // w/o conversion exit  

--    @ObjectModel.foreignKey.association: '_SuperiorProjectNetwork'
      afko.aufnt                                                     as SuperiorProjectNetwork,
      @ObjectModel.foreignKey.association: '_Reservation'
      afko.rsnum                                                     as Reservation,
      @ObjectModel.foreignKey.association: '_SettlementReservation'    
      afko.arsnr                                                     as SettlementReservation,
      @ObjectModel.foreignKey.association: '_ConfirmationGroup'
      afko.rueck                                                     as MfgOrderConfirmation,
      afko.rmzhl                                                     as MfgOrderConfirmationCount,
      @ObjectModel.foreignKey.association: '_CapacityRequirement'
      afko.bedid                                                     as CapacityRequirement,
      @ObjectModel.foreignKey.association: '_InspectionLot'
      afko.prueflos                                                  as InspectionLot,
      @ObjectModel.foreignKey.association: '_ChangeNumber'
      afko.aennr                                                     as ChangeNumber,
      @ObjectModel.foreignKey.association: '_BasicSchedulingType'
      cast(afko.terkz as pph_termkz preserving type)                 as BasicSchedulingType,
      @ObjectModel.foreignKey.association: '_ForecastSchedulingType'
      afko.trkzp                                                     as ForecastSchedulingType,
      afko.breaks                                                    as SchedulingIsAllowingForBreaks,
      afko.plart                                                     as ProdAvailyCheckPlanningType,
      afko.netzkont                                                  as NtwkAccountAssignmentCode,
      afko.profid                                                    as NetworkProfile,
      afko.cuobj                                                     as ProductConfiguration,
      cast(afko.revlv as vdm_qm_revlv preserving type)               as MaterialRevisionLevel,
      afko.kapversa                                                  as CapacityActiveVersion,
      afko.kbed                                                      as CapacityRqmtHasNotToBeCreated,
      afko.cy_seqnr                                                  as OrderSequenceNumber,
      afko.splstat                                                   as MfgOrderSplitStatus,
      @ObjectModel.foreignKey.association: '_RequestOrderType'
      cast(afko.atrkz as vdm_atrkz preserving type)                  as RequestOrderType,

      // Assignments FI/CO

      afko.klvari                                                    as ActualCostsCostingVariant,
      afko.klvarp                                                    as PlannedCostsCostingVariant,

      // Assignments BOO

      cast(afko.plnbez as billofoperationsmaterial  preserving type) as Material,
      @ObjectModel.foreignKey.association: '_BillOfOperationsType'
      cast(afko.plnty as billofoperationstype       preserving type) as BillOfOperationsType,
      @ObjectModel.foreignKey.association: '_BillOfOperationsGroup'
      cast(afko.plnnr as billofoperationsgroup      preserving type) as BillOfOperationsGroup,
      @ObjectModel.foreignKey.association: '_BillOfOperations'
      cast(afko.plnal as billofoperationsvariant    preserving type) as BillOfOperationsVariant,
      @ObjectModel.foreignKey.association: '_BillOfOperationsChangeState'
      afko.zaehl                                                     as BOOInternalVersionCounter,
      @ObjectModel.foreignKey.association: '_BillOfOperationsUsage'
      cast(afko.pverw as billofoperationsusage      preserving type) as BillOfOperationsUsage,
      cast(afko.plnaw as billofoperationsapplication preserving type) as BillOfOperationsApplication,
      afko.tl_versn                                                  as BillOfOperationsVersion,
      afko.plauf                                                     as BOOExplosionDate,
      afko.pdatv                                                     as BOOValidityStartDate,
      -- kept for compatibility reasons
      @VDM.lifecycle.status: #DEPRECATED
      @VDM.lifecycle.successor: 'BillOfOperationsGroup'
      afko.plnnr                                                     as BillOfOperations,

      // Assignments BOM

      cast(afko.stlty as pph_stlty preserving type)                  as BillOfMaterialCategory,
      cast(afko.stlnr as pph_stnum preserving type)                  as BillOfMaterial,     // with conv. exit ALPHA 

      afko.stlal                                                     as BillOfMaterialVariant,
      afko.stlan                                                     as BillOfMaterialVariantUsage,
      afko.bom_versn                                                 as BillOfMaterialVersion,
      afko.stlst                                                     as BillOfMaterialStatus,
      afko.aufld                                                     as BOMExplosionDate,
      afko.sdatv                                                     as BOMValidityStartDate,

      // Fashion Manufacturing Fields

      afko.fsh_mprod_ord                                             as MasterProductionOrder,

      // Floats

      cast(afko.fhori as vdm_fhori preserving type)                  as SchedulingFloatProfile,
      cast(afko.vorgz as vdm_vorgz preserving type)                  as FloatBeforeProductionInWrkDays,
      cast(afko.sichz as vdm_sichz preserving type)                  as FloatAfterProductionInWorkDays,
      afko.freiz                                                     as ReleasePeriodInWorkDays,

      // Dates and Times

      cast(afko.upter as vdm_upter preserving type)                  as ChangeToScheduledDatesIsMade,
      -- planned/basic dates
      afko.gstrp                                                     as PlannedStartDate,
      afko.gsuzp                                                     as PlannedStartTime,
      afko.gltrp                                                     as PlannedEndDate,
      afko.gluzp                                                     as PlannedEndTime,
      cast(afko.ftrmp as fis_co_ftrmp preserving type)               as PlannedReleaseDate,
      -- scheduled dates
      afko.gstrs                                                     as ScheduledBasicStartDate,
      afko.gsuzs                                                     as ScheduledBasicStartTime,
      cast(afko.gltrs as fis_co_gltrs preserving type)               as ScheduledBasicEndDate,
      afko.gluzs                                                     as ScheduledBasicEndTime,
      cast(afko.ftrms as fis_co_ftrms preserving type)               as ScheduledReleaseDate,
      -- confirmed/actual dates
      cast(afko.gstri as fis_co_gstri preserving type)               as ActualStartDate,
      afko.gsuzi                                                     as ActualStartTime,
      afko.getri                                                     as ConfirmedEndDate,
      afko.geuzi                                                     as ConfirmedEndTime,
      @VDM.lifecycle.status: #DEPRECATED
      @VDM.lifecycle.successor: 'ActualDeliveryDate'      
      afko.gltri                                                     as ActualEndDate,   // wrong GFN, it's the delivery date

      cast(afko.gltri as co_ltrmi preserving type)                   as ActualDeliveryDate,
      cast(afko.ftrmi as fis_co_ftrmi preserving type)               as ActualReleasedDate,
      -- forecast dates
      afko.gstps                                                     as ScheduledForecastedStartDate,
      afko.gsups                                                     as ScheduledForecastedStartTime,
      afko.gltps                                                     as ScheduledForecastedEndDate,
      afko.glups                                                     as ScheduledForecastedEndTime,
      afko.ftrps                                                     as ScheduledFcstdReleaseDate,
      afko.gstpp                                                     as ForecastedStartDate,
      afko.gsupp                                                     as ForecastedStartTime,
      afko.gltpp                                                     as ForecastedEndDate,
      afko.glupp                                                     as ForecastedEndTime,
      -- other dates
      afko.gsbtr                                                     as TotalCommitmentDate,
      afko.trmdt                                                     as LastScheduledDate,

      // Quantities and UoM

      @ObjectModel.foreignKey.association: '_BaseUnit'
      afko.gmein                                                     as BaseUnit,
      @Semantics.quantity.unitOfMeasure: 'BaseUnit'
      @Aggregation.default: #SUM
      afko.gamng                                                     as OrderPlannedTotalQty,
      @Semantics.quantity.unitOfMeasure: 'BaseUnit'
      @Aggregation.default: #SUM
      afko.gasmg                                                     as OrderPlannedScrapQty,
      @Semantics.quantity.unitOfMeasure: 'BaseUnit'
      @Aggregation.default: #SUM
      afko.igmng                                                     as OrderConfirmedYieldQty,
      @Semantics.quantity.unitOfMeasure: 'BaseUnit'
      @Aggregation.default: #SUM
      afko.iasmg                                                     as OrderConfirmedScrapQty,
      @Semantics.quantity.unitOfMeasure: 'BaseUnit'
      @Aggregation.default: #SUM
      afko.rmnga                                                     as MfgOrderConfirmedReworkQty,
      @Semantics.quantity.unitOfMeasure: 'BaseUnit'
      @Aggregation.default: #SUM
      (igmng + iasmg + rmnga)                                        as TotalConfirmedQuantity,
      @Semantics.quantity.unitOfMeasure: 'BaseUnit'
      @Aggregation.default: #MIN
      afko.slsvn                                                     as MaterialFromLotSizeQuantity,
      @Semantics.quantity.unitOfMeasure: 'BaseUnit'
      @Aggregation.default: #MAX
      afko.slsbs                                                     as MaterialToLotSizeQuantity,

      @ObjectModel.foreignKey.association: '_MaterialBaseUnit'
      afko.bmeins                                                    as MaterialBaseUnit,
      @Semantics.quantity.unitOfMeasure: 'MaterialBaseUnit'
      @Aggregation.default: #SUM
      afko.bmenge                                                    as PlannedTotalQtyInBaseUnit,

      // Associations

      _BaseUnit,
      _MaterialBaseUnit,
      _Order,                // required for DCLS

      _OrderInternalID,
      _OrderPriority,
      _BillOfOperationsType,
      _BillOfOperationsGroup,
      _BillOfOperations,
      _BillOfOperationsChangeState,
      _BillOfOperationsUsage,
      _Reservation,
      _SettlementReservation,
      _ChangeNumber,
      _CapacityRequirement,
      _ConfirmationGroup,
      _SuperiorProjectNetwork,
      _Project,
      _InspectionLot,
      _BasicSchedulingType,
      _ForecastSchedulingType,
      _RequestOrderType
};