I_LinearAssetManagementData

DDL: I_LINEARASSETMANAGEMENTDATA SQL: ILAMDATA Type: view BASIC Package: EAML

Linear Asset Management Data

I_LinearAssetManagementData is a Basic CDS View (Dimension) that provides data about "Linear Asset Management Data" in SAP S/4HANA. It reads from 1 data source (eaml_d_lfe_data) and exposes 5 fields with key fields LinearDataObjectType, LinearDataObjectKey. It has 2 associations to related views. Part of development package EAML.

1 data source(s) 5 fields

Data Sources (1)

SourceAliasJoin Type
eaml_d_lfe_data eaml_d_lfe_data from

Associations (2)

CardinalityTargetAliasCondition
[1..1] I_LinearDataObjectType _LinearDataObjectType $projection.LinearDataObjectType = _LinearDataObjectType.LinearDataObjectType
[0..1] I_UnitOfMeasure _LinearDataUnitOfMeasure $projection.LinearDataUnitOfMeasure = _LinearDataUnitOfMeasure.UnitOfMeasure

Annotations (10)

NameValueLevelField
EndUserText.label Linear Asset Management Data view
Analytics.dataCategory #DIMENSION view
VDM.viewType #BASIC view
AccessControl.authorizationCheck #NOT_REQUIRED view
AbapCatalog.sqlViewName ILAMDATA view
ObjectModel.representativeKey LinearDataObjectKey view
ClientHandling.algorithm #SESSION_VARIABLE view
ObjectModel.usageType.dataClass #MASTER view
ObjectModel.usageType.serviceQuality #A view
ObjectModel.usageType.sizeCategory #L view

Fields (5)

KeyFieldSource TableSource FieldDescription
KEY LinearDataObjectType eaml_d_lfe_data obart
KEY LinearDataObjectKey eaml_d_lfe_data tabkey
LinearDataUnitOfMeasure eaml_d_lfe_data linear_unit
_LinearDataObjectType _LinearDataObjectType
_LinearDataUnitOfMeasure _LinearDataUnitOfMeasure 
@EndUserText.label: 'Linear Asset Management Data' //same as DDL description

@Analytics.dataCategory: #DIMENSION
@VDM.viewType: #BASIC
@AccessControl.authorizationCheck: #NOT_REQUIRED
@AbapCatalog.sqlViewName: 'ILAMDATA'

@ObjectModel.representativeKey: 'LinearDataObjectKey'
@ObjectModel.semanticKey:  [ 'LinearDataObjectType', 'LinearDataObjectKey' ]

@ClientHandling.algorithm: #SESSION_VARIABLE

@ObjectModel.usageType.dataClass: #MASTER
@ObjectModel.usageType.serviceQuality: #A
@ObjectModel.usageType.sizeCategory: #L

define view I_LinearAssetManagementData
  as select from eaml_d_lfe_data
  association [1..1] to I_LinearDataObjectType as _LinearDataObjectType    on $projection.LinearDataObjectType = _LinearDataObjectType.LinearDataObjectType
  association [0..1] to I_UnitOfMeasure        as _LinearDataUnitOfMeasure on $projection.LinearDataUnitOfMeasure = _LinearDataUnitOfMeasure.UnitOfMeasure
{
      @ObjectModel.foreignKey.association: '_LinearDataObjectType'
  key eaml_d_lfe_data.obart                                                                                                                                                  as LinearDataObjectType,
  key eaml_d_lfe_data.tabkey                                                                                                                                                 as LinearDataObjectKey,

      @Semantics.unitOfMeasure: true
      eaml_d_lfe_data.linear_unit                                                                                                                                            as LinearDataUnitOfMeasure,

      // Convert start point, end point and length to user's unit of choice stored in linear_unit

      unit_conversion(
          quantity => eaml_d_lfe_data.end_point,
          source_unit => cast( 'M' as abap.unit( 2 ) ),
          target_unit => eaml_d_lfe_data.linear_unit,
         error_handling => 'KEEP_UNCONVERTED'
      )
                                                                                                                                                                             as LinearDataEndPoint,
      unit_conversion(
          quantity => eaml_d_lfe_data.start_point,
          source_unit => cast( 'M' as abap.unit( 2 ) ),
          target_unit => eaml_d_lfe_data.linear_unit,
         error_handling => 'KEEP_UNCONVERTED'
      )
                                                                                                                                                                             as LinearDataStartPoint,

      @Semantics.quantity.unitOfMeasure: 'LinearDataUnitOfMeasure'
      @DefaultAggregation: #SUM
      unit_conversion(
          quantity => eaml_d_lfe_data.linear_length,
          source_unit => cast( 'M' as abap.unit( 2 ) ),
          target_unit => eaml_d_lfe_data.linear_unit,
         error_handling => 'KEEP_UNCONVERTED'
      )                                                                                                                                                                      as LinearDataLength,


      _LinearDataObjectType,
      _LinearDataUnitOfMeasure

}

Learn More