I_DirectActivityAllocationItem

@AbapCatalog.sqlViewName: 'IDRCTACTYITM'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK


@ClientHandling.algorithm: #SESSION_VARIABLE
@AccessControl.personalData.blocking: #NOT_REQUIRED
@Metadata.ignorePropagatedAnnotations: true
@VDM.viewType: #COMPOSITE

@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.dataClass:  #MIXED
@ObjectModel.usageType.serviceQuality: #D
@EndUserText.label: 'Direct Activity Allocation Item'

define view I_DirectActivityAllocationItem

  as select from I_GLAccountLineItemRawData as _Item
  
  inner join I_AccountAssignmentType as _AAT
    on _AAT.AccountAssignmentType = _Item.AccountAssignmentType  
  

  association [0..1] to I_WBSElementBasicData          as _PartnerWBSElementText         on  $projection.PartnerWBSElementInternalID = _PartnerWBSElementText.WBSElementInternalID
  
  association [0..1] to I_CostCenterActivityTypeText   as _PartnerCostCtrActivityTypeTxt on  $projection.ControllingArea = _PartnerCostCtrActivityTypeTxt.ControllingArea
                                                                                         and $projection.PartnerCostCtrActivityType = _PartnerCostCtrActivityTypeTxt.CostCtrActivityType  
                                                                                         and $projection.PostingDate <= _PartnerCostCtrActivityTypeTxt.ValidityEndDate
                                                                                         and $projection.PostingDate >= _PartnerCostCtrActivityTypeTxt.ValidityStartDate 
                                                                                         and _PartnerCostCtrActivityTypeTxt.Language = $session.system_language 
    
    
  association [0..1] to I_CostCenterText               as _PartnerCostCenterText         on  $projection.ControllingArea   = _PartnerCostCenterText.ControllingArea
                                                                                         and $projection.PartnerCostCenter = _PartnerCostCenterText.CostCenter
                                                                                         and $projection.PostingDate <= _PartnerCostCenterText.ValidityEndDate
                                                                                         and $projection.PostingDate >= _PartnerCostCenterText.ValidityStartDate 
                                                                                         and _PartnerCostCenterText.Language = $session.system_language
  
  association [0..1] to I_CostCenterActivityTypeText   as _CostCtrActivityTypeTxt        on $projection.ControllingArea = _CostCtrActivityTypeTxt.ControllingArea
                                                                                         and $projection.CostCtrActivityType = _CostCtrActivityTypeTxt.CostCtrActivityType  
                                                                                         and $projection.PostingDate <= _CostCtrActivityTypeTxt.ValidityEndDate
                                                                                         and $projection.PostingDate >= _CostCtrActivityTypeTxt.ValidityStartDate 
                                                                                         and _CostCtrActivityTypeTxt.Language = $session.system_language 
    
    
  association [0..1] to I_CostCenterText               as _CostCenterText                on  $projection.ControllingArea   = _CostCenterText.ControllingArea
                                                                                         and $projection.OriginCostCenter = _CostCenterText.CostCenter
                                                                                         and $projection.PostingDate <= _CostCenterText.ValidityEndDate
                                                                                         and $projection.PostingDate >= _CostCenterText.ValidityStartDate 
                                                                                         and _CostCenterText.Language = $session.system_language
                                                                                         
  association [0..1] to I_CompanyCode                  as _CompanyCodeText               on  $projection.CompanyCode = _CompanyCodeText.CompanyCode
  
  association [1..1] to I_DrctActyAllocSuccssrRefItem  as _SuccessorReferenceItem         on  $projection.ControllingArea   = _SuccessorReferenceItem.ControllingArea
                                                                                          and $projection.ReferenceDocument = _SuccessorReferenceItem.PredecessorReferenceDocument 
                                                                                          and $projection.ReferenceDocumentItem = _SuccessorReferenceItem.PredecessorReferenceDocItem   
    
  association [0..*] to I_FundText                     as _FundText                      on  $projection.FinancialManagementArea = _FundText.FinancialManagementArea
                                                                                         and $projection.Fund                    = _FundText.Fund
  
  association [0..*] to I_FundText                     as _PartnerFundText               on  $projection.FinancialManagementArea = _PartnerFundText.FinancialManagementArea
                                                                                         and $projection.PartnerFund             = _PartnerFundText.Fund
  
  association [0..*] to I_GrantText                    as _GrantText                     on  $projection.GrantID = _GrantText.GrantID
   
  association [0..*] to I_GrantText                    as _PartnerGrantText              on  $projection.PartnerGrant = _PartnerGrantText.GrantID
  
  association [0..*] to I_BudgetPeriodText             as _BudgetPeriodText              on  $projection.BudgetPeriod = _BudgetPeriodText.BudgetPeriod
    
  association [0..*] to I_BudgetPeriodText             as _PartnerBudgetPeriodText       on  $projection.PartnerBudgetPeriod = _PartnerBudgetPeriodText.BudgetPeriod
  
  association [0..*] to I_FunctionalAreaText           as _PartnerFunctionalAreaText     on  $projection.PartnerFunctionalArea = _PartnerFunctionalAreaText.FunctionalArea
  
  association [0..*] to I_FunctionalAreaText           as _FunctionalAreaText            on  $projection.FunctionalArea = _FunctionalAreaText.FunctionalArea
  
  association [0..*] to I_BillableControlText          as _BillableControlText           on  $projection.BillableControl = _BillableControlText.BillableControl
  
  association [0..*] to I_GLAccountText                as _GLAccountText                 on  $projection.GLAccount = _GLAccountText.GLAccount
                                                                                         and $projection.ChartOfAccounts = _GLAccountText.ChartOfAccounts    
                                                                                         
  association [0..*] to I_UnitOfMeasureText            as _UnitOfMeasureText             on $projection.BaseUnit = _UnitOfMeasureText.UnitOfMeasure                                                                                                                                                                          
                                                                                                                                                                                                                             
