I_LegalRegulation

@EndUserText.label: 'Legal Regulation'
@VDM.viewType: #BASIC
@AbapCatalog.sqlViewName: 'ILEGRGLN'
@AccessControl.authorizationCheck: #CHECK
@ObjectModel.representativeKey: 'LegalRegulation'
@ClientHandling.algorithm: #SESSION_VARIABLE
@Search.searchable: false

@AbapCatalog.buffering.status: #ACTIVE
@AbapCatalog.buffering.type: #FULL
@ObjectModel.usageType.sizeCategory: 'M'
@ObjectModel.usageType.serviceQuality: #A
@ObjectModel.usageType.dataClass: #MASTER
define view I_LegalRegulation
  as select from /sapsll/t606g
  association [0..*] to I_LegalRegulationText      as _LegalRegulationText    on _LegalRegulationText.LegalRegulation = $projection.LegalRegulation
  association [0..*] to I_CountryText              as _CountryText            on _CountryText.Country = $projection.OriginCountry
  association [0..*] to I_TrdClassfctnNmbrSchmText as _CtrlClNmbrSchmText     on _CtrlClNmbrSchmText.TrdClassfctnNmbrSchm = $projection.CtrlClNmbrSchm
  association [0..*] to I_TrdClassfctnNmbrSchmText as _CmmdtyCodeNmbrSchmText on _CmmdtyCodeNmbrSchmText.TrdClassfctnNmbrSchm = $projection.CmmdtyCodeNmbrSchm
  association [0..*] to I_TrdClassfctnNmbrSchmText as _CstmsTrifNmbrNmbrSchmText on _CstmsTrifNmbrNmbrSchmText.TrdClassfctnNmbrSchm = $projection.CmmdtyCodeNmbrSchm
  association [0..*] to I_LegalRegulationAct       as _LegalRegulationAct     on _LegalRegulationAct.LegalRegulation = $projection.LegalRegulation
{
      @ObjectModel.text.association: '_LegalRegulationText'
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
  key lgreg                    as LegalRegulation,
      trara                    as IntlTrdLglRglnArea,
      @ObjectModel.text.association: '_CountryText'
      gglnd                    as OriginCountry,
      @ObjectModel.text.association: '_CtrlClNmbrSchmText'
      cclns                    as CtrlClNmbrSchm,
      cast( case cclns
          when '' then ''
          else 'X'
       end as boolean_flg )    as IsCtrlClNmbrSchmAssgd,
      @ObjectModel.text.association: '_CmmdtyCodeNmbrSchmText'
      cocns                    as CmmdtyCodeNmbrSchm,
      cast( case cocns
          when '' then ''
          else 'X' 
       end as boolean_flg )    as IsCmmdtyCodeNmbrSchmAssgd,
      cgrco                    as IsControlGroupingRelevant,
      @ObjectModel.text.association: '_CstmsTrifNmbrNmbrSchmText'
      tnons                    as CstmsTrifNmbrNmbrSchm,
      cast( case tnons
          when '' then ''
          else 'X'
       end as boolean_flg )    as CstmsTrifNmbrNmbrSchmIsAssgd,
      cast( case mprod
          when 'A' then 'X'
          else '' 
       end as boolean_flg )    as TrdCmplncCtrlIsRlvtForAllProd,

      _LegalRegulationText,
      _CountryText,
      _CtrlClNmbrSchmText,
      _CmmdtyCodeNmbrSchmText,
      _CstmsTrifNmbrNmbrSchmText,
      _LegalRegulationAct
}