I_EntProjectElementJVA

DDL: I_ENTPROJECTELEMENTJVA Type: view_entity BASIC Package: VDM_PPM_OBJECTS_TASK

Joint Venture Accounting for Proj Elmnt

I_EntProjectElementJVA is a Basic CDS View that provides data about "Joint Venture Accounting for Proj Elmnt" in SAP S/4HANA. It reads from 2 data sources (prps, /s4ppm/task) and exposes 11 fields with key field ProjectElementUUID. It has 2 associations to related views. Part of development package VDM_PPM_OBJECTS_TASK.

2 data source(s) 11 fields

Data Sources (2)

SourceAliasJoin Type
prps prps inner
/s4ppm/task task from

Associations (2)

CardinalityTargetAliasCondition
[1..1] I_EnterpriseProject _EnterpriseProject $projection.ProjectUUID = _EnterpriseProject.ProjectUUID
[1..1] I_EnterpriseProjectElement _EnterpriseProjectElement $projection.ProjectElementUUID = _EnterpriseProjectElement.ProjectElementUUID

Annotations (10)

NameValueLevelField
AccessControl.authorizationCheck #MANDATORY view
EndUserText.label Joint Venture Accounting for Proj Elmnt view
Metadata.ignorePropagatedAnnotations true view
ObjectModel.usageType.serviceQuality #C view
ObjectModel.usageType.sizeCategory #L view
ObjectModel.usageType.dataClass #MIXED view
ObjectModel.sapObjectNodeType.name EntProjElmntJntVntrAcct view
VDM.viewType #BASIC view
VDM.lifecycle.contract.type #PUBLIC_LOCAL_API view
Analytics.dataExtraction.enabled true view

Fields (11)

KeyFieldSource TableSource FieldDescription
KEY ProjectElementUUID /s4ppm/task guid
ProjectUUID /s4ppm/task project_guid
WBSElementInternalID
JointVenture prps vname
JointVentureCostRecoveryCode prps recid
JointVentureEquityType prps etype
JntVntrProjectType prps otype
JntIntrstBillgClass prps jibcl
JntIntrstBillgSubClass prps jibsa
_EnterpriseProject _EnterpriseProject
_EnterpriseProjectElement _EnterpriseProjectElement 
@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #MANDATORY
@EndUserText.label: 'Joint Venture Accounting for Proj Elmnt'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel:{
  usageType:{
    serviceQuality: #C,
    sizeCategory: #L,
    dataClass: #MIXED
  },
  supportedCapabilities: [ #EXTRACTION_DATA_SOURCE, #SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE, #CDS_MODELING_ASSOCIATION_TARGET ],
  sapObjectNodeType.name: 'EntProjElmntJntVntrAcct'
}
@VDM:{
  viewType: #BASIC,
  lifecycle.contract.type: #PUBLIC_LOCAL_API
}
@Analytics: {
  dataExtraction: {
    enabled: true,
    delta.changeDataCapture: {
      mapping: [
        {
            table: '/s4ppm/task', role: #MAIN,
            viewElement: ['ProjectElementUUID'],
            tableElement: ['guid']
        },
        {
            table: 'prps', role: #LEFT_OUTER_TO_ONE_JOIN,
            viewElement: ['WBSElementInternalID'],
            tableElement: ['pspnr']
        }
      ]
    }
  }
}
define view entity I_EntProjectElementJVA
  as select from /s4ppm/task as task
    inner join   prps        as prps on prps.pspnr = task.pspnr
  association [1..1] to I_EnterpriseProject        as _EnterpriseProject        on $projection.ProjectUUID = _EnterpriseProject.ProjectUUID
  association [1..1] to I_EnterpriseProjectElement as _EnterpriseProjectElement on $projection.ProjectElementUUID = _EnterpriseProjectElement.ProjectElementUUID
{
  key task.guid                                         as ProjectElementUUID,
      task.project_guid                                 as ProjectUUID,
      cast( prps.pspnr as ps_s4_pspnr preserving type ) as WBSElementInternalID,

      prps.vname                                        as JointVenture,
      prps.recid                                        as JointVentureCostRecoveryCode,
      prps.etype                                        as JointVentureEquityType,
      prps.otype                                        as JntVntrProjectType,
      prps.jibcl                                        as JntIntrstBillgClass,
      prps.jibsa                                        as JntIntrstBillgSubClass,

      _EnterpriseProject,
      _EnterpriseProjectElement
}

Learn More