I_DisputeCaseCompanyCodeVH

DDL: I_DISPUTECASECOMPANYCODEVH Type: view BASIC Package: ODATA_DISPUTE

Dispute Case Company Code

I_DisputeCaseCompanyCodeVH is a Basic CDS View that provides data about "Dispute Case Company Code" in SAP S/4HANA. It reads from 3 data sources (knb1, t001, tfdm_defcc) and exposes 5 fields with key fields Customer, CompanyCode. It has 2 associations to related views. Part of development package ODATA_DISPUTE.

3 data source(s) 5 fields

Data Sources (3)

SourceAliasJoin Type
knb1 knb1 from
t001 t001 inner
tfdm_defcc tfdm_defcc inner

Associations (2)

CardinalityTargetAliasCondition
[0..1] I_Customer _Customer $projection.Customer = _Customer.Customer
[0..1] I_Customer_VH _CustomerVH $projection.Customer = _CustomerVH.Customer

Annotations (16)

NameValueLevelField
AbapCatalog.sqlViewName IDCCCMP view
AbapCatalog.compiler.compareFilter true view
AbapCatalog.preserveKey true view
AccessControl.authorizationCheck #CHECK view
AccessControl.personalData.blocking #BLOCKED_DATA_EXCLUDED view
EndUserText.label Dispute Case Company Code view
VDM.viewType #BASIC view
VDM.lifecycle.contract.type #SAP_INTERNAL_API view
ClientHandling.algorithm #SESSION_VARIABLE view
ObjectModel.usageType.serviceQuality #B view
ObjectModel.usageType.sizeCategory #S view
ObjectModel.usageType.dataClass #MIXED view
ObjectModel.dataCategory #VALUE_HELP view
ObjectModel.resultSet.sizeCategory #XS view
Search.searchable true view
Consumption.ranked true view

Fields (5)

KeyFieldSource TableSource FieldDescription
KEY Customer knb1 kunnr
KEY CompanyCode knb1 bukrs
CompanyCodeName t001 butxt
_Customer _Customer
_CustomerVH _CustomerVH 
@AbapCatalog: { sqlViewName: 'IDCCCMP',
                compiler: { compareFilter: true },
                preserveKey: true }
@AccessControl: { authorizationCheck: #CHECK,
                  personalData:       { blocking: #BLOCKED_DATA_EXCLUDED } }
@EndUserText: { label: 'Dispute Case Company Code' }
@VDM: { viewType:  #BASIC,
        lifecycle: { contract: { type: #SAP_INTERNAL_API } } }
@ClientHandling: { algorithm: #SESSION_VARIABLE }
@ObjectModel: { usageType:         { serviceQuality: #B,
                                     sizeCategory: #S,
                                     dataClass: #MIXED },
                dataCategory:      #VALUE_HELP,
                resultSet: { sizeCategory: #XS } }
@Search: { searchable: true }
@Consumption: { ranked: true,
                dbHints: [ 'USE_HEX_PLAN' ] }

define view I_DisputeCaseCompanyCodeVH
  as select from knb1
    inner join   t001       on knb1.bukrs = t001.bukrs
    inner join   tfdm_defcc on knb1.bukrs = tfdm_defcc.bukrs

  // VDM Associations

  // Customer

  association [0..1] to I_Customer    as _Customer   on $projection.Customer = _Customer.Customer

  // Customer Value Help

  association [0..1] to I_Customer_VH as _CustomerVH on $projection.Customer = _CustomerVH.Customer

{

      // VDM Fields

      @Search: { defaultSearchElement: true,
                 fuzzinessThreshold:   0.8,
                 ranking:              #LOW }
      @Consumption: { valueHelpDefinition: [ { entity: { name: 'I_Customer_VH',
                                                         element: 'Customer' },
                                               association: '_CustomerVH' } ] }
  key knb1.kunnr as Customer,

      @ObjectModel: { text: { element: [ 'CompanyCodeName' ] } }
      @Search: { defaultSearchElement: true,
                 fuzzinessThreshold:   0.8,
                 ranking:              #HIGH }
  key knb1.bukrs as CompanyCode,

      @Semantics: { text: true }
      @Search: { defaultSearchElement: true,
                 fuzzinessThreshold:   0.8,
                 ranking:              #LOW }
      t001.butxt as CompanyCodeName,

      // Exposed Associations

      _Customer,
      _CustomerVH

}

where
      tfdm_defcc.case_type is not initial
  and tfdm_defcc.subject   = '000'

Learn More