I_InspectionCodeText

DDL: I_INSPECTIONCODETEXT Type: view_entity BASIC Package: VDM_QM_PLANNING

Inspection Code - Text

I_InspectionCodeText is a Basic CDS View that provides data about "Inspection Code - Text" in SAP S/4HANA. It reads from 1 data source (qpct) and exposes 8 fields with key fields InspectionCatalog, InspectionCodeGroup, InspectionCode, Language. It has 3 associations to related views. Part of development package VDM_QM_PLANNING.

1 data source(s) 8 fields

Data Sources (1)

SourceAliasJoin Type
qpct qpct from

Associations (3)

CardinalityTargetAliasCondition
[1..1] I_Inspectioncatalog _InspectionCatalog $projection.InspectionCatalog = _InspectionCatalog.InspectionCatalog
[1..1] I_InspectionCodeGroup _InspectionCodeGroup $projection.InspectionCatalog = _InspectionCodeGroup.InspectionCatalog and $projection.InspectionCodeGroup = _InspectionCodeGroup.InspectionCodeGroup
[1..1] I_InspectionCode _InspectionCode $projection.InspectionCatalog = _InspectionCode.InspectionCatalog and $projection.InspectionCodeGroup = _InspectionCode.InspectionCodeGroup and $projection.InspectionCode = _InspectionCode.InspectionCode

Annotations (11)

NameValueLevelField
AccessControl.authorizationCheck #CHECK view
EndUserText.label Inspection Code - Text view
ObjectModel.dataCategory #TEXT view
Analytics.technicalName IINSPCODETEXT view
ObjectModel.representativeKey InspectionCode view
VDM.viewType #BASIC view
VDM.lifecycle.contract.type #PUBLIC_LOCAL_API view
ObjectModel.usageType.serviceQuality #A view
ObjectModel.usageType.sizeCategory #M view
ObjectModel.usageType.dataClass #CUSTOMIZING view
Metadata.ignorePropagatedAnnotations true view

Fields (8)

KeyFieldSource TableSource FieldDescription
KEY InspectionCatalog katalogart
KEY InspectionCodeGroup codegruppe
KEY InspectionCode code
KEY Language sprache
InspectionCodeText
_InspectionCatalog _InspectionCatalog
_InspectionCodeGroup _InspectionCodeGroup
_InspectionCode _InspectionCode 
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Inspection Code - Text'
@ObjectModel.dataCategory: #TEXT
@Analytics.technicalName: 'IINSPCODETEXT'
@ObjectModel.representativeKey: 'InspectionCode'
@VDM: {
    viewType: #BASIC,
    lifecycle.contract.type: #PUBLIC_LOCAL_API
}
@ObjectModel.supportedCapabilities: 
    [ #SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE, #CDS_MODELING_ASSOCIATION_TARGET, #LANGUAGE_DEPENDENT_TEXT ]
@ObjectModel.usageType: { serviceQuality: #A, sizeCategory: #M, dataClass: #CUSTOMIZING }
@Metadata.ignorePropagatedAnnotations: true
define view entity I_InspectionCodeText
  as select from qpct
  association [1..1] to I_Inspectioncatalog   as _InspectionCatalog   on  $projection.InspectionCatalog = _InspectionCatalog.InspectionCatalog
  association [1..1] to I_InspectionCodeGroup as _InspectionCodeGroup on  $projection.InspectionCatalog   = _InspectionCodeGroup.InspectionCatalog
                                                                      and $projection.InspectionCodeGroup = _InspectionCodeGroup.InspectionCodeGroup
  association [1..1] to I_InspectionCode      as _InspectionCode      on  $projection.InspectionCatalog   = _InspectionCode.InspectionCatalog
                                                                      and $projection.InspectionCodeGroup = _InspectionCode.InspectionCodeGroup
                                                                      and $projection.InspectionCode      = _InspectionCode.InspectionCode
{
      @ObjectModel.foreignKey.association: '_InspectionCatalog'
  key katalogart as InspectionCatalog,
      //--[ GENERATED:012:GlBfhyFV7kY4h7jYW0xcqG

      @Consumption.valueHelpDefinition: [ 
        { entity:  { name:    'I_InspectionCodeGroupStdVH',
                     element: 'InspectionCodeGroup' },
          additionalBinding: [{ localElement: 'InspectionCatalog',
                                element: 'InspectionCatalog' }]
        }]
      // ]--GENERATED

      @ObjectModel.foreignKey.association: '_InspectionCodeGroup'
  key codegruppe as InspectionCodeGroup,
      //--[ GENERATED:012:GlBfhyFV7kY4h7jYW0xcqG

      @Consumption.valueHelpDefinition: [ 
        { entity:  { name:    'I_InspectionCodeStdVH',
                     element: 'InspectionCode' },
          additionalBinding: [{ localElement: 'InspectionCatalog',
                                element: 'InspectionCatalog' },
                              { localElement: 'InspectionCodeGroup',
                                element: 'InspectionCodeGroup' }]
        }]
      // ]--GENERATED

      @ObjectModel.foreignKey.association: '_InspectionCode'
  key code       as InspectionCode,
      @Semantics.language: true
  key sprache    as Language,
      @Semantics.text: true
      cast( kurztext as vdm_qtxt_code preserving type )  as InspectionCodeText,

      // Associations

      _InspectionCatalog,
      _InspectionCodeGroup,
      _InspectionCode
}

Learn More