@AccessControl: { authorizationCheck: #MANDATORY,
personalData.blocking: #REQUIRED }
@EndUserText.label: 'Journal Entry Analyzer - Cube'
//@ObjectModel.representativeKey: 'LedgerGLLineItem'
@ObjectModel: {
usageType: { sizeCategory: #XXL,
dataClass: #MIXED,
serviceQuality: #D },
supportedCapabilities: [#ANALYTICAL_PROVIDER, #SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE],
modelingPattern: #ANALYTICAL_CUBE }
@Analytics: { dataCategory: #CUBE, internalName: #LOCAL }
@Metadata: { ignorePropagatedAnnotations: true,
allowExtensions: true }
@VDM.lifecycle.contract.type: #PUBLIC_LOCAL_API
@VDM.viewType: #COMPOSITE
@AccessControl.auditFilter: #ENABLED
@Environment.sql.passValueForClient: true
//@AbapCatalog.entityBuffer.definitionAllowed: false
//@AbapCatalog.viewEnhancementCategory:[#NONE]
@AbapCatalog.extensibility:{
extensible: true,
elementSuffix:'JEA'
// dataSources: ['_Extension'],
// allowNewDatasources: false,
// quota: {
// maximumFields: 1000,
// maximumBytes: 2500
// }
}
define view entity I_JournalEntryAnalyzerCube
as select from I_GLAccountLineItem as I_GLAccountLineItem
association [0..1] to I_GLAccountInChartOfAccounts as _CorporateGroupAccount on $projection.CorporateGroupChartOfAccounts = _CorporateGroupAccount.ChartOfAccounts
and $projection.CorporateGroupAccount = _CorporateGroupAccount.GLAccount
association [0..1] to I_ChartOfAccounts as _CorporateGroupChartOfAccounts on $projection.CorporateGroupChartOfAccounts = _CorporateGroupChartOfAccounts.ChartOfAccounts
association [0..1] to I_WBSElementBasicData as _WBSElementBasicData on $projection.WBSElementInternalID = _WBSElementBasicData.WBSElementInternalID
association [0..1] to I_ProjectBasicData as _ProjectBasicData on $projection.ProjectInternalID = _ProjectBasicData.ProjectInternalID
association [0..1] to I_WBSElementByExternalID as _WBSElementExternalID on $projection.WBSElementExternalID = _WBSElementExternalID.WBSElementExternalID
association [0..1] to I_ProjectByExternalID as _ProjectExternalID on $projection.ProjectExternalID = _ProjectExternalID.ProjectExternalID
association [0..1] to I_OperationalAcctgDocItem as _OperationalAcctgDocItem on $projection.CompanyCode = _OperationalAcctgDocItem.CompanyCode
and $projection.FiscalYear = _OperationalAcctgDocItem.FiscalYear
and $projection.AccountingDocument = _OperationalAcctgDocItem.AccountingDocument
and $projection.AccountingDocumentItem = _OperationalAcctgDocItem.AccountingDocumentItem
association [1..1] to I_CalendarMonth as _CalendarMonth on $projection.CalendarMonth = _CalendarMonth.CalendarMonth
association [1..1] to I_CalendarQuarter as _CalendarQuarter on $projection.CalendarQuarter = _CalendarQuarter.CalendarQuarter
association [1..1] to I_YearMonth as _CalendarYearMonth on $projection.CalendarYearMonth = _CalendarYearMonth.YearMonth
association [0..1] to I_ValuationArea as _ValuationArea on $projection.ValuationArea = _ValuationArea.ValuationArea
association of exact one to exact one E_JournalEntryItem as _Extension on $projection.SourceLedger = _Extension.SourceLedger
and $projection.CompanyCode = _Extension.CompanyCode
and $projection.FiscalYear = _Extension.FiscalYear
and $projection.AccountingDocument = _Extension.AccountingDocument
and $projection.LedgerGLLineItem = _Extension.LedgerGLLineItem
{
@ObjectModel.foreignKey.association: '_Ledger'
// @Consumption.filter.mandatory: true
// @Analytics.constraints.filter: #UNIQUE_PER_CELL
key I_GLAccountLineItem.Ledger,
@ObjectModel.foreignKey.association: '_SourceLedger'
key I_GLAccountLineItem.SourceLedger,
@ObjectModel.foreignKey.association: '_CompanyCode'
key I_GLAccountLineItem.CompanyCode,
@ObjectModel.foreignKey.association: '_FiscalYear'
// @Semantics.fiscal.year: true
key cast( I_GLAccountLineItem.FiscalYear as fis_gjahr_no_conv preserving type ) as FiscalYear,
@ObjectModel.foreignKey.association: '_JournalEntry'
key I_GLAccountLineItem.AccountingDocument,
key I_GLAccountLineItem.LedgerGLLineItem,
@ObjectModel.foreignKey.association: '_LedgerFiscalYearForVariant'
@Semantics.fiscal.year: true
I_GLAccountLineItem.LedgerFiscalYear,
I_GLAccountLineItem.GLRecordType,
@ObjectModel.foreignKey.association: '_ControllingArea'
I_GLAccountLineItem.ControllingArea,
@ObjectModel.foreignKey.association: '_ChartOfAccounts'
I_GLAccountLineItem.ChartOfAccounts,
@ObjectModel.foreignKey.association: '_GLAccountInChartOfAccounts'
I_GLAccountLineItem.GLAccount,
@ObjectModel.foreignKey.association: '_CostCenter'
I_GLAccountLineItem.CostCenter,
@ObjectModel.foreignKey.association: '_ProfitCenter'
I_GLAccountLineItem.ProfitCenter,
@ObjectModel.foreignKey.association: '_FunctionalArea'
I_GLAccountLineItem.FunctionalArea,
I_GLAccountLineItem.AccountingDocumentItem,
@ObjectModel.foreignKey.association: '_DebitCreditCode'
I_GLAccountLineItem.DebitCreditCode,
// Time Characteristics
@ObjectModel.foreignKey.association: '_FiscalPeriodForVariant'
//0FISCPER3 doesn’t support text, variant is unknown. We can’t use T009C since there 0FISCPER3 is not compound to 0FISCVARNT.
@Semantics.fiscal.period: true
I_GLAccountLineItem.FiscalPeriod,
@ObjectModel.foreignKey.association: '_FiscalYearVariant'
@Semantics.fiscal.yearVariant: true
I_GLAccountLineItem.FiscalYearVariant,
@ObjectModel.foreignKey.association: '_FiscalYearPeriodForVariant'
@Semantics.fiscal.yearPeriod: true
I_GLAccountLineItem.FiscalYearPeriod,
// @Semantics.businessDate.at: true
I_GLAccountLineItem.PostingDate,
// @Semantics.businessDate.at: true
I_GLAccountLineItem.DocumentDate,
// free fields
@ObjectModel.foreignKey.association: '_AccountingDocumentType'
I_GLAccountLineItem.AccountingDocumentType,
// cast(AccountingDocumentType as fis_blart) as JournalEntryType,
I_GLAccountLineItem.AssignmentReference,
@ObjectModel.foreignKey.association: '_PostingKey'
I_GLAccountLineItem.PostingKey,
I_GLAccountLineItem.TransactionTypeDetermination,
@ObjectModel.foreignKey.association: '_SubldgrAccountLineItemType'
I_GLAccountLineItem.SubLedgerAcctLineItemType,
// @ObjectModel.foreignKey.association: '_User'
I_GLAccountLineItem.AccountingDocCreatedByUser,
// @Semantics.businessDate.lastChangedAt: true
I_GLAccountLineItem.LastChangeDateTime,
I_GLAccountLineItem.CreationDateTime,
-- cast(CreationDate as FIS_CPDAT) as CreationDate,
// @Semantics.businessDate.createdAt: true
I_GLAccountLineItem.CreationDate,
@ObjectModel.foreignKey.association: '_AlternativeGLAccount'
I_GLAccountLineItem.AlternativeGLAccount,
@ObjectModel.foreignKey.association: '_CountryChartOfAccounts'
I_GLAccountLineItem.CountryChartOfAccounts,
@ObjectModel.foreignKey.association: '_CorporateGroupChartOfAccounts'
I_GLAccountLineItem._ChartOfAccounts.CorporateGroupChartOfAccounts as CorporateGroupChartOfAccounts,
@ObjectModel.foreignKey.association: '_CorporateGroupAccount'
I_GLAccountLineItem._GLAccountInChartOfAccounts.CorporateGroupAccount as CorporateGroupAccount,
I_GLAccountLineItem._GLAccountInChartOfAccounts.IsBalanceSheetAccount,
I_GLAccountLineItem.InvoiceReference,
@Semantics.fiscal.year: true
I_GLAccountLineItem.InvoiceReferenceFiscalYear,
I_GLAccountLineItem.FollowOnDocumentType,
I_GLAccountLineItem.InvoiceItemReference,
I_GLAccountLineItem.ReferencePurchaseOrderCategory,
// @ObjectModel.foreignKey.association: '_PurchasingDocument'
I_GLAccountLineItem.PurchasingDocument,
// @ObjectModel.foreignKey.association: '_PurchasingDocumentItem'
I_GLAccountLineItem.PurchasingDocumentItem,
I_GLAccountLineItem.AccountAssignmentNumber,
I_GLAccountLineItem.DocumentItemText,
@ObjectModel.foreignKey.association: '_SalesDocument'
I_GLAccountLineItem.SalesDocument,
@ObjectModel.foreignKey.association: '_SalesDocumentItem'
I_GLAccountLineItem.SalesDocumentItem,
@ObjectModel.foreignKey.association: '_Product'
I_GLAccountLineItem.Product,
@ObjectModel.foreignKey.association: '_Plant'
I_GLAccountLineItem.Plant,
@ObjectModel.foreignKey.association: '_Supplier'
I_GLAccountLineItem.Supplier,
@ObjectModel.foreignKey.association: '_Customer'
I_GLAccountLineItem.Customer,
I_GLAccountLineItem.ComponentBreakdown,
I_GLAccountLineItem.CompBreakdownScaleNumerator,
@ObjectModel.foreignKey.association: '_SpecialGLCode'
I_GLAccountLineItem.SpecialGLCode,
@ObjectModel.foreignKey.association: '_FinancialAccountType'
I_GLAccountLineItem.FinancialAccountType,
@Semantics.booleanIndicator
I_GLAccountLineItem.IsOpenItemManaged,
I_GLAccountLineItem.ClearingDate,
@Analytics.internalName: #LOCAL
//@ObjectModel.foreignKey.association: '_ClearingJournalEntry'
I_GLAccountLineItem.ClearingJournalEntry,
@Semantics.fiscal.year: true
@Analytics.internalName: #LOCAL
@ObjectModel.foreignKey.association: '_ClearingJrnlEntryFiscalYear'
I_GLAccountLineItem.ClearingJournalEntryFiscalYear,
I_GLAccountLineItem.ValueDate,
@ObjectModel.foreignKey.association: '_MasterFixedAsset'
I_GLAccountLineItem.MasterFixedAsset,
@ObjectModel.foreignKey.association: '_FixedAsset'
I_GLAccountLineItem.FixedAsset,
AssetValueDate,
@ObjectModel.foreignKey.association: '_AssetTransactionType'
I_GLAccountLineItem.AssetTransactionType,
@ObjectModel.foreignKey.association: '_ValuationArea'
I_GLAccountLineItem.ValuationArea,
@ObjectModel.foreignKey.association: '_OffsettingAccountWithBP'
I_GLAccountLineItem.OffsettingAccount,
I_GLAccountLineItem._OffsettingAccountWithBP.OffsettingAccountName as OffsettingAccountName,
@ObjectModel.foreignKey.association: '_OffsettingAccountType'
I_GLAccountLineItem.OffsettingAccountType,
@ObjectModel.foreignKey.association: '_OffsettingChartOfAccounts'
I_GLAccountLineItem.OffsettingChartOfAccounts,
@ObjectModel.foreignKey.association: '_Order'
I_GLAccountLineItem.OrderID,
@ObjectModel.foreignKey.association: '_OrderCategory'
I_GLAccountLineItem.OrderCategory,
@ObjectModel.foreignKey.association: '_WBSElementBasicData'
I_GLAccountLineItem.WBSElementInternalID,
@ObjectModel.foreignKey.association: '_WBSElementExternalID'
cast( _WBSElementBasicData.WBSElementExternalID as fis_wbsext_no_conv ) as WBSElementExternalID,
@ObjectModel.foreignKey.association: '_BillingDocumentType'
I_GLAccountLineItem.BillingDocumentType,
@ObjectModel.foreignKey.association: '_SalesOrganization'
I_GLAccountLineItem.SalesOrganization,
@ObjectModel.foreignKey.association: '_DistributionChannel'
I_GLAccountLineItem.DistributionChannel,
@ObjectModel.foreignKey.association: '_Division'
@Analytics.internalName:#LOCAL
I_GLAccountLineItem.OrganizationDivision,
@ObjectModel.foreignKey.association: '_Segment'
I_GLAccountLineItem.Segment,
I_GLAccountLineItem.AccountAssignment,
@Analytics.internalName: #LOCAL
@ObjectModel.foreignKey.association: '_AccountAssignmentType'
I_GLAccountLineItem.AccountAssignmentType,
@ObjectModel.foreignKey.association: '_AccountingDocumentCategory'
I_GLAccountLineItem.AccountingDocumentCategory,
@ObjectModel.foreignKey.association: '_MovementCategory'
I_GLAccountLineItem.AssetAcctTransClassfctn,
I_GLAccountLineItem.AssetDepreciationArea,
@ObjectModel.foreignKey.association: '_BusinessTransactionCategory'
I_GLAccountLineItem.BusinessTransactionCategory,
@ObjectModel.foreignKey.association: '_BusinessTransactionType'
I_GLAccountLineItem.BusinessTransactionType,
I_GLAccountLineItem.ControllingBusTransacType,
@ObjectModel.foreignKey.association: '_CustomerGroup'
I_GLAccountLineItem.CustomerGroup,
@Consumption.valueHelpDefinition: [
{ entity: { name: 'I_AcctgServiceDocumentTypeVH',
element: 'ServiceDocumentType' }
}]
@Analytics.internalName: #LOCAL
@ObjectModel.foreignKey.association: '_ServiceDocumentType'
I_GLAccountLineItem.ServiceDocumentType,
@Consumption.valueHelpDefinition: [
{ entity: { name: 'I_AcctgServiceDocumentVH',
element: 'ServiceDocument' }
}]
@Analytics.internalName: #LOCAL
@ObjectModel.foreignKey.association: '_ServiceDocument'
I_GLAccountLineItem.ServiceDocument,
@Consumption.valueHelpDefinition: [
{ entity: { name: 'I_AcctgServiceDocumentItemVH',
element: 'ServiceDocumentItem' }
}]
@Analytics.internalName: #LOCAL
@ObjectModel.foreignKey.association: '_ServiceDocumentItem'
I_GLAccountLineItem.ServiceDocumentItem,
I_GLAccountLineItem.DepreciationFiscalPeriod,
@ObjectModel.foreignKey.association: '_FinancialTransactionType'
I_GLAccountLineItem.FinancialTransactionType,
@ObjectModel.foreignKey.association: '_GLAccountType'
I_GLAccountLineItem.GLAccountType,
@Analytics.internalName: #LOCAL
I_GLAccountLineItem.AssetClass,
I_GLAccountLineItem.IsReversal,
I_GLAccountLineItem.IsReversed,
I_GLAccountLineItem.IsSettled,
I_GLAccountLineItem.IsSettlement,
@ObjectModel.foreignKey.association: '_SoldProductGroup'
I_GLAccountLineItem.SoldProductGroup,
I_GLAccountLineItem.PredecessorReferenceDocCntxt,
I_GLAccountLineItem.PredecessorReferenceDocItem,
@ObjectModel.foreignKey.association: '_PredecessorReferenceDocType'
I_GLAccountLineItem.PredecessorReferenceDocType,
I_GLAccountLineItem.PredecessorReferenceDocument,
I_GLAccountLineItem.SourceReferenceDocumentType,
I_GLAccountLineItem.SourceReferenceDocumentCntxt,
I_GLAccountLineItem.SourceReferenceDocument,
I_GLAccountLineItem.SourceReferenceDocumentItem,
I_GLAccountLineItem.SourceReferenceDocSubitem,
@ObjectModel.foreignKey.association: '_ProjectBasicData'
I_GLAccountLineItem.ProjectInternalID,
@Analytics.internalName: #LOCAL
@ObjectModel.foreignKey.association: '_ProjectExternalID'
cast( _ProjectBasicData.ProjectExternalID as fis_projectext_no_conv ) as ProjectExternalID,
I_GLAccountLineItem.ReferenceDocument,
I_GLAccountLineItem.ReferenceDocumentContext,
I_GLAccountLineItem.ReferenceDocumentItem,
I_GLAccountLineItem.ReferenceDocumentItemGroup,
@ObjectModel.foreignKey.association: '_ReferenceDocumentType'
I_GLAccountLineItem.ReferenceDocumentType,
I_GLAccountLineItem.ReversalReferenceDocument,
I_GLAccountLineItem.ReversalReferenceDocumentCntxt,
@ObjectModel.foreignKey.association: '_SoldProduct'
I_GLAccountLineItem.SoldProduct,
@Analytics.internalName: #LOCAL
@ObjectModel.foreignKey.association: '_CustomerSupplierCountry'
I_GLAccountLineItem.CustomerSupplierCountry,
@ObjectModel.foreignKey.association: '_SalesDistrict'
@Analytics.internalName:#LOCAL
I_GLAccountLineItem.SalesDistrict,
I_GLAccountLineItem.BillToParty,
I_GLAccountLineItem.ShipToParty,
I_GLAccountLineItem.IsStatisticalOrder,
I_GLAccountLineItem.IsStatisticalCostCenter,
I_GLAccountLineItem.IsStatisticalSalesDocument,
I_GLAccountLineItem.WBSIsStatisticalWBSElement,
//////////////////////////////////////////////////
// .INCLUDE ACDOC_SI_LOG_ACT: New Fields PM //
//////////////////////////////////////////////////
@ObjectModel.foreignKey.association: '_ProductGroup'
I_GLAccountLineItem.ProductGroup,
/////////////////////////////////////////////////////////////////////////////
// .INCLUDE ACDOC_SI_FINCS Universal Journal Entry: Fields for Group Reporting
////////////////////////////////////////////////////////////////////////////
@ObjectModel.foreignKey.association: '_Company'
I_GLAccountLineItem.Company,
///////////////////////////////////////////////////////////////////////////////
// Currency and Amount Fields
///////////////////////////////////////////////////////////////////////////////
@ObjectModel.foreignKey.association: '_CompanyCodeCurrency'
I_GLAccountLineItem.CompanyCodeCurrency,
@Aggregation.default: #SUM
@Semantics: { amount : {currencyCode: 'CompanyCodeCurrency'} }
I_GLAccountLineItem.AmountInCompanyCodeCurrency,
@Aggregation.default: #SUM
@Semantics: { amount : {currencyCode: 'CompanyCodeCurrency'} }
I_GLAccountLineItem.DebitAmountInCoCodeCrcy,
@Aggregation.default: #SUM
@Semantics: { amount : {currencyCode: 'CompanyCodeCurrency'} }
I_GLAccountLineItem.CreditAmountInCoCodeCrcy,
@ObjectModel.foreignKey.association: '_TransactionCurrency'
I_GLAccountLineItem.TransactionCurrency,
@Aggregation.default: #SUM
@Semantics: { amount : {currencyCode: 'TransactionCurrency'} }
I_GLAccountLineItem.AmountInTransactionCurrency,
////////////////////////////////////
// NEW
@ObjectModel.foreignKey.association: '_GlobalCurrency'
I_GLAccountLineItem.GlobalCurrency,
@Aggregation.default: #SUM
@Semantics: { amount : {currencyCode: 'GlobalCurrency'} }
I_GLAccountLineItem.AmountInGlobalCurrency,
@ObjectModel.foreignKey.association: '_FunctionalCurrency'
I_GLAccountLineItem.FunctionalCurrency,
@Aggregation.default: #SUM
@Semantics: { amount : {currencyCode: 'FunctionalCurrency'} }
I_GLAccountLineItem.AmountInFunctionalCurrency,
@Aggregation.default: #SUM
@Semantics: { amount : {currencyCode: 'FunctionalCurrency'} }
I_GLAccountLineItem.DebitAmountInFunctionalCrcy,
@Aggregation.default: #SUM
@Semantics: { amount : {currencyCode: 'FunctionalCurrency'} }
I_GLAccountLineItem.CreditAmountInFunctionalCrcy,
@ObjectModel.foreignKey.association: '_FreeDefinedCurrency1'
I_GLAccountLineItem.FreeDefinedCurrency1,
@Aggregation.default: #SUM
@Semantics: { amount : {currencyCode: 'FreeDefinedCurrency1'} }
I_GLAccountLineItem.AmountInFreeDefinedCurrency1,
@ObjectModel.foreignKey.association: '_FreeDefinedCurrency2'
I_GLAccountLineItem.FreeDefinedCurrency2,
@Aggregation.default: #SUM
@Semantics: { amount : {currencyCode: 'FreeDefinedCurrency2'} }
I_GLAccountLineItem.AmountInFreeDefinedCurrency2,
@ObjectModel.foreignKey.association: '_FreeDefinedCurrency3'
I_GLAccountLineItem.FreeDefinedCurrency3,
@Aggregation.default: #SUM
@Semantics: { amount : {currencyCode: 'FreeDefinedCurrency3'} }
I_GLAccountLineItem.AmountInFreeDefinedCurrency3,
@ObjectModel.foreignKey.association: '_FreeDefinedCurrency4'
I_GLAccountLineItem.FreeDefinedCurrency4,
@Aggregation.default: #SUM
@Semantics: { amount : {currencyCode: 'FreeDefinedCurrency4'} }
I_GLAccountLineItem.AmountInFreeDefinedCurrency4,
@ObjectModel.foreignKey.association: '_FreeDefinedCurrency5'
I_GLAccountLineItem.FreeDefinedCurrency5,
@Aggregation.default: #SUM
@Semantics: { amount : {currencyCode: 'FreeDefinedCurrency5'} }
I_GLAccountLineItem.AmountInFreeDefinedCurrency5,
@ObjectModel.foreignKey.association: '_FreeDefinedCurrency6'
I_GLAccountLineItem.FreeDefinedCurrency6,
@Aggregation.default: #SUM
@Semantics: { amount : {currencyCode: 'FreeDefinedCurrency6'} }
I_GLAccountLineItem.AmountInFreeDefinedCurrency6,
@ObjectModel.foreignKey.association: '_FreeDefinedCurrency7'
I_GLAccountLineItem.FreeDefinedCurrency7,
@Aggregation.default: #SUM
@Semantics: { amount : {currencyCode: 'FreeDefinedCurrency7'} }
I_GLAccountLineItem.AmountInFreeDefinedCurrency7,
@ObjectModel.foreignKey.association: '_FreeDefinedCurrency8'
I_GLAccountLineItem.FreeDefinedCurrency8,
@Aggregation.default: #SUM
@Semantics: { amount : {currencyCode: 'FreeDefinedCurrency8'} }
I_GLAccountLineItem.AmountInFreeDefinedCurrency8,
I_GLAccountLineItem.ControllingObjectCurrency,
@Aggregation.default: #SUM
@Semantics: { amount : {currencyCode: 'ControllingObjectCurrency'} }
I_GLAccountLineItem.AmountInObjectCurrency,
@ObjectModel.foreignKey.association: '_BaseUnit'
I_GLAccountLineItem.BaseUnit,
@Aggregation.default: #SUM
@Semantics: { quantity : {unitOfMeasure: 'BaseUnit'} }
I_GLAccountLineItem.Quantity,
@ObjectModel.foreignKey.association: '_CostSourceUnit'
I_GLAccountLineItem.CostSourceUnit,
@Aggregation.default: #SUM
@Semantics: { quantity : {unitOfMeasure: 'CostSourceUnit'} }
I_GLAccountLineItem.ValuationQuantity,
@ObjectModel.foreignKey.association: '_AdditionalQuantity1Unit'
I_GLAccountLineItem.AdditionalQuantity1Unit,
@Aggregation.default: #SUM
@Semantics: { quantity : {unitOfMeasure: 'AdditionalQuantity1Unit'} }
I_GLAccountLineItem.AdditionalQuantity1,
@ObjectModel.foreignKey.association: '_AdditionalQuantity2Unit'
I_GLAccountLineItem.AdditionalQuantity2Unit,
@Aggregation.default: #SUM
@Semantics: { quantity : {unitOfMeasure: 'AdditionalQuantity2Unit'} }
I_GLAccountLineItem.AdditionalQuantity2,
@ObjectModel.foreignKey.association: '_AdditionalQuantity3Unit'
I_GLAccountLineItem.AdditionalQuantity3Unit,
@Aggregation.default: #SUM
@Semantics: { quantity : {unitOfMeasure: 'AdditionalQuantity3Unit'} }
I_GLAccountLineItem.AdditionalQuantity3,
@Aggregation.default: #SUM
@Semantics: { amount : {currencyCode: 'TransactionCurrency'} }
I_GLAccountLineItem.DebitAmountInTransCrcy,
@Aggregation.default: #SUM
@Semantics: { amount : {currencyCode: 'TransactionCurrency'} }
I_GLAccountLineItem.CreditAmountInTransCrcy,
@ObjectModel.foreignKey.association: '_BalanceTransactionCurrency'
I_GLAccountLineItem.BalanceTransactionCurrency,
@Aggregation.default: #SUM
@Semantics: { amount : {currencyCode: 'BalanceTransactionCurrency'} }
I_GLAccountLineItem.AmountInBalanceTransacCrcy,
@Aggregation.default: #SUM
@Semantics: { amount : {currencyCode: 'BalanceTransactionCurrency'} }
I_GLAccountLineItem.CreditAmountInBalanceTransCrcy,
@Aggregation.default: #SUM
@Semantics: { amount : {currencyCode: 'BalanceTransactionCurrency'} }
I_GLAccountLineItem.DebitAmountInBalanceTransCrcy,
@Aggregation.default: #SUM
@Semantics: { amount : {currencyCode: 'GlobalCurrency'} }
I_GLAccountLineItem.DebitAmountInGlobalCrcy,
@Aggregation.default: #SUM
@Semantics: { amount : {currencyCode: 'GlobalCurrency'} }
I_GLAccountLineItem.CreditAmountInGlobalCrcy,
@Aggregation.default: #SUM
@Semantics: { amount : {currencyCode: 'FreeDefinedCurrency1'} }
I_GLAccountLineItem.DebitAmountInFreeDefinedCrcy1 as DebitAmountInFreeDfndCrcy1,
@Aggregation.default: #SUM
@Semantics: { amount : {currencyCode: 'FreeDefinedCurrency1'} }
I_GLAccountLineItem.CreditAmountInFreeDefinedCrcy1 as CreditAmountInFreeDfndCrcy1,
@Aggregation.default: #SUM
@Semantics: { amount : {currencyCode: 'FreeDefinedCurrency2'} }
I_GLAccountLineItem.DebitAmountInFreeDefinedCrcy2 as DebitAmountInFreeDfndCrcy2,
@Aggregation.default: #SUM
@Semantics: { amount : {currencyCode: 'FreeDefinedCurrency2'} }
I_GLAccountLineItem.CreditAmountInFreeDefinedCrcy2 as CreditAmountInFreeDfndCrcy2,
@Aggregation.default: #SUM
@Semantics: { amount : {currencyCode: 'FreeDefinedCurrency3'} }
I_GLAccountLineItem.DebitAmountInFreeDefinedCrcy3 as DebitAmountInFreeDfndCrcy3,
@Aggregation.default: #SUM
@Semantics: { amount : {currencyCode: 'FreeDefinedCurrency3'} }
I_GLAccountLineItem.CreditAmountInFreeDefinedCrcy3 as CreditAmountInFreeDfndCrcy3,
@Aggregation.default: #SUM
@Semantics: { amount : {currencyCode: 'FreeDefinedCurrency4'} }
I_GLAccountLineItem.DebitAmountInFreeDefinedCrcy4 as DebitAmountInFreeDfndCrcy4,
@Aggregation.default: #SUM
@Semantics: { amount : {currencyCode: 'FreeDefinedCurrency4'} }
I_GLAccountLineItem.CreditAmountInFreeDefinedCrcy4 as CreditAmountInFreeDfndCrcy4,
@Aggregation.default: #SUM
@Semantics: { amount : {currencyCode: 'FreeDefinedCurrency5'} }
I_GLAccountLineItem.DebitAmountInFreeDefinedCrcy5 as DebitAmountInFreeDfndCrcy5,
@Aggregation.default: #SUM
@Semantics: { amount : {currencyCode: 'FreeDefinedCurrency5'} }
I_GLAccountLineItem.CreditAmountInFreeDefinedCrcy5 as CreditAmountInFreeDfndCrcy5,
@Aggregation.default: #SUM
@Semantics: { amount : {currencyCode: 'FreeDefinedCurrency6'} }
I_GLAccountLineItem.DebitAmountInFreeDefinedCrcy6 as DebitAmountInFreeDfndCrcy6,
@Aggregation.default: #SUM
@Semantics: { amount : {currencyCode: 'FreeDefinedCurrency6'} }
I_GLAccountLineItem.CreditAmountInFreeDefinedCrcy6 as CreditAmountInFreeDfndCrcy6,
@Aggregation.default: #SUM
@Semantics: { amount : {currencyCode: 'FreeDefinedCurrency7'} }
I_GLAccountLineItem.DebitAmountInFreeDefinedCrcy7 as DebitAmountInFreeDfndCrcy7,
@Aggregation.default: #SUM
@Semantics: { amount : {currencyCode: 'FreeDefinedCurrency7'} }
I_GLAccountLineItem.CreditAmountInFreeDefinedCrcy7 as CreditAmountInFreeDfndCrcy7,
@Aggregation.default: #SUM
@Semantics: { amount : {currencyCode: 'FreeDefinedCurrency8'} }
I_GLAccountLineItem.DebitAmountInFreeDefinedCrcy8 as DebitAmountInFreeDfndCrcy8,
@Aggregation.default: #SUM
@Semantics: { amount : {currencyCode: 'FreeDefinedCurrency8'} }
I_GLAccountLineItem.CreditAmountInFreeDefinedCrcy8 as CreditAmountInFreeDfndCrcy8,
////////////////////////////////////
// NEW
@Aggregation.default: #SUM
@Semantics: { amount : {currencyCode: 'GlobalCurrency'} }
I_GLAccountLineItem.FixedAmountInGlobalCrcy,
@Aggregation.default: #SUM
@Semantics: { quantity : {unitOfMeasure: 'BaseUnit'} }
I_GLAccountLineItem.FixedQuantity,
@Aggregation.default: #SUM
@Semantics: { quantity : {unitOfMeasure: 'CostSourceUnit'} }
I_GLAccountLineItem.ValuationFixedQuantity,
////////////////////////////////////
///////////////////////////////////////////////////////////////////////////////
// Fields from associations
///////////////////////////////////////////////////////////////////////////////
I_GLAccountLineItem.CalendarYear,
@ObjectModel.foreignKey.association: '_CalendarQuarter'
I_GLAccountLineItem.CalendarQuarter,
I_GLAccountLineItem.CalendarYearQuarter,
@ObjectModel.foreignKey.association: '_CalendarMonth'
I_GLAccountLineItem.CalendarMonth,
@ObjectModel.foreignKey.association: '_CalendarYearMonth'
I_GLAccountLineItem.CalendarYearMonth,
I_GLAccountLineItem.CalendarWeek,
I_GLAccountLineItem.CalendarYearWeek,
I_GLAccountLineItem._FiscalCalendarDate.FiscalQuarter as FiscalQuarter,
I_GLAccountLineItem._FiscalCalendarDate.FiscalWeek as FiscalWeek,
I_GLAccountLineItem._FiscalCalendarDate.FiscalYearQuarter as FiscalYearQuarter,
I_GLAccountLineItem._FiscalCalendarDate.FiscalYearWeek as FiscalYearWeek,
///////////////////////////////////////////////////////////////////////////////
// Associations
///////////////////////////////////////////////////////////////////////////////
I_GLAccountLineItem._JournalEntry,
_OperationalAcctgDocItem,
I_GLAccountLineItem._CompanyCode,
I_GLAccountLineItem._FiscalYear,
I_GLAccountLineItem._FiscalPeriodForVariant,
I_GLAccountLineItem._LedgerFiscalYearForVariant,
I_GLAccountLineItem._FiscalYearVariant,
I_GLAccountLineItem._FiscalYearPeriodForVariant,
I_GLAccountLineItem._ControllingArea,
I_GLAccountLineItem._BalanceTransactionCurrency,
I_GLAccountLineItem._TransactionCurrency,
I_GLAccountLineItem._CompanyCodeCurrency,
I_GLAccountLineItem._GlobalCurrency,
I_GLAccountLineItem._FunctionalCurrency,
I_GLAccountLineItem._FreeDefinedCurrency1,
I_GLAccountLineItem._FreeDefinedCurrency2,
I_GLAccountLineItem._FreeDefinedCurrency3,
I_GLAccountLineItem._FreeDefinedCurrency4,
I_GLAccountLineItem._FreeDefinedCurrency5,
I_GLAccountLineItem._FreeDefinedCurrency6,
I_GLAccountLineItem._FreeDefinedCurrency7,
I_GLAccountLineItem._FreeDefinedCurrency8,
I_GLAccountLineItem._BaseUnit,
I_GLAccountLineItem._CostSourceUnit,
I_GLAccountLineItem._AdditionalQuantity1Unit,
I_GLAccountLineItem._AdditionalQuantity2Unit,
I_GLAccountLineItem._AdditionalQuantity3Unit,
I_GLAccountLineItem._Segment,
I_GLAccountLineItem._ProfitCenter,
I_GLAccountLineItem._CurrentProfitCenter,
I_GLAccountLineItem._CostCenter,
I_GLAccountLineItem._CurrentCostCenter,
I_GLAccountLineItem._AccountAssignmentType,
I_GLAccountLineItem._Company,
_ProjectBasicData,
_ProjectExternalID,
_WBSElementBasicData,
_WBSElementExternalID,
I_GLAccountLineItem._Product,
I_GLAccountLineItem._SoldProduct,
I_GLAccountLineItem._SoldProductGroup_2 as _SoldProductGroup,
I_GLAccountLineItem._ProductGroup_2 as _ProductGroup,
I_GLAccountLineItem._SalesDocument,
I_GLAccountLineItem._SalesDocumentItem,
I_GLAccountLineItem._InternalOrder,
I_GLAccountLineItem._Order,
I_GLAccountLineItem._FunctionalArea,
I_GLAccountLineItem._OrderCategory,
I_GLAccountLineItem._GLAccountInChartOfAccounts,
I_GLAccountLineItem._GLAccountInCompanyCode,
I_GLAccountLineItem._ChartOfAccounts,
I_GLAccountLineItem._AccountingDocumentType,
I_GLAccountLineItem._FinancialAccountType,
I_GLAccountLineItem._DebitCreditCode,
I_GLAccountLineItem._Plant,
I_GLAccountLineItem._Ledger,
I_GLAccountLineItem._SourceLedger,
I_GLAccountLineItem._Customer,
I_GLAccountLineItem._CustomerCompany,
I_GLAccountLineItem._CustomerGroup,
I_GLAccountLineItem._Supplier,
I_GLAccountLineItem._SupplierCompany,
I_GLAccountLineItem._PostingKey,
I_GLAccountLineItem._SubLedgerAccLineItemType as _SubldgrAccountLineItemType,
I_GLAccountLineItem._AccountingDocumentCategory,
I_GLAccountLineItem._FinancialTransactionType,
I_GLAccountLineItem._BusinessTransactionCategory,
I_GLAccountLineItem._BusinessTransactionType,
I_GLAccountLineItem._ReferenceDocumentType,
I_GLAccountLineItem._PredecessorReferenceDocType,
I_GLAccountLineItem._User,
I_GLAccountLineItem._GLAccountType,
I_GLAccountLineItem._OffsettingAccountType,
I_GLAccountLineItem._OffsettingChartOfAccounts,
I_GLAccountLineItem._OffsettingAccount,
I_GLAccountLineItem._OffsettingAccountWithBP,
I_GLAccountLineItem._AlternativeGLAccount,
I_GLAccountLineItem._CountryChartOfAccounts,
_CorporateGroupChartOfAccounts,
_CorporateGroupAccount,
// I_GLAccountLineItem._PurchasingDocument,
// I_GLAccountLineItem._PurchasingDocumentItem,
I_GLAccountLineItem._SpecialGLCode,
I_GLAccountLineItem._ClearingJrnlEntryFiscalYear,
I_GLAccountLineItem._ClearingJournalEntry,
I_GLAccountLineItem._MasterFixedAsset,
I_GLAccountLineItem._FixedAsset,
I_GLAccountLineItem._MovementCategory,
I_GLAccountLineItem._AssetTransactionType,
I_GLAccountLineItem._BillingDocumentType,
I_GLAccountLineItem._SalesOrganization,
I_GLAccountLineItem._DistributionChannel,
I_GLAccountLineItem._Division,
I_GLAccountLineItem._CustomerSupplierCountry,
I_GLAccountLineItem._SalesDistrict,
I_GLAccountLineItem._BillToParty,
I_GLAccountLineItem._ShipToParty,
_CalendarMonth,
_CalendarQuarter,
_CalendarYearMonth,
_ValuationArea,
I_GLAccountLineItem._ServiceDocumentType,
I_GLAccountLineItem._ServiceDocument,
I_GLAccountLineItem._ServiceDocumentItem
//_Extension Extensions must be local
}