I_IssueChangeReq

@AbapCatalog.sqlViewName: 'ISSUECHANGREQ'
@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.compiler.compareFilter: true
@ObjectModel.usageType.dataClass: #MIXED
@ObjectModel.usageType.serviceQuality: #B
@ObjectModel.usageType.sizeCategory: #XL
@AccessControl.authorizationCheck: #CHECK
@VDM.viewType: #BASIC
@EndUserText.label: 'Issue Change Request'

define view I_IssueChangeReq
  as select from I_MasterProject as MasterProject
    inner join   P_RootNode      as IssueRefNode  on MasterProject.ProjectUUID = IssueRefNode.id
    inner join   P_PICMStatus    as IssueStatuses on  IssueRefNode.application    = IssueStatuses.application
                                                  and IssueRefNode.issue_category = IssueStatuses.category
                                                  and IssueRefNode.issue_type     = IssueStatuses.type
                                                  and IssueRefNode.stat_cd        = IssueStatuses.stacd
{

  MasterProject.MasterProjectUUID,
  MasterProject.ProjectUUID,
 // MasterProject.MasterProjectUUID_E,

  MasterProject.MasterProject,
  MasterProject.MasterProjectName,
  MasterProject.MasterProjectType,
  MasterProject.MasterProjectStage,
  MasterProject.StartDate,
  MasterProject.EndDate,
  MasterProject.Customer,
  MasterProject.MasterProjectOrganization,
  MasterProject.MasterProjectIsConfidential,
  MasterProject.Country,
  MasterProject.Region,
  MasterProject.WorkType,
  MasterProject.Industry,
  MasterProject.ProjectRisk,
  MasterProject.FinancialRisk,
  MasterProject.TechnicalRisk,
  MasterProject.OverallRisk,
  //  IssueRefNode.id                           as MasterProjectUUID,

  cast(case
  when IssueRefNode.issue_category = 'ICH' then 1
  else 0
  end as int4) as ChangeRequest,
  cast(case
  when IssueRefNode.issue_category = 'ICM' then 1
  else 0
  end as int4) as Issue

}
where
       IssueRefNode.application      =  'ICM'
  and(
       IssueRefNode.issue_category   =  'ICM'
    or IssueRefNode.issue_category   =  'ICH'
  )
  and  IssueRefNode.archiving_status <> '02' // Exclude Archived Objects

  and(
       IssueStatuses.iam_status      =  '60'
    or IssueStatuses.iam_status      =  '05'
  ) // Show only New or In Process Issues/Change Requests

  and  IssueStatuses.exclude_in_list =  '' // Fliter issues based on exclude functionality