I_InsurancePolicyDatePhaseT

DDL: I_INSURANCEPOLICYDATEPHASET Type: view_entity BASIC Package: VDM_PM_PLCY_AUXILIARY

Date phase in insurance policy - Text

I_InsurancePolicyDatePhaseT is a Basic CDS View that provides data about "Date phase in insurance policy - Text" in SAP S/4HANA. It reads from 1 data source (dd07t) and exposes 6 fields with key fields Language, InsurPlcyDatePerfPhaseType. It has 1 association to related views. Part of development package VDM_PM_PLCY_AUXILIARY.

1 data source(s) 6 fields

Data Sources (1)

SourceAliasJoin Type
dd07t dd07t from

Associations (1)

CardinalityTargetAliasCondition
[0..1] I_Language _Language $projection.Language = _Language.Language

Annotations (13)

NameValueLevelField
AccessControl.authorizationCheck #NOT_REQUIRED view
EndUserText.label Date phase in insurance policy - Text view
VDM.viewType #BASIC view
VDM.lifecycle.contract.type #PUBLIC_LOCAL_API view
ObjectModel.dataCategory #TEXT view
ObjectModel.modelingPattern #LANGUAGE_DEPENDENT_TEXT view
ObjectModel.representativeKey InsurPlcyDatePerfPhaseType view
ObjectModel.usageType.serviceQuality #A view
ObjectModel.usageType.dataClass #CUSTOMIZING view
ObjectModel.usageType.sizeCategory #S view
Search.searchable true view
Analytics.dataExtraction.enabled true view
Metadata.ignorePropagatedAnnotations true view

Fields (6)

KeyFieldSource TableSource FieldDescription
KEY Language
KEY InsurPlcyDatePerfPhaseType
DomainValue dd07t domvalue_l
InsurPlcyDatePhaseName dd07t ddtext
_DatePhase _DatePhase
_Language _Language 
@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'Date phase in insurance policy - Text'
@VDM: {
  viewType:#BASIC,
  lifecycle.contract.type:#PUBLIC_LOCAL_API
}
@ObjectModel: {
  dataCategory: #TEXT,
  modelingPattern: #LANGUAGE_DEPENDENT_TEXT,
  representativeKey:'InsurPlcyDatePerfPhaseType',
  usageType.serviceQuality: #A,
  usageType.dataClass: #CUSTOMIZING,
  usageType.sizeCategory: #S,
  supportedCapabilities: [#CDS_MODELING_ASSOCIATION_TARGET,
                          #CDS_MODELING_DATA_SOURCE,
                          #EXTRACTION_DATA_SOURCE,
                          #LANGUAGE_DEPENDENT_TEXT,
                          #SEARCHABLE_ENTITY,
                          #SQL_DATA_SOURCE]
}
@Search.searchable: true
@Analytics.dataExtraction.enabled: true
@Metadata.ignorePropagatedAnnotations: true

define view entity I_InsurancePolicyDatePhaseT
  as select from dd07t
  association        to parent I_InsurancePolicyDatePhase as _DatePhase on $projection.InsurPlcyDatePerfPhaseType = _DatePhase.InsurPlcyDatePerfPhaseType
  association [0..1] to I_Language                        as _Language  on $projection.Language = _Language.Language
{
      @ObjectModel.foreignKey.association: '_Language'
      @Semantics.language: true
  key cast( dd07t.ddlanguage as spras preserving type ) as Language,
      @ObjectModel.foreignKey.association: '_DatePhase'
      @ObjectModel.text.element: ['InsurPlcyDatePhaseName']
  key cast( dd07t.domvalue_l as /pm0/abd_phase_vl )     as InsurPlcyDatePerfPhaseType,
      @Analytics.hidden: true
      @Consumption.hidden: true
      dd07t.domvalue_l                                  as DomainValue,
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #LOW
      @Semantics.text: true
      dd07t.ddtext                                      as InsurPlcyDatePhaseName,
      _DatePhase,
      _Language
}
where
      dd07t.domname  = '/PM0/ABD_PHASE_VL'
  and dd07t.as4local = 'A'
  and dd07t.as4vers  = '0000'

Learn More