I_DocumentInfoRecordLinkAttach

@AbapCatalog.sqlViewName: 'IDIRLNKATTCH'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck:#MANDATORY
@EndUserText.label: 'DIR and Attachment details'
@VDM.viewType: #COMPOSITE
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType: {serviceQuality: #C, sizeCategory: #L, dataClass: #TRANSACTIONAL}
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API

define view I_DocumentInfoRecordLinkAttach 
    as select from I_DocumentInfoRecordObjectLink as Objlink
    
    left outer to one join I_DocumentInfoRecordAttachment as _Attachment on  Objlink.DocumentInfoRecordDocType    = _Attachment.DocumentInfoRecordDocType
                                                                      and Objlink.DocumentInfoRecordDocPart    = _Attachment.DocumentInfoRecordDocPart
                                                                      and Objlink.DocumentInfoRecordDocNumber  = _Attachment.DocumentInfoRecordDocNumber
                                                                      and Objlink.DocumentInfoRecordDocVersion = _Attachment.DocumentInfoRecordDocVersion 
{
    /*  Document Info Record key Details */
  key Objlink.DocumentInfoRecordDocType      as DocumentInfoRecordDocType,
  key Objlink.DocumentInfoRecordDocNumber    as DocumentInfoRecordDocNumber,
  key Objlink.DocumentInfoRecordDocVersion   as DocumentInfoRecordDocVersion,
  key Objlink.DocumentInfoRecordDocPart      as DocumentInfoRecordDocPart,

      /*  Object Type and Object Key Details */
  key Objlink.LinkedSAPObject                as LinkedSAPObject,
  key Objlink.LinkedSAPObjectKey             as LinkedSAPObjectKey, 
  
  @Semantics.uuid : true
  _Attachment.FileUUID                       as FileUUID,
  _Attachment.PhysicalDocument               as PhysicalDocument,
  
      _Attachment.FileName                     as  FileName,
      _Attachment.DocumentInfoRecordFileName   as  DocumentInfoRecordFileName,
      _Attachment.FileDescription              as  FileDescription,
      _Attachment.FileSize                     as  FileSize,
      _Attachment.WorkstationApplication       as  WorkstationApplication,
      _Attachment.MimeType                     as  MimeType,
      _Attachment.StorageCategory              as  StorageCategory,      
     cast( _Attachment.IsOriginalVersionActive as abap.char(1))     as  OriginalVersionIsActive,
      _Attachment.OriginalIsProtected          as  OriginalIsProtected,
      _Attachment.DocumentTitle                as  DocumentTitle,
      _Attachment.DocumentFormat               as  DocumentFormat,

      /*  Originals Admin Details */
      _Attachment.CreationDateTime             as  CreationDateTime,

//      @Consumption.valueHelpDefinition:[{association: '_CreatedUser'}]

      @Semantics.user.createdBy: true
      _Attachment.CreatedByUser                as  CreatedByUser,

      @Semantics.businessDate.at: true
      _Attachment.ChangedDateTime              as  ChangedDateTime,

//      @Consumption.valueHelpDefinition:[{association: '_ChangedUser'}]

      @Semantics.user.lastChangedBy: true
      _Attachment.LastChangedByUser            as  LastChangedByUser,

      _Attachment.OriginalCheckedOutTime       as  OriginalCheckedOutTime,

//      @Consumption.valueHelpDefinition:[{association: 'CheckedOutUser' }]

      _Attachment.OriginalCheckedOutUser       as  OriginalCheckedOutUser,

      /*  LOIO and PHIO Details */
      _Attachment.LogicalDocument              as  LogicalDocument,
      _Attachment.LogicalDocumentClass         as  LogicalDocumentClass,
      _Attachment.PhysicalDocumentClass        as  PhysicalDocumentClass,

      _Attachment.LogicalDocumentIsReference   as  LogicalDocumentIsReference,
      _Attachment.OriginalType                 as  OriginalType,
      _Attachment.PhysicalDocTechnicalStatus   as  PhysicalDocTechnicalStatus,
      _Attachment.InternalComment              as  InternalComment,
      
      _Attachment.AttachmentAsURLLength        as  AttachmentAsURLLength,
      _Attachment.AttachmentAsURL              as  AttachmentAsURL
  
}