I_IntcoJrnlEntryForControlling

@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #MANDATORY
@EndUserText.label: 'Intercompany Journal Entry'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType:{
  serviceQuality: #X,
  sizeCategory: #S,
  dataClass: #MIXED
}
@VDM.viewType: #BASIC
@AccessControl.personalData.blocking: #REQUIRED
define view entity I_IntcoJrnlEntryForControlling
  as select from I_GLAccountLineItemRawData as _GLAccountLineItemRawData

    inner join   bkpf                       as _JournalEntryHeader on  _GLAccountLineItemRawData.AccountingDocument =  _JournalEntryHeader.belnr
                                                                   and _GLAccountLineItemRawData.CompanyCode        =  _JournalEntryHeader.bukrs
                                                                   and _GLAccountLineItemRawData.FiscalYear         =  _JournalEntryHeader.gjahr
                                                                   and _GLAccountLineItemRawData.CompanyCode        <> _JournalEntryHeader.ausbk

    inner join   I_Ledger                   as _Ledger             on _GLAccountLineItemRawData.SourceLedger = _Ledger.Ledger
{
  key _GLAccountLineItemRawData.AccountingDocument,
  key _GLAccountLineItemRawData.LedgerGLLineItem,
  key _GLAccountLineItemRawData.CompanyCode,
  key _GLAccountLineItemRawData.FiscalYear,
  key _GLAccountLineItemRawData.SourceLedger as Ledger,

      // FXUBRQ21-11282 : List of items

      @Semantics.quantity.unitOfMeasure: 'BaseUnit'
      _GLAccountLineItemRawData.Quantity,
      @Semantics.amount.currencyCode: 'TransactionCurrency'
      _GLAccountLineItemRawData.AmountInTransactionCurrency,
      _GLAccountLineItemRawData.TransactionCurrency,
      
      @Semantics.amount.currencyCode: 'GlobalCurrency'
      _GLAccountLineItemRawData.AmountInGlobalCurrency,
      _GLAccountLineItemRawData.GlobalCurrency,

      _GLAccountLineItemRawData.PartnerCostCtrActivityType,
      _GLAccountLineItemRawData.BaseUnit,

      _GLAccountLineItemRawData.CostAnalysisResource,
      _GLAccountLineItemRawData.PersonnelNumber,
      _GLAccountLineItemRawData.FunctionalArea,
      _GLAccountLineItemRawData.GLAccount,

      --RECEIVER DATA
      _GLAccountLineItemRawData.TimeSheetOvertimeCategory,

      _GLAccountLineItemRawData.FiscalPeriod,
      _GLAccountLineItemRawData.PostingDate,

      _GLAccountLineItemRawData.AccountAssignmentType,
      _GLAccountLineItemRawData.ProfitCenter,
      _GLAccountLineItemRawData._ProjectBasicData.ProjectExternalID,
      _GLAccountLineItemRawData.ServiceDocument,
      _GLAccountLineItemRawData.ServiceDocumentType,
      _GLAccountLineItemRawData._WBSElementBasicData.WBSElementExternalID,
      _GLAccountLineItemRawData.ReferenceDocument,
      _GLAccountLineItemRawData.ReferenceDocumentItem,

      --SENDER DATA??
      case when _GLAccountLineItemRawData.PartnerCompanyCode is not initial
              then _GLAccountLineItemRawData.PartnerCompanyCode
              else _JournalEntryHeader.ausbk
           end                               as PartnerCompanyCode,
      _GLAccountLineItemRawData.PartnerCostCenter,
      _GLAccountLineItemRawData.PartnerProfitCenter,
      _GLAccountLineItemRawData.WorkItem,
      _GLAccountLineItemRawData.ControllingBusTransacType,


      --Necessary exposures for foreign keys
      _GLAccountLineItemRawData.WBSElementInternalID,
      @Semantics.fiscal.yearVariant: true
      _GLAccountLineItemRawData.FiscalYearVariant,
      @Semantics.fiscal.year: true
      _GLAccountLineItemRawData.LedgerFiscalYear,
      _GLAccountLineItemRawData.ProjectInternalID,
      _GLAccountLineItemRawData.CostCenter,
      _GLAccountLineItemRawData.ControllingArea,
      _GLAccountLineItemRawData.ChartOfAccounts,

      _GLAccountLineItemRawData._CompanyCode,
      _GLAccountLineItemRawData._JournalEntry,
      _GLAccountLineItemRawData._FiscalYear,
      _GLAccountLineItemRawData._FiscalPeriodForVariant,
      _GLAccountLineItemRawData._FiscalYearVariant,
      _GLAccountLineItemRawData._LedgerFiscalYearForVariant,

      _GLAccountLineItemRawData._ProjectBasicData,
      _GLAccountLineItemRawData._WBSElementBasicData,
      _GLAccountLineItemRawData._ServiceDocument,
      _GLAccountLineItemRawData._CostCenter,
      _GLAccountLineItemRawData._ControllingArea,
      _GLAccountLineItemRawData._GLAccountInChartOfAccounts,
      _GLAccountLineItemRawData._ChartOfAccounts,

      _GLAccountLineItemRawData._PartnerCostCtrActivityType
}
where
          _Ledger.IsLeadingLedger                               =  'X'

  and(
          _GLAccountLineItemRawData.OriginCtrlgDebitCreditCode  =  'S'
  )
  and(
          _GLAccountLineItemRawData.AccountAssignmentType       =  'PR'
    or    _GLAccountLineItemRawData.AccountAssignmentType       =  'KS'
    or    _GLAccountLineItemRawData.AccountAssignmentType       =  'SV'
  )
  and     _GLAccountLineItemRawData.ControllingBusTransacType   <> 'RKLN'
  and(
          _GLAccountLineItemRawData.ControllingBusTransacType   <> 'RKU2'
    and   _GLAccountLineItemRawData.BusinessTransactionCategory <> 'RKU2'
  )
  and(
    (
          _JournalEntryHeader.ausbk                             is not null
      and _JournalEntryHeader.ausbk                             <> ''
      and _JournalEntryHeader.ausbk                             <> _GLAccountLineItemRawData.CompanyCode
    )
    or(
          _GLAccountLineItemRawData.PartnerCompanyCode          is not null
      and _GLAccountLineItemRawData.PartnerCompanyCode          <> ''
      and _GLAccountLineItemRawData.CompanyCode                 <> _GLAccountLineItemRawData.PartnerCompanyCode
    )
  )
  //  and     _GLAccountLineItemRawData.co_belnr is not null and _GLAccountLineItemRawData.co_belnr <> '' - Not available

  and     _GLAccountLineItemRawData.ControllingDocumentItem     is not null
  and     _GLAccountLineItemRawData.ControllingDocumentItem     <> '000'
  and(
          _GLAccountLineItemRawData.ControllingBusTransacType   <> 'COIN'
    or(
          _GLAccountLineItemRawData.ControllingBusTransacType   =  'COIN'
      and _GLAccountLineItemRawData.ReferenceDocumentType       =  'CTE'
    )
  )