{
  key FiscalYear,
  key cast(ReferenceDocument as referencedocument) as ReferenceDocument,
  key ControllingArea,
  key CompanyCode,    
  key LedgerGLLineItem,
  key ReferenceDocumentItem,
      _Item.AccountingDocument,
      
      cast(PartnerCompanyCode as sendercompanycode) as SenderCompanyCode,
      
      SourceLedger,
      
      cast(PartnerAccountAssignment as sender_co_obj_k) as AccountAssignment,
      
      cast(PartnerAccountAssignmentType as j_obart) as AccountAssignmentType,
      
      cast(AccountAssignment as receiver_co_obj_k) as PartnerAccountAssignment,
      
      cast(_Item.AccountAssignmentType as receiver_object_type) as PartnerAccountAssignmentType,
      
      cast(PartnerCostCtrActivityType as lstar) as CostCtrActivityType,
      
      cast(CostCenter as fis_skost) as PartnerCostCenter,
      //CostCenter,

      
      cast(PartnerCostCenter as sendercostcenter) as OriginCostCenter,
      
      DocumentItemText,
      
      cast(GLAccount as fco_allocation_account) as GLAccount,      
      
      @Semantics.unitOfMeasure:true
      BaseUnit,
      
      @Semantics: { quantity : {unitOfMeasure: 'BaseUnit'} }
      cast(Quantity as lstxx) as Quantity,
      
      @Semantics: { amount : {currencyCode: 'TransactionCurrency'} }      
      cast(case Quantity
              when 0 then 0
              else division (abs(AmountInTransactionCurrency) , abs(Quantity), 5 ) 
           end as pricetotalamtintranscrcy) as PrcTotAmtInTransactionCurrency,
      
      @Semantics.currencyCode:true
      TransactionCurrency,
      
      @Semantics: { amount : {currencyCode: 'TransactionCurrency'} }
      cast(AmountInTransactionCurrency as fis_wsl) as AmountInTransactionCurrency,
      
      @Semantics.currencyCode:true
      CompanyCodeCurrency,
      @Semantics: { amount : {currencyCode: 'CompanyCodeCurrency'} }
      cast(AmountInCompanyCodeCurrency as fis_hsl) as AmountInCompanyCodeCurrency,
      
      @Semantics: { amount : {currencyCode: 'CompanyCodeCurrency'} }
      cast(case Quantity
              when 0 then 0
              else division (abs(AmountInCompanyCodeCurrency) , abs(Quantity), 5 ) 
           end as pricetotalamtincocodecrcy) as PrcTotAmtInCompanyCodeCurrency,
      
      @Semantics.currencyCode:true
      GlobalCurrency,
      @Semantics: { amount : {currencyCode: 'GlobalCurrency'} }
      cast(AmountInGlobalCurrency as fis_ksl) as AmountInGlobalCurrency,
      
      @Semantics: { amount : {currencyCode: 'GlobalCurrency'} }      
      cast(case Quantity
              when 0 then 0
              else division (abs(AmountInGlobalCurrency) , abs(Quantity), 5 ) 
           end as prctotamtinglobalcurrency) as PrcTotAmtInGlobalCurrency,
      
      //WBS Element

      cast(_WBSElementBasicData.WBSElementExternalID as fis_par_psp_pnr_ext ) as PartnerWBSElementExternalID,
      @API.element.releaseState: #DEPRECATED
      @API.element.successor:   'PartnerWBSElementExternalID'
      @VDM.lifecycle.status:    #DEPRECATED
      @VDM.lifecycle.successor: 'PartnerWBSElementExternalID'
      cast(_WBSElementBasicData.WBSElementExternalID as fis_par_psp_pnr_ext) as PartnerWBSElement,
      cast(WBSElementInternalID as fco_par_psp_pnr) as PartnerWBSElementInternalID,
      
      cast(_ProjectBasicData.ProjectExternalID as fis_part_projectext_no_conv) as PartnerProjectExternalID,
      @API.element.releaseState: #DEPRECATED
      @API.element.successor:   'PartnerProjectExternalID'
      @VDM.lifecycle.status:    #DEPRECATED
      @VDM.lifecycle.successor: 'PartnerProjectExternalID'
      cast(Project as fis_part_project) as PartnerProject,      
      
      //Service Contract Item and Service Order Item

      cast(ServiceDocumentType as fco_psrvdoc_type) as PartnerServiceDocumentType,
      cast(ServiceDocument as fco_psrvdoc_id) as PartnerServiceDocument,
      cast(ServiceDocumentItem as fco_psrvdoc_item_id) as PartnerServiceDocumentItem,
      
      //Network

      cast(ProjectNetwork as par_npln) as PartnerProjectNetwork,
      
      //Activity or Order

      cast(OrderID as fis_par_aufnr) as PartnerOrder,
      cast(RelatedNetworkActivity as par_vornr_auf) as PartnerProjectNetworkActivity,
      
      //Cost Center/Activity Type

      cast(CostCtrActivityType as fis_par_lstar) as PartnerCostCtrActivityType,
      
      //Real Estate Management - Rental Unit

      cast(CompanyCode as pbukrs) as PartnerCompanyCode,
      
      //Cost object

      cast(CostObject as par_kstrg) as PartnerCostObject, 
      
      //Sales Order

      cast(SalesDocument as fis_par_kdauf) as PartnerSalesDocument,
      cast(SalesDocumentItem as fis_par_kdpos) as PartnerSalesDocumentItem,
      
      WorkItem,
      PersonnelNumber,
      cast('' as ckml_f_procnr) as ReceiverProcurementProcess,
      cast( case Product
              when '' then ''
              else Plant
      end as werks_d) as Plant,  
      //Plant,

      Product as Material,  
      cast(BusinessProcess as par_prznr) as PartnerBusinessProcess, 
      Product,      
      
      //Public Sector

      cast(PartnerFund as fm_sfonds) as Fund,
      cast(PartnerFunctionalArea as fm_sfarea) as FunctionalArea,
      cast(PartnerGrant as gm_grant_sender) as GrantID,
      cast(PartnerBudgetPeriod as fm_budget_period) as BudgetPeriod,
      cast(Fund as fm_efonds) as PartnerFund,
      cast(FunctionalArea as fm_efarea) as PartnerFunctionalArea,
      cast(GrantID as gm_grant_receiver) as PartnerGrant,
      cast(BudgetPeriod as fm_pbudget_period) as PartnerBudgetPeriod,
      FinancialManagementArea,
      
      IsSettled,
      BillableControl,    
      
      
      //_Item._JournalEntry.AccountingDocumentHeaderText,

      
      DocumentDate,
      PostingDate,
      //cast(_Item._JournalEntry.ExchangeRateDate as fin_currconvdat) as ExchangeRateDate,

      //_Item._JournalEntry.FiscalPeriod,

      //_Item._JournalEntry.AccountingDocumentCreationDate,

      
      AccountingDocCreatedByUser,    
      
      // Joint Venture

      JointVentureCostRecoveryCode,
      SenderCostRecoveryCode,
      
      @UI.hidden: true
      IsReversal,
      @UI.hidden: true
      IsReversed, 
      
      ReferenceDocumentType,
      
      ReversalReferenceDocument, 
      PredecessorReferenceDocument, 
            
      cast(
        case _Item.AccountAssignmentType
          when 'EO' then AccountAssignment
          else ''
      end as rkeobjnr) as PartnerProfitabilitySegment,
      
      @Semantics.booleanIndicator
      cast(
        case _Item.AccountAssignmentType
          when 'EO' then 'X'
          else ''
      end as profitabilitysegmentisassigned) as PartProfitabilitySgmtIsAssgd,
      
      OperatingConcern,
      
      PredecessorReferenceDocItem,
      IsSettlement,
      
      OrderOperation,
      cast(CompanyCode as pbukrs) as ReceiverRECompanyCode,
      REBusinessEntity as REPartnerBusinessEntity,
      RealEstateBuilding as RealEstatePartnerBuilding,
      RealEstateProperty as RealEstatePartnerProperty,
      RERentalObject as REPartnerRentalObject,
      RealEstateContract as RealEstatePartnerContract,
      REServiceChargeKey as REPartnerServiceChargeKey,
      RESettlementUnitID as REPartnerSettlementUnitID,
      SettlementReferenceDate as PartnerSettlementReferenceDate,
      
      ControllingBusTransacType,
      
      PartnerProfitCenter,
      ProfitCenter,
      
      ServicesRenderedDate,
      
      //Additional amounts

      @Semantics.currencyCode:true
      FreeDefinedCurrency1,
      @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency1'} }
      AmountInFreeDefinedCurrency1,
      
      @Semantics.currencyCode:true
      FreeDefinedCurrency2,
      @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency2'} }
      AmountInFreeDefinedCurrency2,
      
      @Semantics.currencyCode:true
      FreeDefinedCurrency3,
      @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency3'} }
      AmountInFreeDefinedCurrency3,
      
      @Semantics.currencyCode:true
      FreeDefinedCurrency4,
      @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency4'} }
      AmountInFreeDefinedCurrency4,
      
      @Semantics.currencyCode:true
      FreeDefinedCurrency5,
      @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency5'} }
      AmountInFreeDefinedCurrency5,
      
      @Semantics.currencyCode:true
      FreeDefinedCurrency6,
      @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency6'} }
      AmountInFreeDefinedCurrency6,
      
      @Semantics.currencyCode:true
      FreeDefinedCurrency7,
      @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency7'} }
      AmountInFreeDefinedCurrency7,
      
      @Semantics.currencyCode:true
      FreeDefinedCurrency8,
      @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency8'} }
      AmountInFreeDefinedCurrency8,
      
      @Semantics.currencyCode:true
      FunctionalCurrency,
      @Semantics: { amount : {currencyCode: 'FunctionalCurrency'} }
      AmountInFunctionalCurrency,
      
      ChartOfAccounts,
      TransactionSubitem,
      _Item.AccountingDocumentType,
      
      _CompanyCodeText,
      _ReferenceDocumentType,
      _PartnerWBSElementText,      
      _JournalEntry,
      _SuccessorReferenceItem,
      _PartnerCostCtrActivityTypeTxt,
      _PartnerCostCenterText,
      _CostCtrActivityTypeTxt,
      _CostCenterText,
      _FundText,
      _PartnerFundText,
      _GrantText,
      _PartnerGrantText,
      _BudgetPeriodText,
      _PartnerBudgetPeriodText,
      _PartnerFunctionalAreaText,
      _FunctionalAreaText,
      _BillableControlText,
      _GLAccountText,
      _UnitOfMeasureText

}

where
  ( //RKL - Leistungsverrechnung; RKLU - Umbuchung Leist.verr.

    ControllingBusTransacType = 'RKL'
    and ( BusinessTransactionCategory = 'RKL' or BusinessTransactionCategory = 'RKLU' )   
  )
  and
  ReferenceDocumentType = 'COBK'
  and
  OriginCtrlgDebitCreditCode = 'S'
//  and 

//  _Item.Quantity <> 0

  and
  _Ledger.IsLeadingLedger = 'X'
  and _Item.LogicalSystem = '' 
  and _Item._JournalEntry.SenderLogicalSystem = '' 
  and (_Item.SourceLedger = _Item._JournalEntry.LedgerGroup or _Item._JournalEntry.LedgerGroup = '' )