I_InspMethInspSpecTP

@EndUserText.label: 'Master Charcs. of Inspection Method'
@AccessControl.authorizationCheck: #CHECK
@VDM: {
    viewType: #TRANSACTIONAL,
    lifecycle.contract.type: #SAP_INTERNAL_API
} 
@ObjectModel.usageType: {
    dataClass: #MIXED,
    sizeCategory: #L,
    serviceQuality: #C
}

/* Draft 2.0*/
@ObjectModel:{
    createEnabled: false,
    updateEnabled: false,
    deleteEnabled: false,
    writeDraftPersistence: 'QIMETHINSPSPEC_D'
}

define view entity I_InspMethInspSpecTP as select from I_InspMethInspSpec 

  association [1..1] to I_InspectionMethodVersionTP as _InspectionMethod
    on     $projection.InspectionMethod        = _InspectionMethod.InspectionMethod
       and $projection.InspectionMethodPlant   = _InspectionMethod.InspectionMethodPlant
       and $projection.InspectionMethodVersion = _InspectionMethod.InspectionMethodVersion

{
   @ObjectModel.readOnly: true
   key InspectionMethod,
   @ObjectModel.readOnly: true
   key InspectionMethodPlant,
   @ObjectModel.readOnly: true
   key InspectionMethodVersion,
   key InspectionSpecification,
   key InspectionSpecificationPlant,
   key InspectionSpecificationVersion,
   
   @ObjectModel.readOnly: true
   InspSpecCharacteristicType,
   @ObjectModel.readOnly: true
   InspectionSpecificationStatus,
   @ObjectModel.readOnly: true
   InspSpecStatusCriticality,
   
   @Consumption.hidden: true
   _InspectionMethod.QltyMstrDataAuthorizationGroup,
   
   /* Associations */
   @ObjectModel.association.type:  [ #TO_COMPOSITION_PARENT, #TO_COMPOSITION_ROOT ]
   _InspectionMethod,
   
   _InspSpecVersionText,
   _InspSpecificationPlant,
   _InspSpecCharcType,
   _InspSpecStatus,
   _InspectionMethodVersion
   
}