I_DeliveryStatusValuation

@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.personalData.blocking: #('TRANSACTIONAL_DATA')
@EndUserText.label: 'Valuation of Document Status'
@Metadata.ignorePropagatedAnnotations: true
@VDM.viewType: #COMPOSITE
@ObjectModel:{
  representativeKey: 'DeliveryDocument',
  usageType:{
    serviceQuality: #X,
    sizeCategory: #S,
    dataClass: #MIXED
    }
}
define view entity I_DeliveryStatusValuation as select from I_DeliveryDocument
{
  key DeliveryDocument,
  
  ShippingPoint,
  
  cast ( case
    //ready for picking

    when ( OverallPickingStatus = 'A'  or OverallPickingStatus = 'B' ) 
      then '1'
      
    //ready for Confirmation

    when ( 
           ( OverallPickingStatus = '' or OverallPickingStatus = 'C' ) and 
           ( OverallPickingConfStatus = 'A' or OverallPickingConfStatus = 'B' ) 
      ) then '2'
      
    //ready for Goods Issue

    when ( 
           ( OverallGoodsMovementStatus = 'A' or OverallGoodsMovementStatus = 'B' ) and 
           ( OverallPickingStatus = '' or OverallPickingStatus = 'C' ) and 
           ( OverallPickingConfStatus = '' or OverallPickingConfStatus = 'C' ) and 
           ( OverallChmlCmplncStatus = '' or OverallChmlCmplncStatus = 'A' ) and 
           ( OverallDangerousGoodsStatus = '' or OverallDangerousGoodsStatus = 'A' or OverallDangerousGoodsStatus = 'B' ) and 
           ( OverallSafetyDataSheetStatus = '' or OverallSafetyDataSheetStatus = 'A' or OverallSafetyDataSheetStatus = 'B' )
      ) then '3'
      
    //ready for Reverse GI

    when  OverallGoodsMovementStatus = 'C' 
        then '4'
  end as deliverystatusvaluation ) as DeliveryStatusValuation
}