I_JITOutbCallCompGrpData

@AbapCatalog.sqlViewName: 'IJITOUTBCALLCGRP'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true

@ClientHandling: {
  type: #INHERITED,
  algorithm: #SESSION_VARIABLE
}

@AccessControl: {
  authorizationCheck: #NOT_REQUIRED,
  personalData.blocking: #NOT_REQUIRED
}

@VDM: {
  viewType: #COMPOSITE,
  lifecycle.contract.type: #PUBLIC_LOCAL_API
}

@ObjectModel: {
  usageType.dataClass: #TRANSACTIONAL,
  usageType.serviceQuality: #C,
  usageType.sizeCategory: #XL
}

@EndUserText.label: 'Composite View-JIT Call CompGrp Outbound'

@AccessControl.privilegedAssociations: ['_ProductionSupplyArea' ]

define view I_JITOutbCallCompGrpData
  as select from I_JITOutbCallCompGrp as _JITOutbCallCompGrp
    inner join   I_JITControlCycle    as _JITControlCycle on(
      _JITOutbCallCompGrp.JITControlCycle = _JITControlCycle.JITControlCycle
      and _JITOutbCallCompGrp.Plant       = _JITControlCycle.Plant
    )
  association [1..1] to I_JITOutbCallHeader as _JITOutbCallHeader on  $projection.ParentDraftKey        = _JITOutbCallHeader.JITHeaderUUID
                                                                  and $projection.InternalJITCallNumber = _JITOutbCallHeader.InternalJITCallNumber
