I_IssueDocumentCategoryText

@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'Document Category Causing Issue - Text'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType:{
  serviceQuality: #X,
  sizeCategory: #S,
  dataClass: #MIXED
}
@ObjectModel.dataCategory: #TEXT
@ObjectModel.representativeKey: 'IssueDocumentCategory'
@VDM.viewType: #BASIC
@Search.searchable: true


define view entity I_IssueDocumentCategoryText 
as select from dd07t 
association[0..1] to I_IssueDocumentCategory as _IssueDocumentCategory on $projection.IssueDocumentCategory = _IssueDocumentCategory.IssueDocumentCategory
association[0..1] to I_Language as _Language on $projection.Language = _Language.Language
{
    @ObjectModel.foreignKey.association: '_IssueDocumentCategory'
    key cast(substring(dd07t.domvalue_l, 1, 4) as issuedocumentcategory_sof preserving type) as IssueDocumentCategory,
          
    @ObjectModel.foreignKey.association: '_Language'
    @Semantics.language: true
    key ddlanguage as Language,
    
    @Search.defaultSearchElement: true
    @Search.fuzzinessThreshold: 0.8     
    @Semantics.text: true
    @Search.ranking: #LOW 
    cast(ddtext as issuedocumentcategoryname preserving type) as IssueDocumentCategoryName,

    @Consumption.hidden: true
    dd07t.domvalue_l as DomainValue, 
       
    //Associations

    _IssueDocumentCategory,
    _Language
}
where (domname = 'ISSUEDOCUMENTCATEGORY_SOF') and (as4local = 'A');