I_FinInstrActivityCategoryText

@AbapCatalog.buffering.status: #NOT_ALLOWED
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.sqlViewName: 'IFININSTRACTCATT'
@AccessControl.authorizationCheck: #NOT_REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'Fin Instrument Activity Category - Text'
@ObjectModel.dataCategory: #TEXT
@ObjectModel.supportedCapabilities: [ #LANGUAGE_DEPENDENT_TEXT, #SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE, #CDS_MODELING_ASSOCIATION_TARGET, #EXTRACTION_DATA_SOURCE ]
@ObjectModel.modelingPattern: #LANGUAGE_DEPENDENT_TEXT
@ObjectModel.representativeKey: 'FinancialInstrActivityCategory'
@ObjectModel.usageType.dataClass: #MASTER
@ObjectModel.usageType.serviceQuality: #B
@ObjectModel.usageType.sizeCategory: #M
@Analytics.dataExtraction.enabled: true
@Analytics.dataExtraction.delta.changeDataCapture.automatic: true
@ObjectModel.sapObjectNodeType.name: 'FinInstrActivityCategoryText'
@Metadata.ignorePropagatedAnnotations: true 
@VDM.viewType: #BASIC
@Search.searchable: true
@Consumption.ranked: true

define view I_FinInstrActivityCategoryText
  as select from at02t
  association [0..1] to I_Language                 as _Language              on $projection.Language = _Language.Language
  association [0..1] to I_FinancialInstrProdCat    as _ProductCategory       on $projection.FinancialInstrProductCategory  = _ProductCategory.FinancialInstrProductCategory
  association [0..1] to I_FinInstrTransCat         as _TransactionCategory   on $projection.FinancialInstrProductCategory  = _TransactionCategory.FinancialInstrProductCategory
                                                                            and $projection.FinInstrTransactionCategory    = _TransactionCategory.FinInstrTransactionCategory
  association [0..1] to I_FinInstrActivityCategory as _ActivityCategory      on $projection.FinancialInstrProductCategory  = _ActivityCategory.FinancialInstrProductCategory
                                                                            and $projection.FinInstrTransactionCategory    = _ActivityCategory.FinInstrTransactionCategory
                                                                            and $projection.FinancialInstrActivityCategory = _ActivityCategory.FinancialInstrActivityCategory
{
  @Semantics.language: true
  @ObjectModel.foreignKey.association: '_Language'
  key spras    as Language,
  @ObjectModel.foreignKey.association: '_ProductCategory'
  key sanlfor  as FinancialInstrProductCategory,
  @ObjectModel.foreignKey.association: '_TransactionCategory'
  key sfgtyp   as FinInstrTransactionCategory,
  @ObjectModel.foreignKey.association: '_ActivityCategory'
  key sfgzustt as FinancialInstrActivityCategory,

  @Semantics.text: true
  @Search.defaultSearchElement: true
  @Search.fuzzinessThreshold: 0.8
  @Search.ranking: #LOW
  xtext        as FinInstrActivityCategoryName,

  _Language,
  _ProductCategory,
  _TransactionCategory,
  _ActivityCategory
}