I_InspSubsetResultLongText

@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Long Text of Insp Point Result'
@VDM.viewType: #BASIC
@ObjectModel: {
    dataCategory: #TEXT,
    usageType: {
        dataClass: #TRANSACTIONAL,
        sizeCategory: #L,
        serviceQuality: #C
    },
    representativeKey: 'InspectionLot'
}
@Analytics.technicalName: 'IINSPSBSTRESLT'
define view entity I_InspSubsetResultLongText as select from qasrltext 
    association [1] to I_InspectionLot as _InspectionLot
      on $projection.InspectionLot = _InspectionLot.InspectionLot
    association [1..1] to I_Language as _Language
      on $projection.Language = _Language.Language
{
    @ObjectModel.foreignKey.association: '_InspectionLot'
    key prueflos as InspectionLot,
    key vorglfnr as InspPlanOperationInternalID,
    key merknr   as InspectionCharacteristic,
    key probenr  as InspectionSubsetInternalID,
    key counter  as ItemCounter,
    @ObjectModel.foreignKey.association: '_Language'
    @Semantics.language: true
    key langu as Language,
    textid as LongTextID,

    content     as InspSubsetResultLongText,
    created_by  as LongTextCreatedByUser,
    created_at  as LongTextCreatedAt,
    changed_by  as LongTextLastChangedByUser,
    changed_at  as LongTextLastChangedAt,

    /* Association */
    _InspectionLot,
    _Language    
}