I_FMEAObject

@VDM.viewType: #BASIC
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Objects of an FMEA'
@ObjectModel.representativeKey: 'FMEAObjectUUID'
@ObjectModel.usageType: { serviceQuality: #B, sizeCategory: #M, dataClass: #TRANSACTIONAL }
define view entity I_FMEAObject
  as select from plmm_audit_obj
  association [0..1] to I_FailureModeEffectAnalysis as _FailureModeEffectAnalysis on  $projection.FMEAHeaderUUID = _FailureModeEffectAnalysis.FMEAHeaderUUID
  association [0..1] to I_FMEAType                  as _FMEAType                  on  $projection.FMEAType = _FMEAType.FMEAType
  association [0..1] to I_FMEATypeObjectType        as _FMEATypeObjectType        on  $projection.FMEAType           = _FMEATypeObjectType.FMEAType
                                                                                  and $projection.FMEATypeObjectType = _FMEATypeObjectType.FMEATypeObjectType
  association [0..1] to I_Product                   as _Product                   on  $projection.Material = _Product.Product
  association [0..1] to I_BillOfOperationsOpBasic   as _BOOOperationBasic         on  $projection.BillOfOperationsType        = _BOOOperationBasic.BillOfOperationsType
                                                                                  and $projection.BillOfOperationsGroup       = _BOOOperationBasic.BillOfOperationsGroup
                                                                                  and $projection.BOOOperationInternalID      = _BOOOperationBasic.BOOOperationInternalID
                                                                                  and $projection.BOOOpInternalVersionCounter = _BOOOperationBasic.BOOOpInternalVersionCounter

  //Extension

  association [1..1] to E_FMEAObject                as _Extension                 on  $projection.FMEAObjectUUID = _Extension.FMEAObjectUUID
{
  key cast( plmm_audit_obj.guid as plmt_fmea_node_guid preserving type )         as FMEAObjectUUID,
      cast( plmm_audit_obj.project_guid as plmt_fmea_node_guid preserving type ) as FMEAHeaderUUID,
      plmm_audit_obj.audit_type                                                  as FMEAType,
      plmm_audit_obj.object_type                                                 as FMEATypeObjectType,
      plmm_audit_obj.object_value                                                as FMEAObject,

      case when  plmm_audit_obj.object_type = '80' or plmm_audit_obj.object_type = '82'
           then plmm_audit_obj.object_value else null end                        as Material,
      case when plmm_audit_obj.object_type = '81'
           then cast(substring(plmm_audit_obj.object_value,1,1) as plnty preserving type )
           else null end                                                         as BillOfOperationsType,
      case when plmm_audit_obj.object_type = '81'
           then cast(substring(plmm_audit_obj.object_value,2,8) as plnnr preserving type )
       else null end                                                             as BillOfOperationsGroup,
      case when plmm_audit_obj.object_type = '81'
           then cast(substring(plmm_audit_obj.object_value,10,8) as plnkn )
       else null end                                                             as BOOOperationInternalID,
      case when plmm_audit_obj.object_type = '81'
           then cast(substring(plmm_audit_obj.object_value,18,8) as cim_count )
       else null end                                                             as BOOOpInternalVersionCounter,
      //      case when plmm_audit_obj.object_type = '81'

      //           then cast(substring(plmm_audit_obj.object_value,26,2) as plnal preserving type )

      //       else '' end                                                               as BillOfOperationsVariant,

      //      case when plmm_audit_obj.object_type = '81'

      //           then cast(substring(plmm_audit_obj.object_value,28,6) as plnfolge preserving type )

      //       else '' end                                                               as BillOfOperationsSequence,


      //Associations

      _FailureModeEffectAnalysis,
      _FMEAType,
      _FMEATypeObjectType,
      _Product,
      _BOOOperationBasic
}