I_ListedSubstanceVariant

@AbapCatalog.sqlViewName: 'ILISUVAR'
@AbapCatalog.compiler.compareFilter: true
@AccessControl:
{
  authorizationCheck: #MANDATORY,
  privilegedAssociations:  [ '_CreatedByUser', '_LastChangedByUser' ]
}
@EndUserText.label: 'Listed Substance Variant View'
@ObjectModel.representativeKey: 'ListedSubstanceVariantUUID'
@VDM.viewType: #COMPOSITE

// Client handling by session

@ClientHandling.algorithm: #SESSION_VARIABLE

// Used for BOBF Master Data Object

@ObjectModel.usageType:
{
  serviceQuality: #C,     // < 15 msec

  sizeCategory: #L,       // < 10.000.000

  dataClass: #MASTER
}

// Listed Substance Variants (also called conditions / sub-roots)

// variants are only contained in the delivered listed substance table and can not be created by customers

define view I_ListedSubstanceVariant
  as select from I_LstdSubstWthVarAndGrp as ListSub
    inner join   I_LstdSubstWthVarAndGrp as ListSubRef on ListSub.ListedSubstanceReference = ListSubRef.ListedSubstance

  association [0..*] to I_ListedSubstanceCndnText    as _ConditionText     on  $projection.ListedSubstanceCndn = _ConditionText.ListedSubstanceCndn
  association [0..1] to I_User                       as _CreatedByUser     on  $projection.CreatedByUser = _CreatedByUser.UserID
  association [0..1] to I_User                       as _LastChangedByUser on  $projection.LastChangedByUser = _LastChangedByUser.UserID
  association [0..*] to I_ListedSubstanceNameText    as _Text              on  $projection.ListedSubstanceVariantUUID = _Text.ListedSubstanceUUID
  association [0..1] to I_ListedSubstanceDefaultName as _DefaultName       on  $projection.ListedSubstanceVariant     = _DefaultName.ListedSubstance
                                                                           and $projection.ListedSubstanceVariantUUID = _DefaultName.ListedSubstanceUUID
{
  key ListSub.ListedSubstanceUUID                                                  as ListedSubstanceVariantUUID,
      _Text,
      _DefaultName,

      // ID

      ListSub.ListedSubstance                                                      as ListedSubstanceVariant,
      ListSub.ListedSubstanceReference                                             as ListedSubstanceReference,
      ListSubRef.ListedSubstanceUUID                                               as ListedSubstanceUUID,
      @ObjectModel.text.association: '_ConditionText'
      ListSub.ListedSubstanceCndn                                                  as ListedSubstanceCndn,
      ListSub.ContentProvider                                                      as ContentProvider,
      _ConditionText,

      // Identifiers

      ListSub.CASNumber                                                            as CASNumber,
      ListSub.ECNumber                                                             as ECNumber,
      ListSub.MolecularFormula                                                     as MolecularFormula,

      // Admin data

      ListSub.CreatedByUser                                                        as CreatedByUser,
      _CreatedByUser,
      @Semantics.systemDateTime.createdAt: true
      ListSub.CreationDateTime                                                     as CreationDateTime,
      @Semantics.systemDateTime.lastChangedAt: true
      ListSub.LastChangeDateTime                                                   as LastChangeDateTime,
      ListSub.LastChangedByUser                                                    as LastChangedByUser,
      _LastChangedByUser
}
where
  ListSub.ListedSubstanceReference <> ''