I_EHSControlImpl

@EndUserText.label: 'EHS Risk Control Implementation'
@VDM.viewType: #COMPOSITE
@ObjectModel.representativeKey: 'EHSControlInstanceUUID'
@AccessControl.authorizationCheck: #NOT_REQUIRED  // TODO:  we have to check:   #CHECK


@AbapCatalog.sqlViewName: 'IEHSRISKCTRLIMP'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true

// Client handling by session

@ClientHandling.algorithm: #SESSION_VARIABLE
// used for BOBF Master Data Object

@ObjectModel.usageType:{ serviceQuality: #D,        // < 15 msec

                         sizeCategory:  #L,         // < 10.000.000

                         dataClass: #MIXED }

@AccessControl.personalData.blocking: #NOT_REQUIRED

define view I_EHSControlImpl
  //  with parameters

  //    @Consumption.hidden: true

  //    @Environment.systemField: #SYSTEM_DATE

  //    P_KeyDate  : sydatum

  as select from I_EHSRiskControl

  association [1..1] to I_EHSRiskRoot                  as _RiskRoot                     on $projection.EHSRiskUUID = _RiskRoot.EHSRiskUUID
  association [1..1] to I_EHSRiskRevision              as _RiskRevision                 on $projection.EHSRiskRevisionUUID = _RiskRevision.EHSRiskRevisionUUID  
  association [0..1] to I_EHSCtrlEffect                as _EHSCtrlEffect                on $projection.DesiredEHSControlEffect = _EHSCtrlEffect.DesiredEHSControlEffect
  association [0..1] to I_EHSCtrlGoalTar               as _EHSGoalTarget                on $projection.EHSControlTarget = _EHSGoalTarget.EHSControlTarget

  association [0..1] to P_MinDuDteOfOpnActnInstances   as _MinDuDteOfOpnActnInstances   on $projection.EHSControlInstanceUUIDHex = _MinDuDteOfOpnActnInstances.EHSTaskHostObjectInstance
  association [0..1] to P_NmbrOfEHSTskDefAndInstce     as _NmbrOfEHSTskDefAndInstce     on $projection.EHSControlInstanceUUIDHex = _NmbrOfEHSTskDefAndInstce.EHSTaskHostObjectInstance
  association [0..1] to P_NmbrOfOpenEHSTskDefAndInstce as _NmbrOfOpenEHSTskDefAndInstce on $projection.EHSControlInstanceUUIDHex = _NmbrOfOpenEHSTskDefAndInstce.EHSTaskHostObjectInstance



{

  key EHSControlInstanceUUID,
      EHSControlInstanceUUIDHex,
      EHSControlUUID,
      EHSControlIsAdhoc,
      EHSControlAdhocTitle,
      EHSRiskUUID,
      _RiskRoot,
      EHSRiskRevisionUUID,
      _RiskRevision,

      ResponsiblePerson,

      FunctionalLocation,
      Equipment,
      Material,
      Hazard,
      MaintenanceObject,
      TechObjIsEquipOrFuncnlLoc,


      @ObjectModel.foreignKey.association: '_EHSCtrlImplementationStatus'
      EHSControlImplStatus,
      _EHSCtrlImplementationStatus,

      @ObjectModel.foreignKey.association: '_EHSControlRefCategory'
      EHSControlRefCategory,
      _EHSControlRefCategory,

      @ObjectModel.foreignKey.association: '_EHSCtrlEffect'
      DesiredEHSControlEffect,
      _EHSCtrlEffect,

      @ObjectModel.foreignKey.association: '_EHSGoalTarget'
      EHSControlTarget,
      _EHSGoalTarget,

      EHSControlObjective,


      @ObjectModel.foreignKey.association: '_EHSCatalog'
      _EHSControl.EHSControlCatalog,
      _EHSControl._EHSCatalog,
      _EHSControl,

      _RiskRoot.EHSLocationUUID,

      @ObjectModel.foreignKey.association: '_EHSRiskStatus'
      _RiskRevision.EHSRiskStatus,
      _RiskRevision._EHSRiskStatus,

      @ObjectModel.foreignKey.association: '_EHSRiskLevel'
      _RiskRoot.EHSRiskLevel,
      _RiskRoot._EHSRiskLevel,

      _RiskRevision.EHSRiskAssessmentUUID,

      I_EHSRiskControl.EHSControlRemarkUUID,
      _EHSControlRemarkText,

      cast( case
        when _NmbrOfEHSTskDefAndInstce.NmbrOfEHSTaskDefAndInstce is null
          then  cast('01' as ehhss_ctrl_task_status)
        when _NmbrOfEHSTskDefAndInstce.NmbrOfEHSTaskDefAndInstce = 0
          then  cast('01' as ehhss_ctrl_task_status)
        when _NmbrOfOpenEHSTskDefAndInstce.NmbrOfEHSTaskDefAndInstce  > 0
          then cast('02' as ehhss_ctrl_task_status)
        else
         '03' 
      end as ehhss_ctrl_task_status) as EHSControlTaskStatus,

      //      case

      //        when ( _NmbrOfOpnDefWth0OpnInstances.NumberOfOpenEHSActnDefinitions = 0 or

      //              _NmbrOfOpnDefWth0OpnInstances.NumberOfOpenEHSActnDefinitions is null ) and

      //              _MinDuDteOfOpnActnInstances.EHSActionDueUTCDateTime is not null

      //          then _MinDuDteOfOpnActnInstances.EHSActionDueUTCDateTime

      //      end

      _MinDuDteOfOpnActnInstances.EHSTaskDueDate,

      case
         when _MinDuDteOfOpnActnInstances.EHSTaskDueDate < $session.system_date
         then 1
         else 0
       end as EHSActnDuUTCDteTmeCriticality

}