I_JITCompGrpDocStatus

@AbapCatalog.entityBuffer.definitionAllowed: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@Analytics.technicalName: 'IJITCGDSTATUS'
@EndUserText.label: 'JIT Component Grp Doc Stats: Basic View'
@ObjectModel.usageType.serviceQuality: #A
@ObjectModel.usageType.sizeCategory: #S
@ObjectModel.usageType.dataClass: #CUSTOMIZING
@ObjectModel.representativeKey: 'JITCompGrpDocStatus'
@ObjectModel.dataCategory: #TEXT
@ObjectModel.resultSet.sizeCategory: #XS
@Search.searchable: true
@VDM.viewType: #BASIC

/*+[hideWarning] { "IDS" : [ "KEY_CHECK" ] }*/
/*+[hideWarning] { "IDS" : [ "KEY_CHECK/code>*/
define view entity I_JITCompGrpDocStatus
  as select from dd07l

  association [0..*] to I_JITCompGrpDocStatusText as _Text            on $projection.JITCompGrpDocStatus = _Text.JITCompGrpDocStatus

  association [0..*] to I_JITCompGrpDocStatusText as _RelToProdnText  on $projection.JITCompGrpDocRelToProdnSts = _RelToProdnText.JITCompGrpDocRelToProdnSts

  association [0..*] to I_JITCompGrpDocStatusText as _ConfToProdnText on $projection.JITCompGrpDocConfToProdnSts = _ConfToProdnText.JITCompGrpDocConfToProdnSts

  association [0..*] to I_JITCompGrpDocStatusText as _GdsMvtText      on $projection.JITCompGrpDocGdsMvtSts = _GdsMvtText.JITCompGrpDocGdsMvtSts

  association [0..*] to I_JITCompGrpDocStatusText as _PkgGrpText      on $projection.JITCompGrpDocPckgGrpSts = _PkgGrpText.JITCompGrpDocPckgGrpSts
{

        /*==========================================================================================*/
        // Technical Keys 

        /*------------------------------------------------------------------------------------------*/
         @ObjectModel.text.association: '_Text'
         @Search.defaultSearchElement: true
         @Search.ranking: #HIGH
  key    domvalue_l                                                                   as JITCompGrpDocStatus,

         @ObjectModel.text.association: '_RelToProdnText'
  key    cast ( substring( domvalue_l,1,1 ) as njit_r2p_stat preserving type )        as JITCompGrpDocRelToProdnSts,

         @ObjectModel.text.association: '_ConfToProdnText'
  key    cast ( substring( domvalue_l,1,1 ) as njit_cp_stat preserving type )         as JITCompGrpDocConfToProdnSts,

         @ObjectModel.text.association: '_GdsMvtText'
  key    cast ( substring( domvalue_l,1,1 ) as njit_goods_mvmt_stat preserving type ) as JITCompGrpDocGdsMvtSts,

         @ObjectModel.text.association: '_PkgGrpText'
  key    cast ( substring( domvalue_l,1,1 ) as njit_pkg_grp_stat preserving type )    as JITCompGrpDocPckgGrpSts,

         /*==========================================================================================*/
         
          
         /*==========================================================================================*/
         // Associations

         /*------------------------------------------------------------------------------------------*/
         _Text,
         _RelToProdnText,
         _ConfToProdnText,
         _GdsMvtText,
         _PkgGrpText

}
where
      dd07l.domname  = 'NJIT_STATUS'
  and dd07l.as4local = 'A'