I_EHSJob

@EndUserText.label: 'EHS Job'
@Analytics: { dataCategory:#DIMENSION , dataExtraction.enabled:true }
@VDM.viewType: #BASIC
@ObjectModel.representativeKey: 'EHSJobUUID'
@Metadata.allowExtensions:true

@AccessControl.authorizationCheck: #CHECK
@AccessControl.privilegedAssociations: ['_CreatedByUser','_LastChangedByUser']

@AbapCatalog.sqlViewName: 'IEHSJOBROOT'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey:true

// Client handling by session

@ClientHandling.algorithm: #SESSION_VARIABLE

// used for BOBF Master Data Object

@ObjectModel.usageType:{ serviceQuality: #C,        // < 15 msec

                         sizeCategory:  #S,         // < 1.000

                         dataClass: #MASTER }


define view I_EHSJob
  as select from ehhssd_job_root
  association [0..*] to I_EHSJobNameText as _Name              on $projection.EHSJobUUID = _Name.EHSJobUUID
  association [0..1] to I_User           as _CreatedByUser     on $projection.CreatedByUser = _CreatedByUser.UserID
  association [0..1] to I_User           as _LastChangedByUser on $projection.LastChangedByUser = _LastChangedByUser.UserID
  association [0..1] to I_EHSJobType     as _EHSJobType        on $projection.EHSJobType = _EHSJobType.EHSJobType
  association [1..1] to I_EHSJobStatus   as _EHSJobStatus      on $projection.EHSJobStatus = _EHSJobStatus.EHSJobStatus

{
      @ObjectModel.text.association: '_Name'
  key cast( db_key as ehhss_job_uuid_ref preserving type )   as EHSJobUUID,
      _Name,

      datetime_cr                                            as CreationDateTime,
      user_id_cr                                             as CreatedByUser,
      _CreatedByUser,

      datetime_ch                                            as LastChangeDateTime,
      user_id_ch                                             as LastChangedByUser,
      _LastChangedByUser,

      cast( type as ehhss_job_type_code_nc preserving type ) as EHSJobType,
      _EHSJobType,

      @ObjectModel.foreignKey.association: '_EHSJobStatus'
      cast( status as ehhss_job_status_nc preserving type )  as EHSJobStatus,
      _EHSJobStatus,

      @Consumption.filter.hidden: true
      //@Consumption.hidden: true

      //@UI.hidden: true

      id                                                     as EHSJobID,

      migration_src                                          as JobMigrationSource

}