I_FiscalPeriodForVariant

DDL: I_FISCALPERIODFORVARIANT Type: view_entity BASIC Package: FINS_FI_DATE

Fiscal Period For Fiscal Year Variant

I_FiscalPeriodForVariant is a Basic CDS View (Dimension) that provides data about "Fiscal Period For Fiscal Year Variant" in SAP S/4HANA. It reads from 1 data source (P_FiscalYearPeriod) and exposes 15 fields with key fields FiscalYearVariant, FiscalYear, FiscalPeriod. It has 4 associations to related views. Part of development package FINS_FI_DATE.

1 data source(s) 15 fields

Data Sources (1)

SourceAliasJoin Type
P_FiscalYearPeriod P_FiscalYearPeriod from

Associations (4)

CardinalityTargetAliasCondition
[0..1] I_FiscalYearVariant _FiscalYearVariant $projection.FiscalYearVariant = _FiscalYearVariant.FiscalYearVariant
[0..1] I_CalendarDate _FiscalPeriodStartDate $projection.FiscalPeriodStartDate = _FiscalPeriodStartDate.CalendarDate
[0..1] I_FiscalYear _FiscalYear $projection.FiscalYearVariant = _FiscalYear.FiscalYearVariant and $projection.FiscalYear = _FiscalYear.FiscalYear
[0..*] I_FiscalYearPeriodText _Text $projection.FiscalYearVariant = _Text.FiscalYearVariant and $projection.FiscalYear = _Text.FiscalYear and $projection.FiscalPeriod = _Text.FiscalPeriod

Annotations (12)

NameValueLevelField
EndUserText.label Fiscal Period For Fiscal Year Variant view
Metadata.ignorePropagatedAnnotations true view
VDM.viewType #BASIC view
ObjectModel.representativeKey FiscalPeriod view
Analytics.technicalName IFIFFSCLPERDFYV view
ObjectModel.usageType.serviceQuality #A view
ObjectModel.usageType.sizeCategory #L view
ObjectModel.usageType.dataClass #CUSTOMIZING view
Analytics.dataExtraction.enabled true view
AccessControl.authorizationCheck #NOT_REQUIRED view
Analytics.dataCategory #DIMENSION view
ObjectModel.modelingPattern #ANALYTICAL_DIMENSION view

Fields (15)

KeyFieldSource TableSource FieldDescription
KEY FiscalYearVariant P_FiscalYearPeriod fiscal_year_variant
KEY FiscalYear P_FiscalYearPeriod fiscal_year
KEY FiscalPeriod P_FiscalYearPeriod fiscal_period
FiscalPeriodStartDate P_FiscalYearPeriod fiscal_period_start_date
FiscalPeriodEndDate P_FiscalYearPeriod fiscal_period_end_date
IsSpecialPeriod P_FiscalYearPeriod is_special_period
FiscalYearStartDate P_FiscalYearPeriod fiscal_year_start_date
FiscalYearEndDate P_FiscalYearPeriod fiscal_year_end_date
FiscalYearPeriod P_FiscalYearPeriod fiscal_year_period
NextFiscalPeriod P_FiscalYearPeriod next_fiscal_period
NextFiscalPeriodFiscalYear P_FiscalYearPeriod next_fiscal_period_fiscal_year
_FiscalYearVariant _FiscalYearVariant
_FiscalPeriodStartDate _FiscalPeriodStartDate
_FiscalYear _FiscalYear
_Text _Text 
@EndUserText.label: 'Fiscal Period For Fiscal Year Variant'

@Metadata.ignorePropagatedAnnotations: true

@VDM.viewType: #BASIC
@ObjectModel.representativeKey: 'FiscalPeriod'
@Analytics.technicalName: 'IFIFFSCLPERDFYV'
@ObjectModel.usageType.serviceQuality: #A
@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.dataClass: #CUSTOMIZING
@Analytics.dataExtraction.enabled:true

@AccessControl.authorizationCheck: #NOT_REQUIRED

@Analytics: { dataCategory: #DIMENSION }

@ObjectModel.modelingPattern: #ANALYTICAL_DIMENSION
@ObjectModel.supportedCapabilities: [#ANALYTICAL_DIMENSION, #CDS_MODELING_ASSOCIATION_TARGET, #SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE, #EXTRACTION_DATA_SOURCE]

define view entity I_FiscalPeriodForVariant as select from P_FiscalYearPeriod 

association [0..1] to I_FiscalYearVariant    as _FiscalYearVariant     on  $projection.FiscalYearVariant     = _FiscalYearVariant.FiscalYearVariant
association [0..1] to I_CalendarDate         as _FiscalPeriodStartDate on  $projection.FiscalPeriodStartDate = _FiscalPeriodStartDate.CalendarDate
association [0..1] to I_FiscalYear           as _FiscalYear            on  $projection.FiscalYearVariant     = _FiscalYear.FiscalYearVariant
                                                                       and $projection.FiscalYear            = _FiscalYear.FiscalYear
association [0..*] to I_FiscalYearPeriodText as _Text                  on  $projection.FiscalYearVariant     = _Text.FiscalYearVariant
                                                                       and $projection.FiscalYear            = _Text.FiscalYear
                                                                       and $projection.FiscalPeriod          = _Text.FiscalPeriod
{
 
@ObjectModel.foreignKey.association: '_FiscalYearVariant'  
//@Semantics.fiscal.yearVariant: true    

key P_FiscalYearPeriod.fiscal_year_variant            as FiscalYearVariant,
@ObjectModel.foreignKey.association: '_FiscalYear'      
key P_FiscalYearPeriod.fiscal_year                    as FiscalYear,
@ObjectModel.text.association: '_Text'
key P_FiscalYearPeriod.fiscal_period                  as FiscalPeriod,

//@ObjectModel.foreignKey.association: '_FiscalPeriodStartDate'      

    P_FiscalYearPeriod.fiscal_period_start_date       as FiscalPeriodStartDate,
    P_FiscalYearPeriod.fiscal_period_end_date         as FiscalPeriodEndDate,
    
    P_FiscalYearPeriod.is_special_period              as IsSpecialPeriod,
    
    P_FiscalYearPeriod.fiscal_year_start_date         as FiscalYearStartDate,
    P_FiscalYearPeriod.fiscal_year_end_date           as FiscalYearEndDate,
       
    P_FiscalYearPeriod.fiscal_year_period             as FiscalYearPeriod,

    P_FiscalYearPeriod.next_fiscal_period             as NextFiscalPeriod,
    P_FiscalYearPeriod.next_fiscal_period_fiscal_year as NextFiscalPeriodFiscalYear,
    
    _FiscalYearVariant, 
    _FiscalPeriodStartDate,
    _FiscalYear,
    _Text 
           
}

Learn More