I_EHSLocationIncludingRoot

@EndUserText.label: 'EHS Location Including the Root Location'
@VDM.viewType: #COMPOSITE
@ObjectModel.representativeKey: 'EHSLocationUUID'

@AccessControl.authorizationCheck: #MANDATORY

@AbapCatalog.sqlViewName: 'IEHSLOCIROOT'
@AbapCatalog.compiler.compareFilter: true

// Client handling by session 

@ClientHandling.algorithm: #SESSION_VARIABLE

// used for BOBF Master Data Object

@ObjectModel.usageType:{ serviceQuality: #C,        // < 15 msec   

                         sizeCategory:  #XL,         // < 100.000.000

                         dataClass: #MASTER } 
                         
define view I_EHSLocationIncludingRoot 
  as select from I_EHSLocation
  {
    key I_EHSLocation.EHSLocationUUID,  
    key RevisionEndDate,
    RevisionStartDate,
    _EHSLocationRevisionName[1: Language = $session.system_language].EHSLocationName,
    EHSLocationType,
    EHSLocationStatus,
    
    // fields for authorization check

    EHSLocationAuthorizationGroup,
    Plant,
    CostCenter,
    CompanyCode,
    BusinessArea,
    EHSLocationID
  }
    
  union select from I_SAPClient // this generates a dummy topmost location

  association [0..*] to I_OTRText as _OTRText on _OTRText.Language = $session.system_language
  { 
     key cast( hextobin( '00000000000000000000000000000000' ) as ehfnd_location_uuid_ref preserving type ) as EHSLocationUUID,
     key cast( '99991231' as ehfnd_revision_split_date ) as RevisionEndDate,
     cast( '00000000' as ehfnd_revision_end_date ) as RevisionStartDate,
     cast( _OTRText[1: OnlnTxtRpstryConceptID = '4544824ECF3DF419E10000000A428B9F'].Text as ehfnd_loc_name ) as EHSLocationName, // OTR Text for "Locations" 

     '' as EHSLocationType,
     // begin correction 2618695 15.03.2018

     '-1' as EHSLocationStatus, // to pass this pseude location through the dcl

     // end correction 2618695 15.03.2018

    
    // fields for authorization check

    '' as EHSLocationAuthorizationGroup,
    '' as Plant,
    '' as CostCenter,
    '' as CompanyCode,
    '' as BusinessArea,
    '' as EHSLocationID
  } where sapclient = $session.client