I_CustomizingObjectTexts

@AbapCatalog.sqlViewName: 'ICUST_OBJ_TXT'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Customizing Object Texts'
define view I_CustomizingObjectTexts
  // For logical transport object and individual transaction object, description is retrieved from table OBJT

  as select from    objh as CustomizingObjects
    left outer join objt as CustomizingObjectTexts on  CustomizingObjects.objectname   = CustomizingObjectTexts.objectname
                                                   and CustomizingObjects.objecttype   = CustomizingObjectTexts.objecttype
                                                   and CustomizingObjectTexts.language = $session.system_language
{
  key    'R3TR'                        as TransportRequestObjectPgmID,
  key    case CustomizingObjects.objecttype
         when 'L' then CustomizingObjects.objectname
         else 'TDAT'
         end                           as TransportRequestObjectType,
  key    case CustomizingObjects.objecttype
         when 'L' then ' '
         else CustomizingObjects.objectname
         end                           as TransportRequestObjectName,
         CustomizingObjectTexts.ddtext as TransportRequestObjectNameDesc
}
where
     CustomizingObjects.objecttype = 'L' // Logical transport object

  or CustomizingObjects.objecttype = 'T' // Individual transaction object


// For table with text table, description is retrieved from table DD02T

union select from objh
  left outer join dd02t as DictionaryTexts on  objh.objectname            = DictionaryTexts.tabname
                                           and DictionaryTexts.ddlanguage = $session.system_language
                                           and DictionaryTexts.as4local   = 'A'
                                           and DictionaryTexts.as4vers    = '0000'
{
  key 'R3TR'                 as TransportRequestObjectPgmID,
  key 'TABU'                 as TransportRequestObjectType,
  key objectname             as TransportRequestObjectName,
      DictionaryTexts.ddtext as TransportRequestObjectNameDesc
}
where
  objecttype = 'S' // Table with text table


// For maintenance view, description is retrieved from table DD25T

union select from objh  as MaintenanceViews
  left outer join dd25t as MaintenanceViewTexts on  MaintenanceViews.objectname     = MaintenanceViewTexts.viewname
                                                and MaintenanceViewTexts.ddlanguage = $session.system_language
                                                and MaintenanceViewTexts.as4local   = 'A'
                                                and MaintenanceViewTexts.as4vers    = '0000'
{
  key 'R3TR'                      as TransportRequestObjectPgmID,
  key 'VDAT'                      as TransportRequestObjectType,
  key objectname                  as TransportRequestObjectName,
      MaintenanceViewTexts.ddtext as TransportRequestObjectNameDesc
}
where
  MaintenanceViews.objecttype = 'V' // Maintenance view


// For viewcluster, description is retrieved from table VCLDIRT

union select from objh    as Viewclusetrs
  left outer join vcldirt as ViewclusterTexts on  Viewclusetrs.objectname = ViewclusterTexts.vclname
                                              and ViewclusterTexts.spras  = $session.system_language
{
  key    'R3TR'                as TransportRequestObjectPgmID,
  key    'CDAT'                as TransportRequestObjectType,
  key    objectname            as TransportRequestObjectName,
         ViewclusterTexts.text as TransportRequestObjectNameDesc
}
where
  Viewclusetrs.objecttype = 'C' // Viewcluster


// For tables i.e. there is no customizing object, description is retrieved from table DD02T

union select from dd02l as Tables /*+[hideWarning] { "IDS" : [ "CARDINALITY_CHECK" ] }*/
  left outer join dd02t as TableTexts on  Tables.tabname        = TableTexts.tabname
                                      and Tables.as4local       = TableTexts.as4local
                                      and Tables.as4vers        = TableTexts.as4vers
                                      and TableTexts.ddlanguage = $session.system_language
/*+[hideWarning] { "IDS" : [ "CARDINALITY_CHECK" ] }*/ association [0..1] to objh as CustomizingObjects on Tables.tabname = CustomizingObjects.objectname

{
  key    'R3TR'            as TransportRequestObjectPgmID,
  key    'TABU'            as TransportRequestObjectType,
  key    Tables.tabname    as TransportRequestObjectName,
         TableTexts.ddtext as TransportRequestObjectNameDesc

}
where
       Tables.as4local               = 'A'
  and  Tables.as4vers                = '0000'
  and(
       Tables.contflag               = 'C'
    or Tables.contflag               = 'E'
    or Tables.contflag               = 'G'
  )
  and  CustomizingObjects.objectname is null