I_InsurContrLifeCycleStatusT

DDL: I_INSURCONTRLIFECYCLESTATUST Type: view_entity BASIC Package: VDM_PM_PLCY_AUXILIARY

Life Cycle Sts for Contr in Plcy - Txt

I_InsurContrLifeCycleStatusT is a Basic CDS View that provides data about "Life Cycle Sts for Contr in Plcy - Txt" in SAP S/4HANA. It reads from 1 data source (dd07t) and exposes 6 fields with key fields Language, InsurContrLifeCycSts. It has 1 association to related views. Part of development package VDM_PM_PLCY_AUXILIARY.

1 data source(s) 6 fields

Data Sources (1)

SourceAliasJoin Type
dd07t dd07t from

Associations (1)

CardinalityTargetAliasCondition
[0..1] I_Language _Language $projection.Language = _Language.Language

Annotations (13)

NameValueLevelField
EndUserText.label Life Cycle Sts for Contr in Plcy - Txt view
VDM.viewType #BASIC view
VDM.lifecycle.contract.type #PUBLIC_LOCAL_API view
AccessControl.authorizationCheck #NOT_REQUIRED view
Analytics.dataExtraction.enabled true view
Metadata.ignorePropagatedAnnotations true view
ObjectModel.dataCategory #TEXT view
ObjectModel.modelingPattern #LANGUAGE_DEPENDENT_TEXT view
ObjectModel.representativeKey InsurContrLifeCycSts view
ObjectModel.usageType.serviceQuality #A view
ObjectModel.usageType.dataClass #CUSTOMIZING view
ObjectModel.usageType.sizeCategory #S view
Search.searchable true view

Fields (6)

KeyFieldSource TableSource FieldDescription
KEY Language
KEY InsurContrLifeCycSts
DomainValue dd07t domvalue_l
InsurContrLifeCycStsName dd07t ddtext
_InsurContrLifeCycleStatus _InsurContrLifeCycleStatus
_Language _Language 
@EndUserText.label: 'Life Cycle Sts for Contr in Plcy - Txt'
@VDM: {
  viewType:#BASIC,
  lifecycle.contract.type:#PUBLIC_LOCAL_API
}
@AccessControl.authorizationCheck: #NOT_REQUIRED
@Analytics.dataExtraction.enabled: true
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel: {
  dataCategory: #TEXT,
  modelingPattern: #LANGUAGE_DEPENDENT_TEXT,
  representativeKey: 'InsurContrLifeCycSts',
  usageType.serviceQuality: #A,
  usageType.dataClass: #CUSTOMIZING,
  usageType.sizeCategory: #S,
  supportedCapabilities: [#CDS_MODELING_ASSOCIATION_TARGET,
                          #CDS_MODELING_DATA_SOURCE,
                          #EXTRACTION_DATA_SOURCE,
                          #LANGUAGE_DEPENDENT_TEXT,
                          #SEARCHABLE_ENTITY,
                          #SQL_DATA_SOURCE]
}
@Search.searchable: true

define view entity I_InsurContrLifeCycleStatusT
  as select from dd07t
  association        to parent I_InsurContrLifeCycleStatus as _InsurContrLifeCycleStatus on $projection.InsurContrLifeCycSts = _InsurContrLifeCycleStatus.InsurContrLifeCycSts
  association [0..1] to I_Language                         as _Language                  on $projection.Language = _Language.Language

{

      @ObjectModel.foreignKey.association: '_Language'
      @Semantics.language: true
  key cast( dd07t.ddlanguage as spras preserving type )  as Language,
      @ObjectModel.foreignKey.association: '_InsurContrLifeCycleStatus'
      @ObjectModel.text.element: ['InsurContrLifeCycStsName']
  key cast( dd07t.domvalue_l as /pm0/abd_actinactst_cd ) as InsurContrLifeCycSts,
      @Analytics.hidden: true
      @Consumption.hidden: true
      dd07t.domvalue_l                                   as DomainValue,
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #LOW
      @Semantics.text: true
      dd07t.ddtext                                       as InsurContrLifeCycStsName,
      _InsurContrLifeCycleStatus,
      _Language
      
}
where
      dd07t.domname  = '/PM0/ABD_ACTINACTST_CD'
  and dd07t.as4local = 'A'
  and dd07t.as4vers  = '0000'

Learn More