I_FundsCenterBasic

@EndUserText.label: 'Funds Center Basic'
@Analytics: { dataCategory: #DIMENSION, dataExtraction.enabled: true, internalName: #LOCAL }
@VDM.viewType: #BASIC
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking
@AccessControl.privilegedAssociations: ['_CreatedByUser', '_LastChangedByUser']
@ObjectModel.representativeKey: 'FundsCenter'
@ObjectModel.usageType: {
  dataClass: #MASTER,
  serviceQuality: #A,
  sizeCategory: #M
}
@ClientHandling.algorithm: #SESSION_VARIABLE
@Metadata.allowExtensions:true
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.sqlViewName: 'IFUNDSCENTERB'
@AbapCatalog.preserveKey: true
define view I_FundsCenterBasic
  as select from fmfctr

  association [1..1] to I_FinancialManagementArea  as _FinMgmtArea              on  $projection.FinancialManagementArea = _FinMgmtArea.FinancialManagementArea

  association [0..*] to I_FundsCenterText          as _Text                     on  $projection.FinancialManagementArea = _Text.FinancialManagementArea
                                                                                and $projection.FundsCenter             = _Text.FundsCenter
                                                                                and $projection.ValidityEndDate         = _Text.ValidityEndDate

  association [0..1] to I_Fund                     as _Fund                     on  $projection.FinancialManagementArea = _Fund.FinancialManagementArea
                                                                                and $projection.FundsCenterDefaultFund  = _Fund.Fund

  association [0..1] to I_CompanyCode              as _CompanyCode              on  $projection.CompanyCode = _CompanyCode.CompanyCode

  association [0..1] to I_BusinessArea             as _BusinessArea             on  $projection.BusinessArea = _BusinessArea.BusinessArea

  association [0..1] to I_User                     as _CreatedByUser            on  $projection.CreatedByUser = _CreatedByUser.UserID
  association [0..1] to I_User                     as _LastChangedByUser        on  $projection.LastChangeUser = _LastChangedByUser.UserID
  association [0..1] to I_User                     as _FundsCenterManager       on  $projection.FundsCenterManager = _FundsCenterManager.UserID

  association [0..*] to I_FundsCenterHierarchyNode as _FundsCenterHierarchyNode on  $projection.FinancialManagementArea = _FundsCenterHierarchyNode.FinancialManagementArea
                                                                                and $projection.FundsCenter             = _FundsCenterHierarchyNode.FundsCenter
                                                                                                                                                                           
{

      @ObjectModel.foreignKey.association: '_FinMgmtArea'
  key fikrs                                                                                                                     as FinancialManagementArea,
      @ObjectModel.text.association: '_Text'
      @ObjectModel.hierarchy.association: '_FundsCenterHierarchyNode'
  key cast( fictr as fm_fictr preserving type )                                                                                 as FundsCenter,
      @Semantics.businessDate.to: true
  key cast( datbis as fmis_fc_validityenddate preserving type )                                                                 as ValidityEndDate,
      @Semantics.businessDate.from: true
      cast( datab as fmis_fc_validitystartdate preserving type )                                                                as ValidityStartDate,
      @Consumption.valueHelpDefinition: { entity: { name: 'I_BusinessUserVH', element: 'UserID' } }
      //@ObjectModel.text.element: 'CreatedByUserDescription'

      cast( erfname as fmis_fc_createdbyuser preserving type )                                                                  as CreatedByUser,
      //@Semantics.text: true

      //_CreatedByUser.UserDescription                                                                                            as CreatedByUserDescription,

      //      @Semantics.businessDate.createdAt: true

      @Semantics.systemDate.createdAt: true
      cast( erfdat as fmis_fc_creationdate preserving type )                                                                    as CreationDate,
      @Consumption.valueHelpDefinition: { entity: { name: 'I_BusinessUserVH', element: 'UserID' } }
      //@ObjectModel.text.element: 'LastChangedByUserDescription'

      cast( aenname as fmis_fc_lastchangeuser preserving type )                                                                 as LastChangeUser,
      //@Semantics.text: true

      //_LastChangedByUser.UserDescription                                                                                        as LastChangedByUserDescription,

      //      @Semantics.businessDate.lastChangedAt: true

      @Semantics.systemDate.lastChangedAt: true
      cast( aendat as fmis_fc_lastchangedate preserving type )                                                                  as LastChangeDate,
      cast( date_exp as fmis_fc_expirationdate preserving type )                                                                as FundsCenterExpirationDate,
      @VDM.lifecycle.status: #DEPRECATED
      @VDM.lifecycle.successor: 'FundsCenterManager'      
      bossid                                                                                                                    as FundsCenterResponsible,
      cast( bossid as fmis_fundscentermanager preserving type )                                                                     as FundsCenterManager,
      bossname                                                                                                                  as FundsCenterResponsibleName,
      @ObjectModel.foreignKey.association: '_Fund'
      fincode                                                                                                                   as FundsCenterDefaultFund,
      augrp                                                                                                                     as FundsCenterAuthznGrp,      
      cast(
        case augrp
          when '' then '    '
          else fikrs
        end as fmis_fcfinmgmtareaforauthzn preserving type )                                                                    as FndsCenterFinMgmtAreaForAuthzn,
      @ObjectModel.foreignKey.association: '_CompanyCode'
      bukrs                                                                                                                     as CompanyCode,
      @ObjectModel.foreignKey.association: '_BusinessArea'
      gsber                                                                                                                    as BusinessArea,

      prctr                                                                                                                     as ProfitCenter,

      _FinMgmtArea,
      _Fund,
      _Text,
      _CompanyCode,
      _BusinessArea,
      _CreatedByUser,
      _LastChangedByUser,
      _FundsCenterManager,
      _FundsCenterHierarchyNode

}