I_LegalTransactionTP

@AbapCatalog.sqlViewName: 'ILEGALTRTP'
@ClientHandling.algorithm: #SESSION_VARIABLE
@AccessControl.authorizationCheck:#CHECK

@EndUserText.label: 'TP View for LCM Legal Transaction'

@VDM.viewType : #TRANSACTIONAL

//@ObjectModel.modelCategory: #BUSINESS_OBJECT


@ObjectModel: {
  representativeKey: 'LegalTransactionUUID',
  semanticKey:  [ 'LegalTransaction' ] ,

  //Only at Root

  compositionRoot: true,
  transactionalProcessingEnabled: true,

  //All Levels

  draftEnabled: true,

  createEnabled: 'EXTERNAL_CALCULATION',
  updateEnabled: 'EXTERNAL_CALCULATION',
  deleteEnabled: 'EXTERNAL_CALCULATION', //Commented for 1708


  writeActivePersistence: 'LCM_LEGALTR',
  writeDraftPersistence: 'LCM_LEGALTR_D',

  usageType.serviceQuality: #C,
  usageType.sizeCategory: #XL,
  usageType.dataClass: #TRANSACTIONAL,

  entityChangeStateId:'LglCntntMChangedUTCDateTime'

}

@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
@ObjectModel.sapObjectNodeType.name:'LegalTransaction'

define view I_LegalTransactionTP
  as select from I_LegalTransaction

  //Parties

  association [0..*] to I_LegalTransactionEntityTP     as _LegalTransactionEntityTP     on  $projection.LegalTransactionUUID = _LegalTransactionEntityTP.LegalTransactionUUID
  association [0..1] to I_LegalTransactionEntityMain   as _LegalTransactionEntityMain   on  $projection.LegalTransactionUUID = _LegalTransactionEntityMain.LegalTransactionUUID
  association [0..*] to I_LegalTransactionIntContactTP as _LegalTransactionIntContactTP on  $projection.LegalTransactionUUID = _LegalTransactionIntContactTP.LegalTransactionUUID
  association [0..*] to I_LegalTransactionExtContactTP as _LegalTransactionExtContactTP on  $projection.LegalTransactionUUID = _LegalTransactionExtContactTP.LegalTransactionUUID

  //Dates & Reminers

  association [0..*] to I_LegalTransactionDateTP       as _LegalTransactionDateTP       on  $projection.LegalTransactionUUID = _LegalTransactionDateTP.LegalTransactionUUID
  association [0..*] to I_LegalTransactionReminderTP   as _LegalTransactionReminderTP   on  $projection.LegalTransactionUUID = _LegalTransactionReminderTP.LegalTransactionUUID
  //Relationships

  association [0..*] to I_LegalTrRelationshipTP        as _LegalTrRelationshipTP        on  $projection.LegalTransactionUUID = _LegalTrRelationshipTP.LegalTransactionUUID
  association [0..*] to I_LegalTrLinkedObjectsTP       as _LegalTrLinkedObjectsTP       on  $projection.LegalTransactionUUID = _LegalTrLinkedObjectsTP.LegalTransactionUUID

  //Context

  association [0..1] to I_LCMContextTP                 as _Context                      on  $projection.LglCntntMContextUUID = _Context.LglCntntMContextUUID

  //Document Link

  association [0..*] to I_LegalTransactionDocLinkTP    as _LegalTransactionDocLinkTP    on  $projection.LegalTransactionUUID = _LegalTransactionDocLinkTP.LegalTransactionUUID
  //Category

  association [1..*] to I_LegalTrCategoryGroupTP       as _LegalTrCategoryGroupTP       on  $projection.LegalTransactionUUID = _LegalTrCategoryGroupTP.LegalTransactionUUID
  //Task Group

  association [0..*] to I_LglCntntMTaskGroupTP         as _LglCntntMTaskGroupTP         on  $projection.LegalTransactionUUID = _LglCntntMTaskGroupTP.LegalTransactionUUID
  //Renewal

  association [0..1] to I_LegalTransRnwlAndTermnTP     as _LegalTransRnwlAndTermnTP     on  $projection.LegalTransactionUUID = _LegalTransRnwlAndTermnTP.LegalTransactionUUID
  //Extension

  association [1..1] to E_LegalTransaction             as _Extenstion                   on  $projection.LegalTransactionUUID = _Extenstion.LegalTransactionUUID
  //Text associations

  association [0..1] to I_LglCntntMProfileText         as _LglCntntMProfileText         on  $projection.LglCntntMProfile = _LglCntntMProfileText.LglCntntMProfile
                                                                                        and Language                     = $session.system_language

  association [0..1] to I_LanguageText                 as _LanguageText                 on  $projection.LglCntntMLanguage = _LanguageText.LanguageCode
                                                                                        and Language                      = $session.system_language
  association [0..1] to I_LegalTransactionHealthText   as _LegalTransactionHealthText   on  $projection.LegalTransactionHealth = _LegalTransactionHealthText.LegalTransactionHealth
                                                                                        and Language                           = $session.system_language
  association [0..1] to I_SalesOrganizationText        as _SalesOrganizationText        on  $projection.LglCntntMMainOrgSalesOrg = _SalesOrganizationText.SalesOrganization
                                                                                        and Language                             = $session.system_language
  association [0..1] to I_LglCntntMMainOrgTypeText     as _LglCntntMMainOrgTypeText     on  $projection.LglCntntMMainOrgType = _LglCntntMMainOrgTypeText.LglCntntMMainOrgType
                                                                                        and Language                         = $session.system_language

  association [0..1] to I_LegalTrLinkedObjectTrigger   as _LglTrLinkedObjectTrigger     on  $projection.LegalTransactionUUID = _LglTrLinkedObjectTrigger.LegalTransactionUUID

  //  association [0..1] to I_LegalTrEntityAggr as _LegalTrEntityAggr on $projection.legaltransactionentityuuid = _LegalTrEntityAggr.LegalTransactionEntityUUID

  association [0..*] to I_LCMEntityTypeText            as _LCMEntityTypeText            on  $projection.lglcntntmentitytype = _LCMEntityTypeText.LglCntntMEntityType
                                                                                        //and Language                        = $session.system_language

