I_FinTransFXRateAdjustment

@AbapCatalog.viewEnhancementCategory: [ #NONE ]

@AccessControl.authorizationCheck: #MANDATORY

@EndUserText.label: 'Foreign Exchange Rate Adjustment'

@Metadata.ignorePropagatedAnnotations: true

@ObjectModel.usageType: { serviceQuality: #B, sizeCategory: #M, dataClass: #MASTER }

@VDM.viewType: #BASIC

define view entity I_FinTransFXRateAdjustment

  as select from ftrt_fix_trans as FXRateAdjustment
  
  association [0..1] to I_CompanyCode             as _CompanyCode           on  $projection.CompanyCode                   = _CompanyCode.CompanyCode
  association [0..1] to I_FinancialTransaction    as _FinTrans              on  $projection.CompanyCode                   = _FinTrans.CompanyCode
                                                                            and $projection.FinancialTransaction          = _FinTrans.FinancialTransaction
                                                                            

{
  key cast(substring(FXRateAdjustment.bearer_id, 1, 4) as bukrs preserving type)    as CompanyCode,
  key cast(substring(FXRateAdjustment.bearer_id, 5, 13) as tb_rfha preserving type) as FinancialTransaction,
  key FXRateAdjustment.cashflow_id as FXRateAdjustmentCashFlowCode,
  key FXRateAdjustment.ira_date as FXRateAdjustmentFixingDate,
  key cast(FXRateAdjustment.fixing_ref_id as ftr_fixing_ref_id) as ForeignExchangeFixingReference,
      FXRateAdjustment.lcurr as LeadingCurrency,
      FXRateAdjustment.fcurr as FollowingCurrency,
      FXRateAdjustment.fx_rate as FXRateAdjustmentFixingRate,
      FXRateAdjustment.factor_lcurr as FXRateAdjustmentLdngCrcyFactor,
      FXRateAdjustment.factor_fcurr as FXRateAdjustmentFllwngCrcyFctr,
      FXRateAdjustment.fixed_by as FXRateAdjustmentFixedByUser,
      FXRateAdjustment.term_from as FXRateAdjustmentEffctvFrmDate,
      cast(FXRateAdjustment.regi_state as ftr_fixing_fx_regi_state preserving type ) as FXRateAdjustmentStatus,
      FXRateAdjustment.fixing_trigger as FXRateAdjustmentTrigger,
      FXRateAdjustment.fixing_date as FXRateAdjustmentCreatedDate,
      FXRateAdjustment.fixing_time as FXRateAdjustmentCreatedTime,  
      
      //association

      _CompanyCode,
      _FinTrans
}

where FXRateAdjustment.activity_state = '01'
and FXRateAdjustment.bearer_cat = '06'