I_GLAcctInCOACompanyCode

@AbapCatalog.sqlViewName: 'IGLACCTCOACOCD'
@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@VDM.viewType: #COMPOSITE  
@AccessControl.authorizationCheck: #NOT_REQUIRED
@ObjectModel.usageType:{
  serviceQuality: #C,
  sizeCategory: #M,
  dataClass: #MASTER }

@EndUserText.label: 'Operating CoA GL Acct in Company Code'
define view I_GLAcctInCOACompanyCode as select from I_GLAccountInChartOfAccounts as AcctCOA
               left outer to many join I_GLAccountInCompanyCode as AcctCC on
                                                            AcctCOA.GLAccount = AcctCC.GLAccount
                                                            
     association to I_CompanyCode as CC on AcctCC.CompanyCode = CC.CompanyCode                                                              
//                                                            and  AcctCOA.ChartOfAccounts = 'YCOA'


       // association to parent R_OperatingChartOfAccountsTP as _root on $projection.ChartOfAccounts   = _root.ChartOfAccounts                                

                {
               
    @Consumption.filter.mandatory
    @UI.textArrangement: #TEXT_LAST
    @Consumption.valueHelpDefinition: [{ entity: { name:    'P_OperatingChartOfAccounts',
                                                   element: 'ChartOfAccounts' } 
                                                   }]
    @Consumption.semanticObject:      'ChartOfAccounts'
    @Consumption.filter.selectionType: #SINGLE
    
    key AcctCOA.ChartOfAccounts,
        
    @EndUserText.label: 'G/L Account Number'                         
    @EndUserText.quickInfo: 'G/L Account Number'    
    @Consumption.semanticObject: 'GLAccount'    
    @Consumption.valueHelpDefinition: [{ entity: { name:    'I_GLAccount',
                                                 element: 'GLAccount' } }]      
    @Consumption.filter.mandatory  

    key AcctCOA.GLAccount,
    key AcctCC.CompanyCode,
     
    @UI: { lineItem: [ { 
    position: 25,
                       importance: #MEDIUM
                        } ],
    identification: [ { position: 25 } ] }
 
    @EndUserText.label: 'G/L Account Short Text'                         

    AcctCOA._Text[1: Language = $session.system_language].GLAccountName as GLAccountName,
    
    @UI: { lineItem: [ { position: 30,
                       importance: #MEDIUM
                        } ],
    identification: [ { position: 30 } ] }
 
    @EndUserText.label: 'G/L Account Type'                         
    @EndUserText.quickInfo: 'G/L Account Type'
    @ObjectModel.text.element: ['GLAccountTypeName']
    @UI.textArrangement: #TEXT_LAST
    AcctCOA.GLAccountType                                                   ,
    @Semantics.text: true     
    @EndUserText.label: 'G/L Account Type Name'                         
    @EndUserText.quickInfo: 'G/L Account Type Name'          
    AcctCOA._GLAccountType._GLAccountTypeText[1: Language =  $session.system_language].GLAccountTypeName as GLAccountTypeName,
      
    @UI: { lineItem: [ { position: 40,
                         importance: #MEDIUM                          } ],
     identification: [ { position: 40 } ] }
    @EndUserText.label: 'G/L Account Group'                         
    @EndUserText.quickInfo: 'G/L Account Group'
    @ObjectModel.text.element: ['AccountGroupName']
    @UI.textArrangement: #TEXT_LAST      
    AcctCOA.GLAccountGroup                                                  ,
    @Semantics.text: true
    @EndUserText.label: 'G/L Account Group Name'                         
    @EndUserText.quickInfo: 'G/L Account Group Name' 
    AcctCOA._GLAccountGroupText[1: Language =  $session.system_language].AccountGroupName as AccountGroupName,
      
    @UI: { lineItem: [ { position: 50,
                       importance: #MEDIUM  } ],
    identification: [ { position: 50 } ] }
    @ObjectModel.text.element: ['CorporateGroupAccountName']
    @UI.textArrangement: #TEXT_LAST     
    AcctCOA.CorporateGroupAccount                                           as CorporateGroupAccount,
    AcctCOA._CorporateGroupAccount._Text[1: Language = $session.system_language].GLAccountName as CorporateGroupAccountName,        
    @EndUserText.label: 'G/L Account Long Text'                         
    @EndUserText.quickInfo: 'G/L Account Long Text'       
    AcctCOA._Text[1: Language = $session.system_language].GLAccountLongName as GLAccountLongName,

//      _root.FinancialStatementHierarchy as FinancialStatementHierarchy, 

    
    AcctCOA.AccountIsMarkedForDeletion                                      as AccountIsMarkedForDeletion,                                     
    AcctCOA.GLAccountExternal                                               as GLAccountExternal,
    AcctCOA.GLAccountSubtype                                                as GLAccountSubtype ,
    AcctCOA.BankReconciliationAccount                                       as BankReconciliationAccount,
    @EndUserText.label: 'P&L Statement Acct'                         
    AcctCOA.ProfitLossAccountType                                           as ProfitLossAccountType,
    AcctCOA._GLAcctInChartOfAcctsStatus.GLAcctCOAImplementStatus            as GLAcctCOAImplementStatus,
    AcctCOA._GLAcctInChartOfAcctsStatus._GLAccountImpStTypeText[1: Language = $session.system_language].GLAcctCOAImplementStatusName as GLAcctCOAImplementStatusName

//    _root

//    _ChartOfAccounts

//    _GLAcct  

} 
where CC.ChartOfAccounts =  AcctCOA.ChartOfAccounts
//where AcctCOA.ChartOfAccounts = _root.ChartOfAccounts