association [0..1] to I_JITOutbPlngProcedure        as _JITPlngProcedure            on  $projection.ReplnmtPlanningProcedure = _JITPlngProcedure.JITPlanningProcedure
{
  key JITCallCompGrpUUID,
  key InternalJITCallNumber,
      ParentDraftKey,
      CompGrpNumber,
      ExtCompGrpNumber,
      CompGrpMatl,
      CustCompGrpMatl,
      JITExtSequenceNumber,
      TransmittedExtStatusByMfr,
      JITExtStatusAtSupplier,
      JITExtStatusUpdtdOn,
      JITIntProcessingStatus,
      JITIntStatusUpdtdOn,
      RequirementDateTime,
      _JITOutbCallCompGrp.JITSupplyDateTime,
      _JITOutbCallCompGrp.Plant,
      CustSupplyArea,
      UnloadingPointName,
      SupplyControlID,
      SupplyControlUUID,
      _JITOutbCallCompGrp.JITActionCtrl,
      CustAssemblyLoc,
      ShippingPoint,
      _JITOutbCallCompGrp.StorageLocation,
      PlannedShippingDateTime,
      ActualShippingDateTime,
      MaterialAvailabilityDate,
      RequestedDeliveryDate,
      RequestedDeliveryTime,
      _JITOutbCallCompGrp.WarehouseNumber,
      //'' as EWMWarehouse,

      JITSourceWarehouseNumber,
//      DeliveryCreationDate,    

      cast(dats_tims_to_tstmp(RequestedDeliveryDate, RequestedDeliveryTime, abap_user_timezone($session.user, $session.client, 'NULL'), $session.client, 'NULL') as timestampl ) as RequestedDeliveryDateTime,
     
      case dats_is_valid(DeliveryCreationDate)
      when 1 then DeliveryCreationDate
      end as DeliveryCreationDate,
      
      /* Document Status Indicator */
      DeliveryStatus,
      PickingStatus,
      GoodsMovementStatus,
      JITOutbStockTransferSts,
      _JITOutbCallCompGrp.JITControlCycle,
      _JITControlCycle.JITReqQtyLowerToleranceLvl,
      _JITControlCycle.JITReqQtyUpperToleranceLvl,
      _JITOutbCallCompGrp.ProductionSupplyArea,
      JITOutbDestinationStorLoc,
      _JITOutbCallHeader.CreatedByUser,
      _JITOutbCallHeader.CreationDateTime,
      _JITOutbCallHeader.JITLifecycleStatus,
      _JITOutbCallHeader.JITCallType,
      _JITOutbCallHeader.VehicleIdentificationNumber,
      _JITOutbCallHeader.VehicleModel,
      _JITOutbCallHeader.JITIntSequenceNumber,
      _JITOutbCallHeader.LastChangeDateTime,
      _JITOutbCallHeader.LastChangedByUser,
      _JITOutbCallHeader.JITCallImmediateRequest,
      _JITOutbCallHeader.JITMissingPartFlag,
      _JITOutbCallHeader.JITCallPriorityType,
      _JITOutbCallHeader.JITCallPriorityID,
      _JITOutbCallHeader.JITCallProcessingLogID,
      _JITOutbCallHeader.JITPlannedOrderNumber,
      _JITOutbCallHeader.JITVehicleSeqDateTime,
      case
      when _JITOutbCallCompGrp.JITSupplyDateTime < TSTMP_CURRENT_UTCTIMESTAMP() and _JITOutbCallHeader.JITLifecycleStatus = '2' then 'Y'
      else 'N'
      end                                                                                                                                                                        as JITCallHasAlert,
      cast( ' ' as matnr)                                                                                                                                                        as Material,
      cast( ' ' as ebeln )                                                                                                                                                       as SchedulingAgreement,

      _JITControlCycle.ReplenishmentStrategy,
      cast('' as /scwm/lgnum )                                                                                                                                                   as EWMWarehouse,
      _JITControlCycle.SourceStorageBin,
      cast('' as abap.char(5))                                                                                                                                                   as SourceStorageType,
      _JITControlCycle.StorageBin,
      _JITControlCycle.StorageType,
      _JITControlCycle.ReplnmtPlanningProcedure,
      _JITPlngProcedure._Text[1: Language = $session.system_language].JITPlanningProcedureText,
      _ProductionSupplyArea._Text[1: Language = $session.system_language].ProductionSupplyAreaName,
      cast('' as /scwm/de_desc40 )                                                                                                                                               as WarehouseName,
      case when _JITControlCycle.ExtProcurementReplnmtStrgy = ''
      then cast ('' as njit_ext_repl_ind preserving type)
      else cast ('X' as njit_ext_repl_ind preserving type) end                                                                                                                   as JITExternalReplenishment,

      case when _JITControlCycle.ExtProcurementReplnmtStrgy = ''
       then cast ('X' as njit_ext_repl_ind preserving type)
       else cast ('' as njit_ext_repl_ind preserving type) end                                                                                                                   as JITInternalReplenishment,

      _JITControlCycle.IssuingOrReceivingStorageLoc,
      _JITControlCycle._ProductionSupplyArea.AutomotiveLoadingPoint,
      _JITControlCycle.Supplier,
       _JITControlCycle.SupplierName,
      cast('' as bu_partner)                                                                                                                                                     as BusinessPartner,
      cast('' as bu_partner)                                                                                                                                                     as BusinessPartner1,
      cast('' as bu_partner)                                                                                                                                                     as BusinessPartner2,
      case ReplnmtLeadTimeInHours
      when '0' then '00'
      else ReplnmtLeadTimeInHours
      end                                                                                                                                                                        as BufferLeadTime,
      case ReplnmtLeadTimeInMinutes
      when '0' then '00'
      when '1' then '01'
      when '2' then '02'
      when '3' then '03'
      when '4' then '04'
      when '5' then '05'
      when '6' then '06'
      when '7' then '07'
      when '8' then '08'
      when '9' then '09'
      else ReplnmtLeadTimeInMinutes
      end                                                                                                                                                                        as PlannedDurationInMinutes,
      // Associations

      _ProductCompGrp,
      _JITInternalStatus,
      _Plant,
      _JITOutbCallHeader,
      // _JITOutbCallCompMatl,

      _ProductionSupplyArea,
      _StorageLocation

}