I_EHSTaskDefinitionTP

@AbapCatalog.sqlViewName: 'IEHSTASKDEFRTTP'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.personalData.blocking: #('TRANSACTIONAL_DATA')
@AccessControl.privilegedAssociations:  [ '_CreatedByUser', '_LastChangedByUser', '_EHSTaskDefReference','_EHSTaskDefReportingInfo', '_EHSTaskDefMaintenance' , '_EHSTaskDefinitionMoC', '_EHSTaskDefAssigneeNotifEvt', 
                                          '_EHSTaskDefApproverNotifEvt', '_EHSTaskDefOwnerNotifEvt', '_EHSTaskLearning', '_EHSTaskPlannedInstance', '_EHSTskDefSourceDocument' ]
@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'EHSTask Definition TP'
@ObjectModel.compositionRoot:true
@ObjectModel.transactionalProcessingEnabled:true
@ObjectModel.createEnabled:true
@ObjectModel.updateEnabled:true
@ObjectModel.deleteEnabled:'EXTERNAL_CALCULATION'
@ObjectModel.draftEnabled:true                   //draft processing

@ObjectModel.representativeKey: 'EHSTaskDefinitionUUID'
@ObjectModel.semanticKey: ['EHSTaskDefinitionUUID']
// used for BOBF Master Data Object

