I_Division

@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.representativeKey: 'Division'
@ObjectModel.usageType.dataClass: #CUSTOMIZING
@ObjectModel.usageType.serviceQuality: #A
@ObjectModel.usageType.sizeCategory: #S
@EndUserText.label: 'Division'
@Analytics.dataCategory: #DIMENSION
@VDM.viewType: #BASIC
@AccessControl.authorizationCheck:  #NOT_REQUIRED
@AbapCatalog.sqlViewName: 'ISDDIVISION'
@Search.searchable: true
@AbapCatalog.buffering.status: #ACTIVE
@AbapCatalog.buffering.type: #FULL
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@Metadata.ignorePropagatedAnnotations: true
@Analytics.dataExtraction.enabled: true

@ObjectModel.modelingPattern:           #ANALYTICAL_DIMENSION
@ObjectModel.supportedCapabilities:  [  #SQL_DATA_SOURCE,
                                        #CDS_MODELING_DATA_SOURCE,
                                        #CDS_MODELING_ASSOCIATION_TARGET,
                                        #ANALYTICAL_DIMENSION,
                                        #SEARCHABLE_ENTITY,
                                        #EXTRACTION_DATA_SOURCE  ]

@ObjectModel.alternativeKey: [{ id: 'OID', uniqueness: #UNIQUE, element: ['DivisionOID'] }]
@ObjectModel.sapObjectNodeType.name: 'Division'
@ObjectModel.objectIdentifier.oidElement:'DivisionOID'

define view I_Division
  as select from           tspa
  association [0..*] to I_DivisionText          as _Text                  on $projection.Division = _Text.Division
  association [0..*] to I_DivisionHierarchyNode as _DivisionHierarchyNode on $projection.Division = _DivisionHierarchyNode.Division

{
      @Search.defaultSearchElement: true
      @Search.ranking: #HIGH
      @Search.fuzzinessThreshold: 0.8
      @ObjectModel.text.association: '_Text'
      @ObjectModel.hierarchy.association: '_DivisionHierarchyNode'
  key spart as Division,

      @ObjectModel.filter.enabled: false
      @ObjectModel.sort.enabled: false
      cast( spart as division_oid ) as DivisionOID,
      
      _DivisionHierarchyNode,
      _Text
};