I_DefectFractionEstnProcedTxt

@EndUserText.label: 'Estimation for Fraction of Defects Text'
@VDM: {
    viewType: #BASIC,
    lifecycle.contract.type: #PUBLIC_LOCAL_API
}
@AccessControl.authorizationCheck: #NOT_REQUIRED 
@ObjectModel: {
    usageType: { serviceQuality: #A, sizeCategory: #M, dataClass: #CUSTOMIZING },
    representativeKey: 'DefectFractionEstimationProced',
    dataCategory: #TEXT
}
@Analytics.technicalName: 'IDFTFRCNESTNPRCT'
@Search.searchable: true

define view entity I_DefectFractionEstnProcedTxt as select from tq72t
   
   association [1..1] to I_DefectFractionEstnProced as _DefectFractionEstnProced
      on     $projection.DefectFractionEstimationProced = _DefectFractionEstnProced.DefectFractionEstimationProced
      
   association [0..1] to I_Language as _Language
      on     $projection.Language   = _Language.Language
      
{
   @Semantics.language: true
   key tq72t.sprache           as Language, 
   key cast( tq72t.antverf as vdm_qeantverf preserving type )    as DefectFractionEstimationProced,
    
   @Semantics.text: true
   @Search: { defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.8 }
   cast( tq72t.kurztext as vdm_qeantverf_text preserving type )  as DefectFractionEstnProcedTxt
       
   /* Associations*/
   ,_DefectFractionEstnProced
   ,_Language
   
}