I_InspectionSubsetTP

@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Inspection Point of Inspection Operation'
@VDM.viewType: #TRANSACTIONAL 
@AccessControl.privilegedAssociations:  [ '_CreatedByUser' ]
//@ObjectModel.representativeKey: 'InspectionSubsetInternalID'

@ObjectModel.usageType: { serviceQuality: #D, sizeCategory: #L, dataClass: #TRANSACTIONAL }

/* Draft 2.0 */
//@ObjectModel.modelCategory: #BUSINESS_OBJECT

@ObjectModel.semanticKey:  [ 'InspectionLot' , 'InspectionSubsetInternalID' , 'InspPlanOperationInternalID'  ]
@ObjectModel:{
    compositionRoot: true,
    createEnabled: true,
    updateEnabled: true,
    deleteEnabled: true,
    transactionalProcessingEnabled: true,
    draftEnabled: true,
    writeDraftPersistence: 'QINSPSUBSETRR_D',
    entityChangeStateId: 'ChangedDateTime',
    lifecycle.enqueue: {
        expiryBehavior: #RELATIVE_TO_LAST_CHANGE,  // Default #RELATIVE_TO_LAST_CHANGE

        expiryInterval: 'PT15M'                    // Default 'PT15M'

      //  notificationBeforeExpiryInterval: 'PT1M'   // Default 'PT5M'

    },
    lifecycle.processing: {
        expiryBehavior: #RELATIVE_TO_LAST_CHANGE,  // Default #RELATIVE_TO_LAST_CHANGE

        expiryInterval: 'PT30M'                       // Default 'PT30M'

      //  notificationBeforeExpiryInterval: 'PT3M'    // Default 'PT10M'

    }
}

define view entity I_InspectionSubsetTP 
  as select from I_InspectionSubset        as InspectionSubset
    left outer to one join P_InspUsgeDcsnSelectedSetCode as SelectedCodeSet   on  InspectionSubset.InspectionLot                   = SelectedCodeSet.InspectionLot
  association [0..*] to I_InspSubsetCharcResultTP as _InspSubsetCharcResult on  $projection.InspectionLot               = _InspSubsetCharcResult.InspectionLot
                                                                            and $projection.InspPlanOperationInternalID = _InspSubsetCharcResult.InspPlanOperationInternalID
                                                                            and $projection.InspectionSubsetInternalID  = _InspSubsetCharcResult.InspectionSubsetInternalID                                                                           
  association [1..1] to I_UserContactCard         as _CreatedByUser           on  $projection.UserID = _CreatedByUser.ContactCardID
  association [1..1] to I_UserContactCard         as _LastChangedByUser       on  $projection.ContactCardID = _LastChangedByUser.ContactCardID                                                                            


{
      @ObjectModel.foreignKey.association: '_InspectionLot'
  key InspectionSubset.InspectionLot,
      @ObjectModel.foreignKey.association: '_InspectionOperation'
  key InspectionSubset.InspPlanOperationInternalID,
  key InspectionSubset.InspectionSubsetInternalID,
      cast(InspectionSubset.InspectionLot as qplos preserving type )                  as InspectionLotForEdit,
      cast(InspectionSubset.InspPlanOperationInternalID as qlfnkn preserving type )   as InspectionOperationForEdit,
      InspectionSubset._InspectionOperation.InspectionOperation,
      //@ObjectModel.readOnly: true

      cast('' as abap.char( 2 ))                                     as InspSubsetStatus,
      InspectionSubset.InspectionSubsetSortKey,

      //@ObjectModel.readOnly: true

      cast ('' as abap.char(1333))                                   as InspectionOperations,
      // Field for E-tag

      @ObjectModel.readOnly: true
      InspectionSubset.ChangedDateTime,

      cast(00000 as qrastzfak)                                       as InspSubsetTimeInterval,
      cast('' as qrastzeht)                                          as InspSubsetTimeIntervalUnit,

      SelectedCodeSet.SelectedCodeSetPlant,
    //  @ObjectModel.foreignKey.association: '_SelectedCodeSet'

      SelectedCodeSet.SelectedCodeSet,
      @ObjectModel.foreignKey.association: '_UsageDecisionCodeGroup'
      InspectionSubset.InspSubsetUsageDcsnCodeGroup,
      InspectionSubset.InspSubsetUsageDcsnCode,
      @ObjectModel.foreignKey.association: '_InspSubsetUsageDcsnValn'
      InspectionSubset.InspSubsetUsageDcsnValuation,
      InspectionSubset.InspectionSubsetTime,
      SelectedCodeSet.InspSbstTimeFldProperty,
      InspectionSubset.InspectionSubsetDate,
      SelectedCodeSet.InspSbstDateFldProperty,
      InspectionSubset.InspectionSubsetTimeZone,
      InspectionSubset.InspSubsetLongNumericKey,
      InspectionSubset.InspSbstLongNmbrFldProperty,
      InspectionSubset.InspSubsetShortNumericKey,
      InspectionSubset.InspSbstShrtNmbrFldProperty,
      InspectionSubset.InspectionSubsetLongCharKey,
      InspectionSubset.InspSbstLongTxtFldProperty,
      InspectionSubset.InspectionSubsetShortCharKey,
      InspectionSubset.InspSbstShrtTxtFldProperty,  
      SelectedCodeSet.InspSubsetTimeFieldName,
      SelectedCodeSet.InspSubsetDateFieldName,
      
      @Feature: 'QM_IPRR_USER_FIELDS'   
      SelectedCodeSet.InspSubsetLongTxtFieldName,
      @Feature: 'QM_IPRR_USER_FIELDS'
      SelectedCodeSet.InspSubsetShortTxtFieldName,
      @Feature: 'QM_IPRR_USER_FIELDS'
      SelectedCodeSet.InspSubsetLongNmbrFieldName,
      @Feature: 'QM_IPRR_USER_FIELDS'
      SelectedCodeSet.InspSubsetShortNmbrFieldName,
//      @DefaultAggregation:#NONE

      @Semantics.quantity.unitOfMeasure: 'InspectionSubsetQtyUnit'
      InspectionSubset.InspectionSubsetYieldQty,
//      @DefaultAggregation:#NONE

      @Semantics.quantity.unitOfMeasure: 'InspectionSubsetQtyUnit'
      InspectionSubset.InspectionSubsetScrapQty,
//      @DefaultAggregation:#NONE

      @Semantics.quantity.unitOfMeasure: 'InspectionSubsetQtyUnit'
      InspectionSubset.InspectionSubsetReworkQty,
      @ObjectModel.foreignKey.association: '_Unit'
      InspectionSubset.InspectionSubsetQtyUnit,

      //    vetext as InspectionSubset,       QALT.vetext

      InspectionSubset.Inspector,
      
      
//      cast( InspectionSubsetDate as abap.char(8) ) as InspSubsetDateTime,

      
      @ObjectModel.readOnly: true
      InspectionSubset.CreatedByUser                                                           as UserID,
      @ObjectModel.readOnly: true
      InspectionSubset.LastChangedByUser                                      as ContactCardID,

      @ObjectModel.readOnly: true
       _CreatedByUser.FullName                                                 as CreatedByUser,
 //     @Semantics.businessDate.createdAt: true

      @ObjectModel.readOnly: true
      InspectionSubset.CreationDate,
      @Semantics.time: true
      @ObjectModel.readOnly: true
      InspectionSubset.CreationTime,      
      @ObjectModel.readOnly: true
      _LastChangedByUser.FullName                                             as LastChangedByUser,
 //     @Semantics.businessDate.lastChangedAt: true

      @ObjectModel.readOnly: true
      InspectionSubset.LastChangeDate,
      @Semantics.time: true
      @ObjectModel.readOnly: true
      InspectionSubset.LastChangeTime,

      //  Draft Associations

      @ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
      _InspSubsetCharcResult,
 
      // Associations

      InspectionSubset._InspectionLot,
      InspectionSubset._InspectionOperation,
      InspectionSubset._InspectionSubsetInternalID,
      _CreatedByUser,
      _LastChangedByUser,
      InspectionSubset._UsageDecisionCodeGroup,
      InspectionSubset._UsageDecisionCode,
     // _SelectedCodeSet,

      InspectionSubset._InspSubsetUsageDcsnValn,
      InspectionSubset._InspSubsetUsageDcsnValnTxt,
      //    _MaterialSample,

      //    _FunctionalLocation,

      //    _ShopFloorItem,

      //    _Equipment,

      
      InspectionSubset._Unit
}