I_DefectLongText

DDL: I_DEFECTLONGTEXT Type: view_entity COMPOSITE Package: VDM_QM_NOTIFICATION

Defect Long Text

I_DefectLongText is a Composite CDS View that provides data about "Defect Long Text" in SAP S/4HANA. It reads from 1 data source (I_NotificationItemLongText) and exposes 12 fields with key fields DefectInternalID, Language, LongTextInternalNumber. It has 1 association to related views. Part of development package VDM_QM_NOTIFICATION.

1 data source(s) 12 fields

Data Sources (1)

SourceAliasJoin Type
I_NotificationItemLongText I_NotificationItemLongText from

Associations (1)

CardinalityTargetAliasCondition
[1..1] I_Defect _Defect $projection.DefectInternalID = _Defect.DefectInternalID

Annotations (12)

NameValueLevelField
AccessControl.authorizationCheck #MANDATORY view
VDM.viewType #COMPOSITE view
VDM.lifecycle.contract.type #PUBLIC_LOCAL_API view
ObjectModel.modelingPattern #NONE view
ObjectModel.usageType.dataClass #TRANSACTIONAL view
ObjectModel.usageType.sizeCategory #L view
ObjectModel.usageType.serviceQuality #A view
ObjectModel.representativeKey LongTextInternalNumber view
ObjectModel.dataCategory #TEXT view
Analytics.technicalName IDEFLONGTXT view
EndUserText.label Defect Long Text view
Metadata.ignorePropagatedAnnotations true view

Fields (12)

KeyFieldSource TableSource FieldDescription
KEY DefectInternalID
KEY Language Language
KEY LongTextInternalNumber LongTextInternalNumber
LongTextID LongTextID
DefectLongText NotificationItemLongText
LongTextCreatedByUser LongTextCreatedByUser
LongTextCreatedAt LongTextCreatedAt
LongTextLastChangedByUser LongTextLastChangedByUser
LongTextLastChangedAt LongTextLastChangedAt
MimeType MimeType
_Defect _Defect
_Language _Language 
@AccessControl.authorizationCheck: #MANDATORY
@VDM: {
    viewType: #COMPOSITE,
    lifecycle.contract.type: #PUBLIC_LOCAL_API
}
@ObjectModel.supportedCapabilities:
    [ #SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE, #CDS_MODELING_ASSOCIATION_TARGET ]
@ObjectModel.modelingPattern: #NONE
@ObjectModel:
    { usageType: {
        dataClass: #TRANSACTIONAL,
        sizeCategory: #L,
        serviceQuality: #A
    },
    representativeKey: 'LongTextInternalNumber',
    dataCategory: #TEXT
}
@Analytics.technicalName: 'IDEFLONGTXT'
@EndUserText.label: 'Defect Long Text'
@Metadata.ignorePropagatedAnnotations: true // Projection from generic NotificationItemLT to DefectLT => Start new with annotations


define view entity I_DefectLongText as select from I_NotificationItemLongText

    association [1..1] to I_Defect as _Defect    on $projection.DefectInternalID = _Defect.DefectInternalID

{

    @ObjectModel.foreignKey.association: '_Defect'
    key cast( I_NotificationItemLongText.Notification as qdefectinternalid preserving type ) as DefectInternalID,
    
    @Semantics.language: true
    @ObjectModel.foreignKey.association: '_Language'
    key Language,
    
    key LongTextInternalNumber,
    
    
    LongTextID,
    
    @EndUserText:{  label: 'Defect Detailed Description',
                    quickInfo: 'Detailed Description of Defect'
    }/* normally you should build a vdm_q* data element and cast the field to it to get the label, but cast to STRING is not allowed */
    @Semantics.text: true
    NotificationItemLongText as DefectLongText,
    
    LongTextCreatedByUser,
    LongTextCreatedAt,
    LongTextLastChangedByUser,
    LongTextLastChangedAt,
    MimeType,
    
    /* Associations */
    _Defect,
    _Language
  
} where I_NotificationItemLongText.Notification like '$%'
    and I_NotificationItemLongText.NotificationItem = '0000'

Learn More