I_GoodsInvoiceHistory

DDL: I_GOODSINVOICEHISTORY SQL: IGIHDATA Type: view COMPOSITE Package: VDM_CPM_WS

Goods Invoice History Data

I_GoodsInvoiceHistory is a Composite CDS View that provides data about "Goods Invoice History Data" in SAP S/4HANA. It reads from 2 data sources (I_MpProcHistoryInvoiceStatus, I_PurchaseOrderHistory) and exposes 24 fields with key fields PurchaseOrder, PurchaseOrderItem, MaterialDocument, MaterialDocumentItem. Part of development package VDM_CPM_WS.

2 data source(s) 24 fields

Data Sources (2)

SourceAliasJoin Type
I_MpProcHistoryInvoiceStatus HistoryStatus left_outer
I_PurchaseOrderHistory PurchaseOrderHistory from

Annotations (9)

NameValueLevelField
AbapCatalog.sqlViewName IGIHDATA view
AbapCatalog.compiler.compareFilter true view
ClientHandling.algorithm #SESSION_VARIABLE view
VDM.viewType #COMPOSITE view
ObjectModel.usageType.sizeCategory #XL view
ObjectModel.usageType.serviceQuality #C view
ObjectModel.usageType.dataClass #MIXED view
AccessControl.authorizationCheck #CHECK view
EndUserText.label Goods Invoice History Data view

Fields (24)

KeyFieldSource TableSource FieldDescription
KEY PurchaseOrder I_PurchaseOrderHistory PurchaseOrder
KEY PurchaseOrderItem
KEY MaterialDocument I_PurchaseOrderHistory MaterialDocument
KEY MaterialDocumentItem I_PurchaseOrderHistory MaterialDocumentItem
Material I_PurchaseOrderHistory Material
GoodsMovementType I_PurchaseOrderHistory GoodsMovementType
DebitCreditCode I_PurchaseOrderHistory DebitCreditCode
MaterialDocumentYear I_PurchaseOrderHistory MaterialDocumentYear
PurchaseOrderHistCategory I_PurchaseOrderHistory PurchaseOrderHistCategory
PostingDate I_PurchaseOrderHistory PostingDate
Quantity I_PurchaseOrderHistory Quantity
DeliveryQuantityUnit
InvoiceListStatus I_MpProcHistoryInvoiceStatus InvoiceListStatus
InvoiceListStatusDesc
InvoiceReferenceFiscalYear I_MpProcHistoryInvoiceStatus InvoiceReferenceFiscalYear
InvoiceAmtInCoCodeCrcy I_PurchaseOrderHistory InvoiceAmtInPurOrdTransacCrcy
PurOrdAmountInCompanyCodeCrcy I_PurchaseOrderHistory PurchaseOrderAmount
Currency I_PurchaseOrderHistory Currency
PurchaseOrderType
PurchasingOrganization
PurchasingGroup
Plant
_Currency _Currency
_UnitOfMeasure _UnitOfMeasure 
@AbapCatalog.sqlViewName: 'IGIHDATA'
@AbapCatalog.compiler.compareFilter: true
@ClientHandling.algorithm: #SESSION_VARIABLE
@VDM.viewType: #COMPOSITE
@ObjectModel.usageType.sizeCategory:#XL
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.dataClass: #MIXED
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Goods Invoice History Data'
define view I_GoodsInvoiceHistory as select from I_PurchaseOrderHistory as PurchaseOrderHistory

left outer join  I_MpProcHistoryInvoiceStatus as HistoryStatus on     PurchaseOrderHistory.MaterialDocument = HistoryStatus.MaterialDocument
                                                                  and PurchaseOrderHistory.MaterialDocumentYear = HistoryStatus.InvoiceReferenceFiscalYear
                                                                  and PurchaseOrderHistory.PurchaseOrder = HistoryStatus.PurchaseOrder
                                                                  and PurchaseOrderHistory.PurchaseOrderItem = HistoryStatus.PurchaseOrderItem
association[0..1] to I_InvoiceListStatus as _InvoiceListStatus on $projection.InvoiceListStatus = _InvoiceListStatus.InvoiceListStatus
association[0..1] to I_Currency as _Currency on $projection.Currency = _Currency.Currency
association[0..1] to I_UnitOfMeasure as _UnitOfMeasure on $projection.DeliveryQuantityUnit = _UnitOfMeasure.UnitOfMeasure
{
   
   key PurchaseOrderHistory.PurchaseOrder,
   
   
   key ltrim(PurchaseOrderHistory.PurchaseOrderItem,'0') as PurchaseOrderItem,
   
   
   key PurchaseOrderHistory.MaterialDocument,
   
   key PurchaseOrderHistory.MaterialDocumentItem,
   
   PurchaseOrderHistory.Material,
   
   PurchaseOrderHistory.GoodsMovementType,
   
   PurchaseOrderHistory.DebitCreditCode,
   
   PurchaseOrderHistory.MaterialDocumentYear,
   
   
   PurchaseOrderHistory.PurchaseOrderHistCategory,
   
   
   PurchaseOrderHistory.PostingDate,
   
   @Semantics.quantity.unitOfMeasure: 'DeliveryQuantityUnit'
   @DefaultAggregation: #SUM
   PurchaseOrderHistory.Quantity,
   
   @Semantics.unitOfMeasure: true
   PurchaseOrderHistory._PurchaseOrderItem.PurchaseOrderQuantityUnit as DeliveryQuantityUnit,
   
   @ObjectModel.text.element: 'InvoiceListStatusDesc'
   HistoryStatus.InvoiceListStatus,
    
   @Semantics.text: true
   _InvoiceListStatus._Text[1:Language = $session.system_language].InvoiceListStatusDesc,   
   
    HistoryStatus.InvoiceReferenceFiscalYear,
    
    @Semantics.amount.currencyCode: 'Currency'
    @DefaultAggregation: #SUM
   PurchaseOrderHistory.InvoiceAmtInPurOrdTransacCrcy as InvoiceAmtInCoCodeCrcy,
   
   @Semantics.amount.currencyCode: 'Currency'
   @DefaultAggregation: #SUM
   PurchaseOrderHistory.PurchaseOrderAmount as PurOrdAmountInCompanyCodeCrcy,
   
   @Semantics.currencyCode: true
   PurchaseOrderHistory.Currency,
   
   
   PurchaseOrderHistory._PurchaseOrderItem._PurchaseOrder.PurchaseOrderType,
   
   
   PurchaseOrderHistory._PurchaseOrderItem._PurchaseOrder.PurchasingOrganization,
   
   
   PurchaseOrderHistory._PurchaseOrderItem._PurchaseOrder.PurchasingGroup,
   
   
   PurchaseOrderHistory._PurchaseOrderItem.Plant,
   _Currency,
   _UnitOfMeasure
} 
where PurchaseOrderHistory.PurchaseOrderHistCategory = 'Q' or 
PurchaseOrderHistory.PurchaseOrderHistCategory = 'E'

Learn More