I_JointVentureCashCallFDP

@AbapCatalog.sqlViewName: 'IJVCCFDP'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'CDS View for Cash Call OCF'
@VDM.viewType: #COMPOSITE
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@AccessControl.personalData.blocking: #REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE


define view I_JointVentureCashCallFDP as select from    I_GLAccountLineItem  as _GLAccountLineItem
inner join      I_JntVntrCoCodeParam  as _JV_Company
                                      on _GLAccountLineItem.CompanyCode = _JV_Company.CompanyCode
left outer join FCLM_BAM_T012K_BASE   as _Company_Bank_Acc
                                      on _GLAccountLineItem.CompanyCode      = _Company_Bank_Acc.bukrs
                                     and _GLAccountLineItem.HouseBank        = _Company_Bank_Acc.hbkid
                                     and _GLAccountLineItem.HouseBankAccount = _Company_Bank_Acc.hktid
  //association [1..1] to I_Ledger as _Ledger

  //                               on _GLAccountLineItem.Ledger = _Ledger.Ledger


association [1] to I_Customer        as _Partner
                                     on _GLAccountLineItem.Customer = _Partner.Customer

association [1] to I_Customer        as _Operator
                                     on _JV_Company.Operator = _Operator.Customer

association [1] to I_Housebank       as _Company_Bank
                                     on _GLAccountLineItem.CompanyCode = _Company_Bank.CompanyCode
                                    and _GLAccountLineItem.HouseBank   = _Company_Bank.HouseBank

{
      //_GLAccountLineItem

  key _GLAccountLineItem.Ledger                                   as Ledger,
  key _GLAccountLineItem.CompanyCode                              as CompanyCode,
  key _GLAccountLineItem.FiscalYear                               as FiscalYear,
  key _GLAccountLineItem.AccountingDocument                       as AccountingDocument,
  key _GLAccountLineItem.LedgerGLLineItem                        as JournalEntryItem,
      cast( concat( AccountingDocument,
        concat( _GLAccountLineItem.CompanyCode,
          concat( FiscalYear, _GLAccountLineItem.Customer  ) )
           ) as apoc_appl_object_id )                             as OutputControlApplicationObject,           
      _GLAccountLineItem.Customer                                 as JointVenturePartner,
      PostingDate                                                 as PostingDate,
      DocumentDate                                                as DocumentDate,
      FiscalPeriod                                                as PostingPeriod,

      // Start of Customer Fields

      _Partner.BPCustomerName                                     as JointVenturePartnerName,
      _Partner.TelephoneNumber1                                   as JntVntrPartnerTelephoneNumber1,
      _Partner.FaxNumber                                          as JntVntrPartnerFaxNumber,
      _Partner.Country                                            as JntVntrPartnerCountry,
      _Partner.AddressID                                          as JntVntrPartnerAddressID,
      _Partner.Language                                           as Language,
      _Partner._StandardAddress._DefaultEmailAddress.EmailAddress as EmailAddress,

      // Start of Operator Fields

      _Operator.Customer                                          as JointVentureOperator,
      _Operator.BPCustomerName                                    as JointVentureOperatorName,
      _Operator.TelephoneNumber1                                  as JntVntrOptrTelephoneNumber1,
      _Operator.FaxNumber                                         as JntVntrOptrFaxNumber,
      _Operator.Country                                           as JntVntrOptrCountry,
      _Operator.AddressID                                         as JntVntrOptrAddressID,

      // Bank Details

      _Company_Bank.BankInternalID                                as BankInternalID,
      _Company_Bank._Bank.BankName                                as BankName,
      _Company_Bank._Bank.CityName                                as CityName,
      _Company_Bank._Bank.SWIFTCode                               as SWIFTCode,
      _Company_Bank_Acc.bankn                                     as BankAccount

      //    _association_name // Make association public


}where JointVentureAccountingActivity = 'CC' and DebitCreditCode = 'S' and _GLAccountLineItem._Ledger.IsLeadingLedger = 'X'