I_LocationTypeText_2

DDL: I_LOCATIONTYPETEXT_2 Type: view_entity BASIC Package: VDM_LOCATION

Location Type - Text

I_LocationTypeText_2 is a Basic CDS View that provides data about "Location Type - Text" in SAP S/4HANA. It reads from 1 data source (dd07t) and exposes 6 fields with key fields LocationType, Language. It has 1 association to related views. Part of development package VDM_LOCATION.

1 data source(s) 6 fields

Data Sources (1)

SourceAliasJoin Type
dd07t dd07t from

Associations (1)

CardinalityTargetAliasCondition
[0..1] I_Language _Language $projection.Language = _Language.Language

Annotations (12)

NameValueLevelField
AccessControl.authorizationCheck #NOT_REQUIRED view
EndUserText.label Location Type - Text view
Metadata.ignorePropagatedAnnotations true view
ObjectModel.dataCategory #TEXT view
ObjectModel.modelingPattern #LANGUAGE_DEPENDENT_TEXT view
ObjectModel.representativeKey LocationType view
ObjectModel.usageType.serviceQuality #A view
ObjectModel.usageType.dataClass #META view
ObjectModel.usageType.sizeCategory #S view
Search.searchable true view
VDM.lifecycle.contract.type #PUBLIC_LOCAL_API view
VDM.viewType #BASIC view

Fields (6)

KeyFieldSource TableSource FieldDescription
KEY LocationType
KEY Language ddlanguage
DomainValue dd07t domvalue_l
LocationTypeDesc
_LocationType _LocationType
_Language _Language 
@AccessControl.authorizationCheck: #NOT_REQUIRED
//@Analytics.dataExtraction.enabled: true

@EndUserText.label: 'Location Type - Text'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.dataCategory: #TEXT
@ObjectModel.modelingPattern: #LANGUAGE_DEPENDENT_TEXT
@ObjectModel.representativeKey: 'LocationType'
@ObjectModel.supportedCapabilities: [#CDS_MODELING_ASSOCIATION_TARGET, 
                                     #CDS_MODELING_DATA_SOURCE,
//                                     #EXTRACTION_DATA_SOURCE,

                                     #LANGUAGE_DEPENDENT_TEXT,
                                     #SEARCHABLE_ENTITY,
                                     #SQL_DATA_SOURCE]
@ObjectModel.usageType.serviceQuality: #A
@ObjectModel.usageType.dataClass: #META
@ObjectModel.usageType.sizeCategory: #S
@Search.searchable: true
@VDM.lifecycle.contract.type: #PUBLIC_LOCAL_API
@VDM.viewType: #BASIC

define view entity I_LocationTypeText_2
  as select from dd07t
  association        to parent I_LocationType_2 as _LocationType on $projection.LocationType = _LocationType.LocationType
  association [0..1] to I_Language              as _Language     on $projection.Language = _Language.Language

{
     @ObjectModel.foreignKey.association: '_LocationType'
      @ObjectModel.text.element: ['LocationTypeDesc']
  key cast( domvalue_l as /sapapo/c_loctype ) as LocationType,
      @Semantics.language
      @ObjectModel.foreignKey.association: '_Language'
  key ddlanguage                                                     as Language,
      @Analytics.hidden: true
      @Consumption.hidden: true
      dd07t.domvalue_l                                               as DomainValue,
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #LOW
      @Semantics.text: true
      cast( ddtext as /scmtms/vdm_loc_type_desc preserving type )    as LocationTypeDesc,

      /* Associations */
      _LocationType,
      _Language
}
where
       domname                     = '/SAPAPO/C_LOCTYPE'
  and  as4local                    = 'A'
  and(
       substring(domvalue_l, 1, 4) = '1003' /* Shipping Point */
    or substring(domvalue_l, 1, 4) = '1021' /* Business Partner */
    or substring(domvalue_l, 1, 4) = '1100' /* Port */
    or substring(domvalue_l, 1, 4) = '1110' /* Airport */
    or substring(domvalue_l, 1, 4) = '1120' /* Railway Station */
    or substring(domvalue_l, 1, 4) = '1190' /* Rail Junction */
    or substring(domvalue_l, 1, 4) = '1200' /* Loading Point */
  );

Learn More