I_DefectCodeStdVH

DDL: I_DEFECTCODESTDVH Type: view_entity COMPOSITE Package: VDM_QM_NOTIFICATION

Defect Code

I_DefectCodeStdVH is a Composite CDS View that provides data about "Defect Code" in SAP S/4HANA. It reads from 1 data source (I_DefectCode) and exposes 9 fields with key fields DefectCodeGroup, DefectCode. Part of development package VDM_QM_NOTIFICATION.

1 data source(s) 9 fields

Data Sources (1)

SourceAliasJoin Type
I_DefectCode I_DefectCode from

Annotations (14)

NameValueLevelField
VDM.viewType #COMPOSITE view
VDM.lifecycle.contract.type #PUBLIC_LOCAL_API view
ObjectModel.modelingPattern #VALUE_HELP_PROVIDER view
ObjectModel.dataCategory #VALUE_HELP view
Analytics.technicalName IDC__VH view
ObjectModel.representativeKey DefectCode view
ObjectModel.usageType.serviceQuality #B view
ObjectModel.usageType.sizeCategory #M view
ObjectModel.usageType.dataClass #CUSTOMIZING view
AccessControl.authorizationCheck #MANDATORY view
Metadata.ignorePropagatedAnnotations true view
EndUserText.label Defect Code view
Search.searchable true view
Consumption.ranked true view

Fields (9)

KeyFieldSource TableSource FieldDescription
KEY DefectCodeGroup DefectCodeGroup
KEY DefectCode DefectCode
DefectCodeText
DefectCodeGroupText
CodeIsInactive CodeIsInactive
DefectCodeGroupAndCode
_Text _Text
CodeGroupStatus CodeGroupStatus
_DefectCodeGroup _DefectCodeGroup 
@VDM: { 
    viewType: #COMPOSITE,
    lifecycle.contract.type: #PUBLIC_LOCAL_API
}
@ObjectModel.supportedCapabilities: [ #VALUE_HELP_PROVIDER ]
@ObjectModel.modelingPattern: #VALUE_HELP_PROVIDER
@ObjectModel.dataCategory: #VALUE_HELP
@Analytics.technicalName: 'IDC__VH'
@ObjectModel.representativeKey: 'DefectCode'

@ObjectModel.usageType.serviceQuality: #B
@ObjectModel.usageType.sizeCategory: #M
@ObjectModel.usageType.dataClass: #CUSTOMIZING

@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.privilegedAssociations: ['_Text','_DefectCodeGroup']

@Metadata.ignorePropagatedAnnotations: true

@EndUserText.label: 'Defect Code'

@Search.searchable: true
@Consumption.ranked: true
define view entity I_DefectCodeStdVH as select from I_DefectCode {
  @ObjectModel.foreignKey.association: '_DefectCodeGroup'
  @ObjectModel.text.element: [ 'DefectCodeGroupText' ]
  @Consumption.valueHelpDefinition: [ 
     { entity:  { name:    'I_DefectCodeGroupStdVH',
                  element: 'DefectCodeGroup' }
     }]
  @Search: {
    defaultSearchElement: true,
    fuzzinessThreshold: 0.8,
    ranking: #LOW
  }
  key DefectCodeGroup,
  
  @ObjectModel.text.element: ['DefectCodeText']
  @Search: {
    defaultSearchElement: true,
    fuzzinessThreshold: 0.8,
    ranking: #HIGH
  }
  key DefectCode,
  
  @Semantics.text: true
  @Search: {
    defaultSearchElement: true,
    fuzzinessThreshold: 0.8,
    ranking: #LOW
  }
  _Text[ 1:Language = $session.system_language ].DefectCodeText,
  
  @Semantics.text:true
  @Search: {
    defaultSearchElement: true,
    fuzzinessThreshold: 0.8,
    ranking: #LOW
  }
  _DefectCodeGroup._Text[ 1:Language = $session.system_language ].DefectCodeGroupText,
  
  @Consumption.hidden: true
  CodeIsInactive,
  
  @ObjectModel.text.element: ['DefectCodeText']
  cast( concat_with_space( DefectCodeGroup, DefectCode, 1) as qdefect_code_group_and_code preserving type ) as DefectCodeGroupAndCode,
  
  _Text,

  // For authority check

  @Consumption.hidden: true
  CodeGroupStatus,
  @Consumption.hidden: true
  _DefectCodeGroup
}

Learn More