I_EHSLocationRoot

@AbapCatalog:{
    sqlViewName: 'ILOCATIONROOT',
    compiler.compareFilter: true
 }
@EndUserText.label: 'EHS Location'
@Analytics.dataCategory:#DIMENSION
@Analytics.dataExtraction: {
  enabled: true,
  delta.changeDataCapture.automatic: true
}
@VDM.viewType: #BASIC
@AccessControl: { authorizationCheck: #MANDATORY,
                  privilegedAssociations: [ '_CreatedByUser', '_LastChangedByUser' ] }
// Client handling by session

@ClientHandling.algorithm: #SESSION_VARIABLE
@Metadata: { allowExtensions: true,
             ignorePropagatedAnnotations: true }
@ObjectModel:{
    representativeKey: 'EHSLocationUUID',
    compositionRoot: true,
    // used for BOBF Master Data Object

    usageType:{ serviceQuality: #A,        
                sizeCategory:  #M,         // < 100.000

                dataClass: #MASTER },
    sapObjectNodeType.name: 'EHSLocation',
    modelingPattern: #NONE,
    supportedCapabilities: [ #ANALYTICAL_DIMENSION, #EXTRACTION_DATA_SOURCE, #CDS_MODELING_ASSOCIATION_TARGET ]
}

define view I_EHSLocationRoot
  as select from ehfndd_loc_root
  association [0..1] to I_User                       as _CreatedByUser              on $projection.CreatedByUser = _CreatedByUser.UserID
  association [0..1] to I_User                       as _LastChangedByUser          on $projection.LastChangedByUser = _LastChangedByUser.UserID
  association [0..*] to I_EHSLocationRevision        as _EHSLocationRevision        on $projection.EHSLocationUUID = _EHSLocationRevision.EHSLocationUUID
  association [0..*] to I_EHSLocNameCurrentRevision  as _EHSLocNameCurrentRevision  on $projection.EHSLocationUUID = _EHSLocNameCurrentRevision.EHSLocationUUID
  association [0..1] to I_EHSLocNameFallbackLanguage as _EHSLocNameFallbackLanguage on $projection.EHSLocationUUID = _EHSLocNameFallbackLanguage.EHSLocationUUID
{
  key cast( db_key as ehfnd_location_uuid_ref preserving type)          as EHSLocationUUID,
      cast( crea_date_time as ehfnd_bo_crea_date_time preserving type ) as CreationDateTime,
      cast( crea_uname as ehfnd_bo_crea_uname preserving type )         as CreatedByUser,
      _CreatedByUser,
      cast( lchg_date_time as ehfnd_bo_lchg_date_time preserving type ) as LastChangeDateTime,
      cast( lchg_uname as ehfnd_bo_lchg_uname preserving type )         as LastChangedByUser,
      _LastChangedByUser,
      id                                                                as EHSLocationID,
      migration_src                                                     as LocationMigrationSource,
      waste_reg_nmbr                                                    as WasteRegistrationNumber,

      _EHSLocationRevision,
      _EHSLocNameCurrentRevision,
      _EHSLocNameFallbackLanguage
}