I_InsurPlcyCoveragePackage

@EndUserText.label: 'Coverage Package in Insurance Policy'
@VDM: {
  viewType:#COMPOSITE,
  lifecycle.contract.type:#PUBLIC_LOCAL_API
}
@AccessControl: {
  authorizationCheck: #PRIVILEGED_ONLY,
  personalData.blocking: #('TRANSACTIONAL_DATA'),
  privilegedAssociations:  [  '_InsurancePolicyCoverage',
                              '_InsurPlcyCvrgPckgClause',
                              '_InsurPlcyCvrgPckgSurchrgDisc',
                              '_InsurPlcyCvrgPckgInsrdObject',
                              '_InsurPlcyCvrgPckgPlndProcg']
}
@ObjectModel: {
   representativeKey: 'InsurPlcyCoveragePackageID',
   semanticKey: [ 'InsurPlcyCoveragePackageID' ],
   usageType: {
     dataClass:      #TRANSACTIONAL,
     serviceQuality: #C,
     sizeCategory:   #L
   },
   supportedCapabilities: [ #CDS_MODELING_DATA_SOURCE ]
}
@Metadata: {
  allowExtensions:false,
  ignorePropagatedAnnotations:false
}
@Analytics: {
  technicalName: 'IPPlcyCvrgPckg'
}

define view entity I_InsurPlcyCoveragePackage
  as select from I_InsurPlcyCvrgPackageBasic as CoveragePackage

  association        to parent I_InsuranceContract     as _InsuranceContract      on  $projection.InsurPlcyUUID       = _InsuranceContract.InsurPlcyUUID
                                                                                  and $projection.InsurPlcyInsurContr = _InsuranceContract.InsurPlcyInsurContr

  composition [1..*] of I_InsurancePolicyCoverage      as _InsurancePolicyCoverage
  composition [0..*] of I_InsurPlcyCvrgPckgClause      as _InsurPlcyCvrgPckgClause
  composition [0..*] of I_InsurPlcyCvrgPckgInsrdObject as _InsurPlcyCvrgPckgInsrdObject
  composition [0..*] of I_InsurPlcyCvrgPckgSurchrgDisc as _InsurPlcyCvrgPckgSurchrgDisc
  composition [0..*] of I_InsurPlcyCvrgPckgPlndProcg   as _InsurPlcyCvrgPckgPlndProcg 

  association [1..*] to I_InsurPlcyTemplateT           as _InsurPlcyTemplateT     on  $projection.InsurPlcyCvrgPackageTemplate = _InsurPlcyTemplateT.InsurPlcyTemplate
  association [1..1] to I_InsurContrCanclnReason       as _InsurContrCanclnReason on  $projection.InsurPlcyCvrgPckgCanclnReason = _InsurContrCanclnReason.InsurContrCanclnRsn

{

  key CoveragePackage.InsurPlcyUUID,
  key CoveragePackage.InsurPlcyInsurContr,
  key CoveragePackage.InsurPlcyCoveragePackageID,
      CoveragePackage.InsurPlcyJrnlNmbr,
      CoveragePackage.InsurPlcyJrnlEndNmbr,
      @ObjectModel.text.association: '_InsurPlcyTemplateT'
      // @ObjectModel.sapObjectNodeTypeReference: 'InsurancePolicyTemplate'

      CoveragePackage.InsurPlcyCvrgPackageTemplate,
      CoveragePackage.InsurPlcyProductPackageID,
      @ObjectModel.foreignKey.association: '_InsurContrCanclnReason'
      @ObjectModel.sapObjectNodeTypeReference: 'InsurContrCancellationReason'
      CoveragePackage.InsurPlcyCvrgPckgCanclnReason,
      @Semantics.dateTime:true
      CoveragePackage.InsurPlcyCvrgPckgCanclnDteTime,
      @Semantics.systemDateTime.lastChangedAt: true
      CoveragePackage.LastChangeDateTime,

      /* Associations */
      _InsuranceContract,
      _InsurancePolicyCoverage,
      _InsurPlcyCvrgPckgClause,
      _InsurPlcyCvrgPckgInsrdObject,
      _InsurPlcyCvrgPckgSurchrgDisc,
      _InsurPlcyCvrgPckgPlndProcg,

      @Consumption.hidden: true
      _InsurPlcyTemplateT,
      @Consumption.hidden: true
      _InsurContrCanclnReason

}
where
      CoveragePackage.InsurPlcyJrnlEndNmbr    = 2147483647
  and CoveragePackage.InsurPlcyBusinessObject = 'P'