I_LedgerCoCode

@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Company Code Settings for Ledger'
@VDM.viewType: #COMPOSITE

@ObjectModel: { usageType.sizeCategory: #S,
                usageType.dataClass:  #MASTER,
                usageType.serviceQuality: #B,
                supportedCapabilities: [#SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE, #CDS_MODELING_ASSOCIATION_TARGET],
                modelingPattern: #NONE }
@Metadata.ignorePropagatedAnnotations: true

define view entity I_LedgerCoCode as select from I_LedgerCompanyCodeCrcyRoles as I_LedgerCompanyCodeCrcyRoles
  
association [1..1] to I_CompanyCode                  as _CompanyCode                   on  $projection.CompanyCode = _CompanyCode.CompanyCode
association [1..1] to I_Ledger                       as _Ledger                        on  $projection.Ledger = _Ledger.Ledger
association [0..1] to I_ChartOfAccounts              as _ChartOfAccounts               on  $projection.chartofaccounts = _ChartOfAccounts.ChartOfAccounts
association [0..1] to I_ControllingArea              as _ControllingArea               on  $projection.controllingarea = _ControllingArea.ControllingArea
association [1..1] to I_FiscalYearVariant            as _FiscalYearVariant             on  $projection.FiscalYearVariant = _FiscalYearVariant.FiscalYearVariant
association [1..1] to I_Currency                     as _CompanyCodeCurrency           on  $projection.currency = _CompanyCodeCurrency.Currency

{
key I_LedgerCompanyCodeCrcyRoles.Ledger,
@ObjectModel.text.element: ['CompanyCodeName']
key I_LedgerCompanyCodeCrcyRoles.CompanyCode,
@Semantics.text
_CompanyCode.CompanyCodeName,
_CompanyCode.ControllingArea,
_CompanyCode.ChartOfAccounts,
_CompanyCode.CityName,
_CompanyCode.Currency,
I_LedgerCompanyCodeCrcyRoles.FiscalYearVariant,

_CompanyCode,
_Ledger,
_ChartOfAccounts,
_ControllingArea,
_FiscalYearVariant,
_CompanyCodeCurrency

}