I_DataCollectionRoot

DDL: I_DATACOLLECTIONROOT SQL: IMDEFROOT Type: view COMPOSITE Package: EHENV_BO_MDEF_IMPL

Data Collection Root

I_DataCollectionRoot is a Composite CDS View that provides data about "Data Collection Root" in SAP S/4HANA. It reads from 1 data source (I_DataCollectionRootBasic) and exposes 23 fields with key field DataCollectionUUID. It has 4 associations to related views. Part of development package EHENV_BO_MDEF_IMPL.

1 data source(s) 23 fields

Data Sources (1)

SourceAliasJoin Type
I_DataCollectionRootBasic I_DataCollectionRootBasic from

Associations (4)

CardinalityTargetAliasCondition
[0..1] I_UnitOfMeasure _UnitText $projection.UnitOfMeasure = _UnitText.UnitOfMeasure
[0..1] I_UnitOfMeasure _UnitTextAlt $projection.EHSAltvUnitOfMeasurement = _UnitTextAlt.UnitOfMeasure
[1..1] I_EHSLocationRevision _EHSLocation $projection.EHSLocationUUID = _EHSLocation.EHSLocationUUID and( _EHSLocation.RevisionStartDate <= $session.system_date and _EHSLocation.RevisionEndDate >= $session.system_date )
[0..1] I_EHSDataPeriod _EHSDataPeriod $projection.DataUsagePeriodicity = _EHSDataPeriod.EHSDataPeriod

Annotations (10)

NameValueLevelField
AbapCatalog.sqlViewName IMDEFROOT view
EndUserText.label Data Collection Root view
VDM.viewType #COMPOSITE view
AbapCatalog.compiler.compareFilter true view
AbapCatalog.preserveKey true view
AccessControl.authorizationCheck #NOT_REQUIRED view
ClientHandling.algorithm #SESSION_VARIABLE view
ObjectModel.usageType.dataClass #MASTER view
ObjectModel.usageType.serviceQuality #D view
ObjectModel.usageType.sizeCategory #M view

Fields (23)

KeyFieldSource TableSource FieldDescription
KEY DataCollectionUUID DataCollectionUUID
CreationDateTime CreationDateTime
LastChangeDateTime LastChangeDateTime
CreatedByUser CreatedByUser
LastChangedByUser LastChangedByUser
DataCollectionID DataCollectionID
DataCollectionName DataCollectionName
DataCollectionInputMethod DataCollectionInputMethod
EHSAmountExternalSource EHSAmountExternalSource
DataUsagePeriodicity DataUsagePeriodicity
UnitOfMeasure UnitOfMeasure
UnitOfMeasureName
EHSAltvUnitOfMeasurement EHSAltvUnitOfMeasurement
EHSAltvUnitOfMeasurementName
_UnitText _UnitText
_UnitTextAlt _UnitTextAlt
EHSSubjectType EHSSubjectType
EHSSubjectUUID EHSSubjectUUID
DataCollectionTitle DataCollectionTitle
EHSLocationUUID EHSLocationUUID
EHSLocRespTechnicianID
_EHSLocation _EHSLocation
_EHSDataPeriod _EHSDataPeriod 
@AbapCatalog.sqlViewName: 'IMDEFROOT'
@EndUserText.label: 'Data Collection Root'
@VDM.viewType: #COMPOSITE
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey:true

@AccessControl.authorizationCheck: #NOT_REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType: { dataClass: #MASTER,
                          serviceQuality: #D,
                          sizeCategory: #M }

define view I_DataCollectionRoot
  as select from I_DataCollectionRootBasic
  association [0..1] to I_UnitOfMeasure       as _UnitText      on $projection.UnitOfMeasure = _UnitText.UnitOfMeasure
  association [0..1] to I_UnitOfMeasure       as _UnitTextAlt   on $projection.EHSAltvUnitOfMeasurement = _UnitTextAlt.UnitOfMeasure
  /*+[hideWarning] { "IDS" : [ "CARDINALITY_CHECK" ] }*/
  association [1..1] to I_EHSLocationRevision as _EHSLocation   on $projection.EHSLocationUUID     = _EHSLocation.EHSLocationUUID
                                                                and(
                                                                  _EHSLocation.RevisionStartDate   <= $session.system_date
                                                                  and _EHSLocation.RevisionEndDate >= $session.system_date
                                                                )
  association [0..1] to I_EHSDataPeriod       as _EHSDataPeriod on $projection.DataUsagePeriodicity = _EHSDataPeriod.EHSDataPeriod
{

  key DataCollectionUUID,

      CreationDateTime,
      LastChangeDateTime,

      CreatedByUser,

      LastChangedByUser,

      DataCollectionID,
      DataCollectionName,

      DataCollectionInputMethod,
      EHSAmountExternalSource,
      DataUsagePeriodicity,

      @Semantics.unitOfMeasure
      @ObjectModel.foreignKey.association: '_UnitText'
      UnitOfMeasure,
      _UnitText._Text[1: Language =  $session.system_language ].UnitOfMeasureName    as UnitOfMeasureName,
      @Semantics.unitOfMeasure
      @ObjectModel.foreignKey.association: '_UnitTextAlt'
      EHSAltvUnitOfMeasurement                                                       as EHSAltvUnitOfMeasurement,
      _UnitTextAlt._Text[1: Language =  $session.system_language ].UnitOfMeasureName as EHSAltvUnitOfMeasurementName,
      _UnitText,
      _UnitTextAlt,


      EHSSubjectType,
      EHSSubjectUUID,
      DataCollectionTitle,

      @ObjectModel.foreignKey.association: '_EHSLocation'
      EHSLocationUUID,

      _EHSLocation._EHSLocRespTechnician.EHSLocRespTechnicianID                      as EHSLocRespTechnicianID,

      _EHSLocation,

      _EHSDataPeriod

}

Learn More