I_DueDateStatusText

@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.dataCategory: #TEXT
@ObjectModel.representativeKey: 'DueDateStatus'
@ObjectModel.usageType.dataClass: #META
@ObjectModel.usageType.serviceQuality: #A 
@ObjectModel.usageType.sizeCategory: #S 
@EndUserText.label: 'Due Date Status Text'
@VDM.viewType: #BASIC
@Search.searchable: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@AbapCatalog.sqlViewName: 'ISOFDUDTESTST'

define view I_DueDateStatusText
as select from dd07t

association[0..1] to I_DueDateStatus as _DueDateStatus on $projection.DueDateStatus = _DueDateStatus.DueDateStatus
association[0..1] to I_Language as _Language on $projection.Language = _Language.Language
{
    @ObjectModel.foreignKey.association: '_DueDateStatus' 
    @ObjectModel.text.element:  [ 'DueDateStatusDesc' ]  
    key SUBSTRING(dd07t.domvalue_l, 1, 1) as DueDateStatus,
    
    @Semantics.language
    @ObjectModel.foreignKey.association: '_Language' 
    key ddlanguage as Language,
    
    @Semantics.text: true
    @Search.defaultSearchElement: true
    @Search.fuzzinessThreshold: 0.8  
    cast(ddtext as duedatestatusdesc) as DueDateStatusDesc,
    
    //Associations

    _DueDateStatus,
    _Language
} 

where domname = 'DUE_DATE_STATUS' and as4local = 'A';