@ObjectModel.usageType:{ serviceQuality: #C,        // < 15 msec

                         sizeCategory:  #M,         // < 100.000

                         dataClass: #MASTER }
@ObjectModel.entityChangeStateId: 'LastChangeUTCDateTime'
@ObjectModel.writeActivePersistence: 'EHFNDD_TDEF_ROOT'
@ObjectModel.writeDraftPersistence: 'EHFNDW_TDEF_ROOT'
@ObjectModel.sapObjectNodeType.name: 'EHSTaskDefinition'
@Search.searchable: false

@VDM: {
  lifecycle.contract.type:#SAP_INTERNAL_API,
  viewType: #TRANSACTIONAL
}
define view I_EHSTaskDefinitionTP
  as select from I_EHSTaskDefinition as EHSTaskDefinition 
  association [0..1] to I_User                         as _CreatedByUser              on $projection.CreatedByUser = _CreatedByUser.UserID
  association [0..1] to I_User                         as _LastChangedByUser          on $projection.LastChangedByUser = _LastChangedByUser.UserID
  association [0..1] to I_EHSTaskDefAssgmtType         as _EHSTaskAssignedType        on $projection.EHSTaskAssignedType = _EHSTaskAssignedType.EHSTaskDefAssgmtType
  association [0..1] to I_EHSTaskDefAssgmtType         as _EHSTaskApproverType        on $projection.EHSTaskApproverType = _EHSTaskApproverType.EHSTaskDefAssgmtType
  association [0..1] to I_EHSTaskDefExecutionTP        as _EHSTaskDefinitionExecution on $projection.EHSTaskDefinitionUUID = _EHSTaskDefinitionExecution.EHSTaskDefinitionUUID
  association [0..*] to I_EHSTaskDefReferenceTP        as _EHSTaskDefReference        on $projection.EHSTaskDefinitionUUID = _EHSTaskDefReference.EHSTaskDefinitionUUID
  association [0..1] to I_EHSTaskDefMaintenanceTP      as _EHSTaskDefMaintenance      on $projection.EHSTaskDefinitionUUID = _EHSTaskDefMaintenance.EHSTaskDefinitionUUID
  association [0..1] to I_EHSTaskDefMgmtOfChangeTP     as _EHSTaskDefinitionMoC       on $projection.EHSTaskDefinitionUUID = _EHSTaskDefinitionMoC.EHSTaskDefinitionUUID
  association [0..*] to I_EHSTaskPlannedInstanceTP     as _EHSTaskPlannedInstance     on $projection.EHSTaskDefinitionUUID = _EHSTaskPlannedInstance.EHSTaskDefinitionUUID
  association [0..1] to I_EHSLocationPersonRespRole    as _EHSTaskAssignedLocRole     on $projection.EHSTaskAssignedLocRole = _EHSTaskAssignedLocRole.EHSLocationPersonRespRole
  association [0..1] to I_EHSLocationPersonRespRole    as _EHSTaskApproverLocRole     on $projection.EHSTaskApproverLocRole = _EHSTaskApproverLocRole.EHSLocationPersonRespRole
  association [0..1] to I_EHSTaskDefReportInfoTP       as _EHSTaskDefReportingInfo    on $projection.EHSTaskDefinitionUUID = _EHSTaskDefReportingInfo.EHSTaskDefinitionUUID
  association [0..*] to I_EHSTaskDefAssigneeNotifEvtTP as _EHSTaskDefAssigneeNotifEvt on $projection.EHSTaskDefinitionUUID = _EHSTaskDefAssigneeNotifEvt.EHSTaskDefinitionUUID
  association [0..*] to I_EHSTaskDefApproverNotifEvtTP as _EHSTaskDefApproverNotifEvt on $projection.EHSTaskDefinitionUUID = _EHSTaskDefApproverNotifEvt.EHSTaskDefinitionUUID
  association [0..*] to I_EHSTaskDefOwnerNotifEvtTP    as _EHSTaskDefOwnerNotifEvt    on $projection.EHSTaskDefinitionUUID = _EHSTaskDefOwnerNotifEvt.EHSTaskDefinitionUUID
  association [0..1] to I_EHSTaskLearningTP            as _EHSTaskLearning            on $projection.EHSTaskDefinitionUUID = _EHSTaskLearning.EHSTaskDefinitionUUID
  association [0..1] to I_EHSTskDefSourceDocumentTP    as _EHSTskDefSourceDocument    on $projection.EHSTaskDefinitionUUID = _EHSTskDefSourceDocument.EHSTaskDefinitionUUID
  // Extension include

  association [1..1] to E_EHSTaskDefinition            as _Extension                  on $projection.EHSTaskDefinitionUUID = _Extension.EHSTaskDefinitionUUID
{

  key EHSTaskDefinitionUUID,

      // ADMIN FIELDS

      @ObjectModel.readOnly: true
      CreationUTCDateTime,
      @ObjectModel.readOnly: true
      CreatedByUser,
      @ObjectModel.readOnly: true
      LastChangeUTCDateTime,
      @ObjectModel.readOnly: true
      LastChangedByUser,

      // HOST OBJECT

      @ObjectModel.readOnly: true
      EHSTaskHostObjectInstanceUUID,
      @ObjectModel.readOnly: true
      EHSTaskHostObjectInstance,
      @ObjectModel.readOnly: true
      EHSTaskHostObjectAdapterClass,
      @ObjectModel.readOnly: true
      EHSTaskWorkflowEvent,

      // TASK DEFINITION - The WHO and WHAT


      @ObjectModel.mandatory: true
      EHSTaskPriority,
      @ObjectModel : {
        enabled: 'EXTERNAL_CALCULATION',
        readOnly: 'EXTERNAL_CALCULATION',
        mandatory: 'EXTERNAL_CALCULATION'
      }
      EHSTaskAssignedUser,
      @ObjectModel : {
        enabled: 'EXTERNAL_CALCULATION',
        readOnly: 'EXTERNAL_CALCULATION',
        mandatory: 'EXTERNAL_CALCULATION'
      }
      EHSTaskOwnerUser,
      @ObjectModel : {
        enabled: 'EXTERNAL_CALCULATION',
        readOnly: 'EXTERNAL_CALCULATION',
        mandatory: 'EXTERNAL_CALCULATION'
      }
      EHSTaskApprovingUser,
      EHSTaskDefinitionStatus,

      @Semantics.text: true
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @ObjectModel.mandatory: true
      EHSTaskTitle,
      EHSTaskDescription,

      // LOCATION

      @ObjectModel : {
        enabled: 'EXTERNAL_CALCULATION',
        readOnly: 'EXTERNAL_CALCULATION',
        mandatory: 'EXTERNAL_CALCULATION'
      }
      EHSLocationUUID,

      @ObjectModel : {
        enabled: 'EXTERNAL_CALCULATION',
        readOnly: 'EXTERNAL_CALCULATION',
        mandatory: 'EXTERNAL_CALCULATION'
      }
      EHSTaskStartDate,

      // DUE DATE


      @ObjectModel : {
        mandatory: 'EXTERNAL_CALCULATION'
      }
      EHSTaskDueInValue,
      @ObjectModel : {
        mandatory: 'EXTERNAL_CALCULATION'
      }
      EHSTaskDueInUnit,
      @ObjectModel : {
        mandatory: 'EXTERNAL_CALCULATION'
      }
      EHSTaskDueDate,
      EHSTaskIsDueOnSameDay,

      // START BEFORE


      @ObjectModel : {
        mandatory: 'EXTERNAL_CALCULATION'
      }
      EHSTaskStartBeforeValue,
      @ObjectModel : {
        mandatory: 'EXTERNAL_CALCULATION'
      }
      EHSTaskStartBeforeUnit,

      // SCHEDULLING


      EHSTaskRecurrenceIsByDueDate,
      EHSTaskRecurrenceType,
      EHSTaskRecurrenceInterval,
      EHSTaskIsRecurringOnMonday,
      EHSTaskIsRecurringOnTuesday,
      EHSTaskIsRecurringOnWednesday,
      EHSTaskIsRecurringOnThursday,
      EHSTaskIsRecurringOnFriday,
      EHSTaskIsRecurringOnSaturday,
      EHSTaskIsRecurringOnSunday,
      EHSTaskRecurrenceDay,
      EHSTaskRecurrenceMonth,
      EHSTaskRecurrenceOffset,
      EHSTaskRecurrenceWeekDay,
      EHSTaskRecurrenceEndType,
      EHSTaskRecurrenceEndDate,
      @ObjectModel : {
        enabled: 'EXTERNAL_CALCULATION',
        readOnly: 'EXTERNAL_CALCULATION',
        mandatory: 'EXTERNAL_CALCULATION'
      }
      EHSTaskRecurrenceFirstDueDate,
      EHSTaskDefinitionIsPaused,

      EHSTaskID,
      EHSTaskMigrationSource,

      @ObjectModel : {
        enabled: 'EXTERNAL_CALCULATION',
        readOnly: 'EXTERNAL_CALCULATION',
        mandatory: 'EXTERNAL_CALCULATION'
      }
      cast( EHSTaskAssignedType as ehfnd_tdef_assignee_type_char ) as EHSTaskAssignedType,
      @ObjectModel : {
        enabled: 'EXTERNAL_CALCULATION',
        readOnly: 'EXTERNAL_CALCULATION',
        mandatory: 'EXTERNAL_CALCULATION'
      }
      EHSTaskAssignedLocRole,

      @ObjectModel : {
        enabled: 'EXTERNAL_CALCULATION',
        readOnly: 'EXTERNAL_CALCULATION',
        mandatory: 'EXTERNAL_CALCULATION'
      }
      cast( EHSTaskApproverType as ehfnd_tdef_approver_type_char ) as EHSTaskApproverType,
      @ObjectModel : {
        enabled: 'EXTERNAL_CALCULATION',
        readOnly: 'EXTERNAL_CALCULATION',
        mandatory: 'EXTERNAL_CALCULATION'
      }
      EHSTaskApproverLocRole,

      @ObjectModel.readOnly: true
      _EHSTaskDefinitionType.EHSTaskDefinitionManageAction,
      @ObjectModel.readOnly: true
      _EHSTaskDefinitionType.EHSTaskInstanceDisplayAction,
      @ObjectModel.readOnly: true
      _EHSTaskDefinitionType.EHSTaskIsEnabledForReferencing,

      _CreatedByUser,
      _LastChangedByUser,
      _EHSTaskOwnerUser,
      _EHSTaskAssignedUser,
      _EHSTaskAssignedType,
      _EHSTaskAssignedLocRole,
      _EHSTaskApprovingUser,
      _EHSTaskApproverType,
      _EHSTaskApproverLocRole,
      _EHSTaskPriority,
      _EHSTaskDefinitionStatus,
      _EHSTaskDueInUnit,
      _EHSTaskStartBeforeUnit,
      _EHSTaskRecurrenceType,
      _EHSTaskRecurrenceOffset,
      _EHSTaskRecurrenceWeekDay,
      _EHSTaskRecurrenceMonth,
      _EHSTaskRecurrenceEndType,
      _EHSTaskDefinitionType,
      _EHSTaskAdapterClass,

      @ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
      _EHSTaskDefinitionExecution,

      @ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
      _EHSTaskDefReference,
      
      @ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
      _EHSTaskDefReportingInfo,
      
      @ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
      _EHSTaskLearning,
      
      @ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
      _EHSTaskDefMaintenance,

      @ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
      _EHSTaskDefinitionMoC,

      @ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
      _EHSTaskPlannedInstance,

      @ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
      @ObjectModel : {
        createEnabled: 'EXTERNAL_CALCULATION'
      }
      _EHSTaskDefAssigneeNotifEvt,

      @ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
      @ObjectModel : {
        createEnabled: 'EXTERNAL_CALCULATION'
      }
      _EHSTaskDefApproverNotifEvt,

      @ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
      @ObjectModel : {
        createEnabled: 'EXTERNAL_CALCULATION'
      }
      _EHSTaskDefOwnerNotifEvt,
      
      @ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
      @ObjectModel : {
        createEnabled: 'EXTERNAL_CALCULATION'
      }
      _EHSTskDefSourceDocument,
      _EHSTskDefSourceDocument.EHSAttachmentServiceFileID,
      _EHSTskDefSourceDocument.EHSTskDefSrceDocPageNumber,
      _EHSTskDefSourceDocument.EHSTskDefSrceDocTxtFragmentId,
      _EHSTskDefSourceDocument.EHSAttachmentServiceObjectType,
      _EHSTskDefSourceDocument.EHSAttachmentServiceObjectKey,

      // Associations for Authorization Check of Host BO

      _IncidentAuthorizationFields,
      _EHSCtrlImplmtnAuthznFields,
      _EHSRskAssessmentAuthznFields,
      _EHSRskAssmt2RskCtrlAuthznFld,
      _EHSCmplncScenAuthznFields,
      _CmplncRqmtAuthznFields,
      _IncidentTaskRefAccRestricted,
      @ObjectModel.readOnly: true
      _IncidentTaskRefAccRestricted.IncidentHasAccessRestriction
}