I_FiscalPeriodText

DDL: I_FISCALPERIODTEXT Type: view_entity BASIC Package: FINS_FI_DATE

Fiscal Period Text

I_FiscalPeriodText is a Basic CDS View that provides data about "Fiscal Period Text" in SAP S/4HANA. It reads from 2 data sources (finsc_period, t009c) and exposes 8 fields with key fields Language, FiscalYearVariant, FiscalYear, FiscalPeriod. It has 3 associations to related views. Part of development package FINS_FI_DATE.

2 data source(s) 8 fields

Data Sources (2)

SourceAliasJoin Type
finsc_period finsc_period inner
t009c t009c from

Associations (3)

CardinalityTargetAliasCondition
[0..1] I_FiscalYearVariant _FiscalYearVariant $projection.FiscalYearVariant = _FiscalYearVariant.FiscalYearVariant
[0..1] I_FiscalYear _FiscalYear $projection.FiscalYearVariant = _FiscalYear.FiscalYearVariant and $projection.FiscalYear = _FiscalYear.FiscalYear
[0..1] I_Language _Language $projection.Language = _Language.Language

Annotations (16)

NameValueLevelField
AbapCatalog.entityBuffer.definitionAllowed false view
VDM.lifecycle.contract.type #PUBLIC_LOCAL_API view
Metadata.ignorePropagatedAnnotations true view
EndUserText.label Fiscal Period Text view
VDM.viewType #BASIC view
ObjectModel.dataCategory #TEXT view
Analytics.technicalName IFIFISCPERTXT view
ObjectModel.usageType.serviceQuality #A view
ObjectModel.usageType.sizeCategory #S view
ObjectModel.usageType.dataClass #MASTER view
ObjectModel.representativeKey FiscalPeriod view
AccessControl.authorizationCheck #NOT_REQUIRED view
Analytics.dataExtraction.enabled true view
Search.searchable true view
Analytics.internalName #LOCAL view
ObjectModel.modelingPattern #LANGUAGE_DEPENDENT_TEXT view

Fields (8)

KeyFieldSource TableSource FieldDescription
KEY Language t009c spras
KEY FiscalYearVariant
KEY FiscalYear
KEY FiscalPeriod
FiscalPeriodName t009c ltext
_FiscalYearVariant _FiscalYearVariant
_FiscalYear _FiscalYear
_Language _Language 
 @AbapCatalog.entityBuffer.definitionAllowed: false
 @VDM.lifecycle.contract.type: #PUBLIC_LOCAL_API
@Metadata.ignorePropagatedAnnotations: true
@EndUserText.label: 'Fiscal Period Text'
@VDM.viewType: #BASIC

@ObjectModel.dataCategory: #TEXT
@Analytics.technicalName: 'IFIFISCPERTXT' 
@ObjectModel.usageType.serviceQuality: #A
@ObjectModel.usageType.sizeCategory: #S
@ObjectModel.usageType.dataClass: #MASTER

@ObjectModel.representativeKey: 'FiscalPeriod'
@AccessControl.authorizationCheck: #NOT_REQUIRED
@Analytics: {dataExtraction.enabled: true}
@Search.searchable: true

@Analytics.internalName: #LOCAL

@ObjectModel.modelingPattern: #LANGUAGE_DEPENDENT_TEXT
@ObjectModel.supportedCapabilities: [#LANGUAGE_DEPENDENT_TEXT, #CDS_MODELING_ASSOCIATION_TARGET, #SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE, #EXTRACTION_DATA_SOURCE, #SEARCHABLE_ENTITY]

define view entity I_FiscalPeriodText as select from t009c inner join finsc_period on  t009c.periv = finsc_period.fiscal_year_variant
                                                                            and t009c.poper = finsc_period.fiscal_period 
                                                                            and (    t009c.bdatj = finsc_period.fiscal_year 
                                                                                  or t009c.bdatj = '0000')

association [0..1] to I_FiscalYearVariant as _FiscalYearVariant on $projection.FiscalYearVariant = _FiscalYearVariant.FiscalYearVariant
association [0..1] to I_FiscalYear        as _FiscalYear        on $projection.FiscalYearVariant = _FiscalYear.FiscalYearVariant
                                                                and $projection.FiscalYear       = _FiscalYear.FiscalYear
association [0..1] to I_Language          as _Language          on $projection.Language          = _Language.Language

{ 

@Semantics.language: true
key t009c.spras as Language,
@ObjectModel.foreignKey.association: '_FiscalYearVariant'      
key cast( t009c.periv as fis_periv preserving type )                      as FiscalYearVariant,
@ObjectModel.foreignKey.association: '_FiscalYear'      
key cast( finsc_period.fiscal_year as fis_gjahr_no_conv preserving type ) as FiscalYear,
key cast( t009c.poper as fins_fiscalperiod preserving type )              as FiscalPeriod,

//@Semantics.text: true

//t009c.ktext as FiscalPeriodName,


@Semantics.text: true
@Search.defaultSearchElement: true 
@Search.ranking: #HIGH
@Search.fuzzinessThreshold: 0.8
t009c.ltext as FiscalPeriodName,

_FiscalYearVariant,
_FiscalYear,
_Language

}

Learn More