I_GoodsMovementSubstituteDEX

@EndUserText.label: 'Material document substitute extraction'
@AccessControl: {
                   authorizationCheck: #CHECK,
                   personalData.blocking: #NOT_REQUIRED
                }
@ObjectModel: {
                usageType: {
                             sizeCategory: #XXL,
                             serviceQuality: #C,
                             dataClass:#TRANSACTIONAL
                           },
                sapObjectNodeType.name : 'MaterialStock',                           
//                semanticKey: ['MaterialDocumentYear', 'MaterialDocument', 'MaterialDocumentItem'],

                supportedCapabilities: [#EXTRACTION_DATA_SOURCE]
} 
@VDM: {
        viewType: #COMPOSITE,
        lifecycle.contract.type: #PUBLIC_LOCAL_API
      }
@Analytics: {
              dataCategory: #FACT,
              internalName: #LOCAL,
              dataExtraction.enabled: true                                                       
    
           }
@Metadata: {
             ignorePropagatedAnnotations: true
           }

define view entity I_GoodsMovementSubstituteDEX
  as select from I_MaterialDocumentRecord 
  
association [0..1] to I_SupplierCompanyByPlant as _SpecStkIdfgSupplierByPlant on  $projection.SpecialStockIdfgSupplier = _SpecStkIdfgSupplierByPlant.Supplier
                                                                              and $projection.Plant = _SpecStkIdfgSupplierByPlant.Plant  
                                                                                 
association [0..1] to I_CustomerCompanyByPlant as _SpecStockIdfgCustByPlant   on  $projection.SpecialStockIdfgCustomer = _SpecStockIdfgCustByPlant.Customer
                                                                              and $projection.Plant    = _SpecStockIdfgCustByPlant.Plant                                                                                 
 
{
// Technical key fields

  @Consumption.hidden: true
      key MaterialDocumentKey1,
  @Consumption.hidden: true
      key MaterialDocumentKey2,
  @Consumption.hidden: true
      key MaterialDocumentKey3,
  @Consumption.hidden: true
      key MaterialDocumentKey4,
  @Consumption.hidden: true
      key MaterialDocumentKey5,
  @Consumption.hidden: true
      key MaterialDocumentKey6,  
    
// Warehouse stock identifier

      StockIdentifyingMaterial,
      Plant,
      StockIdfgStorageLocation,
      StockIdentifyingBatch,
      SpecialStockIdfgSupplier,
      SpecialStockIdfgSalesOrder,
      SpecialStockIdfgSalesOrderItem,
-- CAST to get rid of conversion exit
      cast(SpecialStockIdfgWBSElement as nsdm_wbselement_internal_id preserving type) as SpecialStockIdfgWBSElement,  
      SpecialStockIdfgCustomer,
      InventorySpecialStockType,
      InventoryStockType,
      SpecialStockIdfgStockOwner,
      cast(ResourceID as nsdm_resourcename preserving type ) as ResourceID,
      
      // Warehouse stock grouping fields     

      CostEstimate, 
      CompanyCode, 
      InventorySpecialStockValnType,   
       
      // Quantities

      @Semantics.quantity.unitOfMeasure: 'MaterialBaseUnit'
//      @DefaultAggregation: #NONE

      MatlStkChangeQtyInBaseUnit,
      @Semantics.quantity.unitOfMeasure: 'MaterialBaseUnit'
//      @DefaultAggregation: #NONE

      MatlCnsmpnQtyInMatlBaseUnit,    
      MaterialBaseUnit,  

      // Amounts

      @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
//      @DefaultAggregation: #NONE

      GoodsMovementStkAmtInCCCrcy,
      @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
//      @DefaultAggregation: #NONE

      GoodsMvtCnsmpnAmtInCCCrcy,    
      CompanyCodeCurrency,  

      // other fields 

      InventoryValuationType,
   
      //Periods and time     

      @Semantics.businessDate.at: true
      DocumentDate,      
      PostingDate,
      @Semantics.fiscal.yearVariant: true
      FiscalYearVariant,
      FiscalYear,
      @Semantics.fiscal.yearPeriod: true
      FiscalYearPeriod,
      YearDay,
      @Semantics.calendar.yearWeek: true
      YearWeek,
      @Semantics.calendar.yearMonth: true
      YearMonth,
      @Semantics.calendar.yearQuarter: true
      YearQuarter,
      @Semantics.calendar.quarter: true
      CalendarQuarter,
      @Semantics.calendar.month: true
      CalendarMonth,
      @Semantics.calendar.week: true
      CalendarWeek,
      @Semantics.calendar.dayOfYear: true
//      CalendarDay, GTN 2 digits but field 3 digits

      cast(CalendarDay as nsdm_day_of_year preserving type) as CalendarDayOfYear,     
      WeekDay,  
      
      _SpecialStockIdfgSupplier,
      _SpecialStockIdfgStockOwner,
      _SpecialStockIdfgCustomer,
      _SpecStkIdfgSupplierByPlant,
      _SpecStockIdfgCustByPlant
            
}
where MaterialDocumentRecordType = 'MIG_DELTA' or MaterialDocumentRecordType = 'AG_MDOC_CF' 
   or MaterialDocumentRecordType = 'ARC_DELTA' or MaterialDocumentRecordType = 'PURGE_CF'