I_DataExchangeInstructionKeys

@AbapCatalog.sqlViewName: 'IINSTRNKEYS'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AbapCatalog.buffering.status: #ACTIVE
@AbapCatalog.buffering.type: #FULL

@AccessControl.authorizationCheck: #NOT_REQUIRED

@ClientHandling.algorithm: #SESSION_VARIABLE

@ObjectModel.usageType.dataClass: #CUSTOMIZING
@ObjectModel.compositionRoot: true
@ObjectModel.representativeKey: 'DataExchangeInstructionKey'
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #S

@VDM.viewType: #BASIC

@EndUserText.label: 'Instruction Keys'
define view I_DataExchangeInstructionKeys 
  as select from t015w
  
   association [1..*] to I_DataExchInstructionKeysText as _Text on  _Text.BankCountryKey             = $projection.BankCountryKey
                                                                and _Text.PaymentMethod              = $projection.PaymentMethod
                                                                and _Text.DataExchangeInstructionKey = $projection.DataExchangeInstructionKey
  
{

  key cast(banks as bank1)               as  BankCountryKey,
  key cast(zlsch as farp_schzw_bseg)     as  PaymentMethod,
  key cast(dtaws as farp_dtaws)          as  DataExchangeInstructionKey,
      cast(dtws1 as farp_dtat16)         as  DataExchangeInstruction1,
      cast(dtws2 as farp_dtat17)         as  DataExchangeInstruction2,
      cast(dtws3 as farp_dtat18)         as  DataExchangeInstruction3,
      cast(dtws4 as farp_dtat19)         as  DataExchangeInstruction4,
      cast(dtzus as farp_dtat20)         as  DataExchangeInstrnAddlInfo, 
      cast(dtkvs as farp_dtat21)         as  DataExchangeCostAllocation, 
      cast(dtkza as farp_dtat22)         as  DataExchangePaymentType,    
      cast(ediza as farp_paiart)         as  PaytInstructionPaymentMethod,
      cast(edime as farp_paimed)         as  PaymentOrderTransmissionMedium,
      cast(dtwsc as farp_dtwsc)          as  DataExchInstrnApplicationArea,
      dturg                              as  IsUrgentPayment,
      
      @ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
      _Text  
}

where dtaws is not initial