{
  key LegalTransactionUUID,

      LegalTransaction,

      LegalTransactionTitle,

      LegalTransactionHealth,

      LglCntntMLanguage,

      LglCntntMContextUUID,

      LglCntntMCreatedByUser,

      LglTransWrkFlwModInstce,

      //@ObjectModel.readOnly: 'EXTERNAL_CALCULATION'

      LglCntntMCreatedUTCDateTime,

      //      @ObjectModel.readOnly: true

      //      LglCntntMCreatedUTCDateTime as LglCntntMCreatedOnDateTime,


      LglCntntMChangedByUser,

      @Semantics.systemDateTime.lastChangedAt: true
      LglCntntMChangedUTCDateTime,

      //      @ObjectModel.readOnly: true

      //      LglCntntMChangedUTCDateTime as LglCntntMChangedOnDateTime,


      LglCntntMProfile,

      LegalTransactionSource,

      IsEndOfPurposeBlocked,

      @ObjectModel.readOnly: true
      LglCntntMRtntnPerdStartDate,

      @ObjectModel.readOnly: true
      _Context.LglCntntMContext as LglCntntMContext,

      @ObjectModel.readOnly: true
      _Context.LglCntntMContextVersion,

      _Context.LglCntntMContextTitle,

      //@ObjectModel.readOnly: true

      _LegalTransactionEntityMain.LglCntntMEntity,
      _LegalTransactionEntityMain.LglCntntMEntityType,
      //      _LegalTransactionEntityTP.LegalTransactionEntityUUID,


      LglCntntMLongTextUUID,
      LglCntntMLongText,
      LglCntntMLongTextMimeType,

      //      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'

      LglCntntMGovLaw,

      LglTransAccessLvl,

      LglCntntMMainOrgType,

      LglCntntMMainOrgCoCode,

      LglCntntMMainOrgSalesOrg,

      LglCntntMMainOrgPurOrg,

      LglCntntMIntegrationType,

      //      Expose esign flag

      cast( '' as boole_d )     as LglCntntMSgntrIsDisabled,

      //      @ObjectModel.readOnly: true

      //      CopiedFromLegalTransactionUUID,

      LglCntntMCrtedFrmLglTransUUID,
      _LglCntntMProfileText,
      _LglCntntMIntegTypeText,


      _LanguageText,
      _LegalTransactionHealthText,
      _LglCntntMAccessLvlText,

      _SalesOrganizationText,

      _LglCntntMMainOrgTypeText,

      _PurchasingOrganization,
      _LglTrLinkedObjectTrigger,
      _LCMEntityTypeText,
      //      _LegalTrEntityAggr,


      @ObjectModel.association.type:  [ #TO_COMPOSITION_CHILD  ]
      _LegalTransactionEntityTP,
      @ObjectModel.association.type:  [ #TO_COMPOSITION_CHILD  ]
      _LegalTransactionIntContactTP,
      @ObjectModel.association.type:  [ #TO_COMPOSITION_CHILD  ]
      _LegalTransactionExtContactTP,
      @ObjectModel.association.type:  [ #TO_COMPOSITION_CHILD  ]
      _LegalTransactionDateTP,
      @ObjectModel.association.type:  [ #TO_COMPOSITION_CHILD  ]
      _LegalTransactionReminderTP,
      @ObjectModel.association.type:  [ #TO_COMPOSITION_CHILD  ]
      _LegalTrRelationshipTP,
      @ObjectModel.association.type:  [ #TO_COMPOSITION_CHILD  ]
      _LegalTrLinkedObjectsTP,
      @ObjectModel.association.type:  [ #TO_COMPOSITION_CHILD ]
      _LegalTransactionDocLinkTP,
      @ObjectModel.association.type:  [ #TO_COMPOSITION_CHILD  ]
      _LegalTrCategoryGroupTP,
      @ObjectModel.association.type:  [ #TO_COMPOSITION_CHILD  ]
      _LglCntntMTaskGroupTP,
      @ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
      _LegalTransRnwlAndTermnTP

}