I_FinPostingClearingHeader

@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.privilegedAssociations: ['_CreatedByContactCard']
@EndUserText.label: 'Posting and Clearing Service Header'
@VDM.viewType: #COMPOSITE
@ObjectModel.usageType.serviceQuality:#C
@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.dataClass:#MIXED
@Metadata.ignorePropagatedAnnotations: true

define view entity I_FinPostingClearingHeader
  as select from I_JournalEntry //Posted document


  association [0..1] to I_CompanyCode     as _CompanyCode             on  $projection.CompanyCode = _CompanyCode.CompanyCode
  association [0..*] to I_CurrencyText    as _TransactionCurrencyText on  $projection.TransactionCurrency = _TransactionCurrencyText.Currency
  association [0..1] to I_BusinessPlace   as _Branch                  on  $projection.CompanyCode = _Branch.CompanyCode
                                                                      and $projection.Branch      = _Branch.BusinessPlace
  association [0..1] to I_UserContactCard as _CreatedByContactCard    on  $projection.AccountingDocCreatedByUser = _CreatedByContactCard.ContactCardID

{
  key cast ( hextobin('00000000000000000000000000000000') as fdc_dft_key preserving type ) as PostingClearingDocumentUUID,
      @ObjectModel.foreignKey.association: '_CompanyCode'
  key CompanyCode,
  key FiscalYear,
  key AccountingDocument,

      /* BKPF fields */
      @ObjectModel.foreignKey.association: '_AccountingDocumentType'
      AccountingDocumentType, //113

      DocumentDate,
      PostingDate,
      cast( right(FiscalPeriod,2) as monat )                                               as PostingFiscalPeriod,
      AccountingDocumentCreationDate                                                       as JournalEntryCreationDate,
      CreationTime                                                                         as JournalEntryCreationTime, //119

      ExchangeRateDate,               //127

      @ObjectModel.foreignKey.association: '_CreatedByContactCard'
      AccountingDocCreatedByUser,
      TransactionCode,                //129

      DocumentReferenceID,            //131

      AccountingDocumentHeaderText,   //137

      @ObjectModel.foreignKey.association: '_TransactionCurrency'
      TransactionCurrency,           
      AbsoluteExchangeRate,         
      ExchRateIsIndirectQuotation,    //151

      @ObjectModel.foreignKey.association: '_BusinessTransactionType'
      BusinessTransactionType,        //178

      @ObjectModel.foreignKey.association: '_ReferenceDocumentType'
      ReferenceDocumentType,          //184

      @ObjectModel.foreignKey.association: '_CompanyCodeCurrency'
      CompanyCodeCurrency,            //198

      AdditionalCurrency1,            //200

      TaxIsCalculatedAutomatically,   //215

      TaxBaseAmountIsNetAmount,       //224

      @ObjectModel.foreignKey.association: '_Branch'
      Branch,                         //260

      NmbrOfPages,                    //261

      Ledger,                         //275

      ExchangeRateType,               //287

      JournalEntryLastChangeDateTime, //315


      /* Foreign Key Associations */
      _CompanyCode, //333

      _AccountingDocumentType, //335

      _CompanyCodeCurrency,
      _TransactionCurrency,    //337

      _BusinessTransactionType, //342

      _ReferenceDocumentType,   //344

      _Branch,
      _CreatedByContactCard,

      /* Text Associations */
      _AccountingDocumentTypeText, //362

      _TransactionCurrencyText
}